CMakeLists.txt

   1 ###############################################################################
   2 # Top contributors (to current version):
   3 #   Aina Niemetz, Mathias Preiner, Gereon Kremer
   4 #
   5 # This file is part of the cvc5 project.
   6 #
   7 # Copyright (c) 2009-2022 by the authors listed in the file AUTHORS
   8 # in the top-level source directory and their institutional affiliations.
   9 # All rights reserved.  See the file COPYING in the top-level source
  10 # directory for licensing information.
  11 # #############################################################################
  12 #
  13 # The build system configuration.
  14 ##
  15
  16 cmake_minimum_required(VERSION 3.9)
  17
  18 #-----------------------------------------------------------------------------#
  19 # Project configuration
  20
  21 project(cvc5)
  22
  23 include(CheckIPOSupported)
  24 include(GNUInstallDirs)
  25 set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  26
  27 include(version)
  28
  29 set(CMAKE_C_STANDARD 99)
  30 set(CMAKE_CXX_STANDARD 17)
  31 set(CMAKE_CXX_EXTENSIONS OFF)
  32 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  33 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  34 set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  35
  36 # Generate compile_commands.json, which can be used for various code completion
  37 # plugins.
  38 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  39
  40 #-----------------------------------------------------------------------------#
  41 # Policies
  42
  43 # Required for FindGLPK since it sets CMAKE_REQUIRED_LIBRARIES
  44 if(POLICY CMP0075)
  45   cmake_policy(SET CMP0075 NEW)
  46 endif()
  47
  48 #-----------------------------------------------------------------------------#
  49 # Tell CMake where to find our dependencies
  50
  51 if(GLPK_DIR)
  52   list(APPEND CMAKE_PREFIX_PATH "${GLPK_DIR}")
  53 endif()
  54
  55 # By default the contrib/get-* scripts install dependencies to deps/install.
  56 list(APPEND CMAKE_PREFIX_PATH "${PROJECT_SOURCE_DIR}/deps/install")
  57
  58 #-----------------------------------------------------------------------------#
  59
  60 include(Helpers)
  61
  62 #-----------------------------------------------------------------------------#
  63 # User options
  64
  65 # License
  66 option(ENABLE_GPL "Enable GPL dependencies")
  67
  68 # General build options
  69 #
  70 # >> 3-valued: IGNORE ON OFF
  71 #    > allows to detect if set by user (default: IGNORE)
  72 #    > only necessary for options set for build types
  73 option(BUILD_SHARED_LIBS          "Build shared libraries and binary")
  74 cvc5_option(ENABLE_ASAN           "Enable ASAN build")
  75 cvc5_option(ENABLE_UBSAN          "Enable UBSan build")
  76 cvc5_option(ENABLE_TSAN           "Enable TSan build")
  77 cvc5_option(ENABLE_ASSERTIONS     "Enable assertions")
  78 cvc5_option(ENABLE_COMP_INC_TRACK
  79             "Enable optimizations for incremental SMT-COMP tracks")
  80 cvc5_option(ENABLE_DEBUG_SYMBOLS  "Enable debug symbols")
  81 cvc5_option(ENABLE_MUZZLE         "Suppress ALL non-result output")
  82 cvc5_option(ENABLE_STATISTICS     "Enable statistics")
  83 cvc5_option(ENABLE_TRACING        "Enable tracing")
  84 cvc5_option(ENABLE_UNIT_TESTING   "Enable unit testing")
  85 cvc5_option(ENABLE_VALGRIND       "Enable valgrind instrumentation")
  86 cvc5_option(ENABLE_AUTO_DOWNLOAD  "Enable automatic download of dependencies")
  87 cvc5_option(ENABLE_IPO            "Enable interprocedural optimization")
  88 # >> 2-valued: ON OFF
  89 #    > for options where we don't need to detect if set by user (default: OFF)
  90 option(ENABLE_BEST             "Enable dependencies known to give best performance")
  91 option(ENABLE_COVERAGE         "Enable support for gcov coverage testing")
  92 option(ENABLE_DEBUG_CONTEXT_MM "Enable the debug context memory manager")
  93 option(ENABLE_PROFILING        "Enable support for gprof profiling")
  94
  95 # Optional dependencies
  96 #
  97 # >> 3-valued: IGNORE ON OFF
  98 #    > allows to detect if set by user (default: IGNORE)
  99 #    > only necessary for options set for ENABLE_BEST
 100 cvc5_option(USE_CLN           "Use CLN instead of GMP")
 101 cvc5_option(USE_CRYPTOMINISAT "Use CryptoMiniSat SAT solver")
 102 cvc5_option(USE_GLPK          "Use GLPK simplex solver")
 103 cvc5_option(USE_KISSAT        "Use Kissat SAT solver")
 104 cvc5_option(USE_EDITLINE      "Use Editline for better interactive support")
 105 # >> 2-valued: ON OFF
 106 #    > for options where we don't need to detect if set by user (default: OFF)
 107 option(USE_POLY               "Use LibPoly for polynomial arithmetic")
 108 option(USE_COCOA              "Use CoCoALib for further polynomial operations")
 109
 110 # Custom install directories for dependencies
 111 # If no directory is provided by the user, we first check if the dependency was
 112 # installed via the corresponding contrib/get-* script and if not found, we
 113 # check the intalled system version. If the user provides a directory we
 114 # immediately fail if the dependency was not found at the specified location.
 115 set(GLPK_DIR          "" CACHE STRING "Set GLPK install directory")
 116
 117 # Prepend binaries with prefix on make install
 118 set(PROGRAM_PREFIX    "" CACHE STRING "Program prefix on make install")
 119
 120 # Supported language bindings based on new C++ API
 121 option(BUILD_BINDINGS_PYTHON "Build Python bindings based on new C++ API ")
 122 option(BUILD_BINDINGS_JAVA "Build Java bindings based on new C++ API ")
 123
 124 # Api documentation
 125 option(BUILD_DOCS "Build Api documentation")
 126
 127 # Link against static system libraries
 128 cvc5_option(STATIC_BINARY "Link against static system libraries \
 129 (enabled by default for static builds)")
 130
 131 #-----------------------------------------------------------------------------#
 132 # Internal cmake variables
 133
 134 set(OPTIMIZATION_LEVEL 3)
 135 set(GPL_LIBS "")
 136
 137 #-----------------------------------------------------------------------------#
 138 # Determine number of threads available, used to configure (default) parallel
 139 # execution of custom test targets (can be overriden with ARGS=-jN).
 140
 141 include(ProcessorCount)
 142 ProcessorCount(CTEST_NTHREADS)
 143 if(CTEST_NTHREADS EQUAL 0)
 144   set(CTEST_NTHREADS 1)
 145 endif()
 146
 147 #-----------------------------------------------------------------------------#
 148 # Build types
 149
 150 # Note: Module CodeCoverage requires the name of the debug build to conform
 151 #       to cmake standards (first letter uppercase).
 152 set(BUILD_TYPES Production Debug Testing Competition)
 153
 154 if(ENABLE_ASAN OR ENABLE_UBSAN OR ENABLE_TSAN)
 155   set(CMAKE_BUILD_TYPE Debug)
 156 endif()
 157
 158 # Set the default build type to Production
 159 if(NOT CMAKE_BUILD_TYPE)
 160   set(CMAKE_BUILD_TYPE
 161       Production CACHE STRING "Options are: ${BUILD_TYPES}" FORCE)
 162   # Provide drop down menu options in cmake-gui
 163   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${BUILD_TYPES})
 164 endif()
 165
 166 # Check if specified build type is valid.
 167 list(FIND BUILD_TYPES ${CMAKE_BUILD_TYPE} FOUND_BUILD_TYPE)
 168 if(${FOUND_BUILD_TYPE} EQUAL -1)
 169   message(FATAL_ERROR
 170     "'${CMAKE_BUILD_TYPE}' is not a valid build type. "
 171     "Available builds are: ${BUILD_TYPES}")
 172 endif()
 173
 174 message(STATUS "Building ${CMAKE_BUILD_TYPE} build")
 175 include(Config${CMAKE_BUILD_TYPE})
 176
 177 #-----------------------------------------------------------------------------#
 178 # Compiler flags
 179
 180 add_check_c_cxx_flag("-O${OPTIMIZATION_LEVEL}")
 181 add_check_c_cxx_flag("-Wall")
 182 add_check_c_cxx_supression_flag("-Wno-unused-private-field")
 183 add_check_c_flag("-fexceptions")
 184 add_check_cxx_flag("-Wsuggest-override")
 185 add_check_cxx_flag("-Wnon-virtual-dtor")
 186 add_check_c_cxx_flag("-Wimplicit-fallthrough")
 187 add_check_c_cxx_flag("-Wshadow")
 188
 189 # Assume no dynamic initialization of thread-local variables in non-defining
 190 # translation units. This option should result in better performance and works
 191 # around crashing issues with our Windows build.
 192 add_check_cxx_flag("-fno-extern-tls-init")
 193
 194 # Temporarily disable -Wclass-memaccess to suppress 'no trivial copy-assignment'
 195 # cdlist.h warnings. Remove when fixed.
 196 add_check_cxx_supression_flag("-Wno-class-memaccess")
 197
 198 if (WIN32)
 199   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,100000000")
 200
 201   # ANTLR uses pragmas that certain versions of MinGW does not support
 202   add_check_c_cxx_flag("-Wno-error=unknown-pragmas")
 203 endif ()
 204
 205 #-----------------------------------------------------------------------------#
 206 # Use ld.gold if available
 207
 208 execute_process(COMMAND ${CMAKE_C_COMPILER}
 209                 -fuse-ld=gold
 210                 -Wl,--version ERROR_QUIET OUTPUT_VARIABLE LD_VERSION)
 211 if ("${LD_VERSION}" MATCHES "GNU gold")
 212   string(APPEND CMAKE_EXE_LINKER_FLAGS " -fuse-ld=gold")
 213   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -fuse-ld=gold")
 214   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -fuse-ld=gold")
 215   message(STATUS "Using GNU gold linker.")
 216 endif ()
 217
 218 #-----------------------------------------------------------------------------#
 219 # Use interprocedural optimization if requested
 220
 221 if(ENABLE_IPO)
 222   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 223 endif()
 224
 225 #-----------------------------------------------------------------------------#
 226
 227 # Only enable unit testing if assertions are enabled. Otherwise, unit tests
 228 # that expect AssertionException to be thrown will fail.
 229 if(NOT ENABLE_ASSERTIONS)
 230   message(STATUS "Disabling unit tests since assertions are disabled.")
 231   set(ENABLE_UNIT_TESTING OFF)
 232 endif()
 233
 234 #-----------------------------------------------------------------------------#
 235 # Shared/static libraries
 236
 237 # Embed the installation prefix as an RPATH in the executable such that the
 238 # linker can find our libraries (such as libcvc5parser) when executing the
 239 # cvc5 binary. This is for example useful when installing cvc5 with a custom
 240 # prefix on macOS (e.g. when using homebrew in a non-standard directory). If
 241 # we do not set this option, then the linker will not be able to find the
 242 # required libraries when trying to run cvc5.
 243 #
 244 # Also embed the installation prefix of the installed contrib libraries as an
 245 # RPATH. This allows to install a dynamically linked binary that depends on
 246 # dynamically linked libraries. This is dangerous, as the installed binary
 247 # breaks if the contrib library is removed or changes in other ways, we thus
 248 # print a big warning and only allow if installing to a custom installation
 249 # prefix.
 250 #
 251 # More information on RPATH in CMake:
 252 # https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling
 253 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR};${PROJECT_SOURCE_DIR}/deps/install/lib")
 254
 255 # Set visibility to default if unit tests are enabled. If unit tests are
 256 # enabled, we also check if we can execute white box unit tests (some versions
 257 # of Clang have issues with the required flag).
 258 set(ENABLE_WHITEBOX_UNIT_TESTING OFF)
 259 if(ENABLE_UNIT_TESTING)
 260   set(CMAKE_CXX_VISIBILITY_PRESET default)
 261   set(CMAKE_VISIBILITY_INLINES_HIDDEN 0)
 262
 263   # Check if Clang version has the bug that was fixed in
 264   # https://reviews.llvm.org/D93104
 265   set(ENABLE_WHITEBOX_UNIT_TESTING ON)
 266   check_cxx_compiler_flag("-faccess-control" HAVE_CXX_FLAGfaccess_control)
 267   if(NOT HAVE_CXX_FLAGfaccess_control)
 268     set(ENABLE_WHITEBOX_UNIT_TESTING OFF)
 269     message(STATUS "Disabling white box unit tests")
 270   endif()
 271 endif()
 272
 273 #-----------------------------------------------------------------------------#
 274 # Enable the ctest testing framework
 275
 276 # This needs to be enabled here rather than in subdirectory test in order to
 277 # allow calling ctest from the root build directory.
 278 enable_testing()
 279
 280 #-----------------------------------------------------------------------------#
 281 # Check options, find packages and configure build.
 282
 283 if(BUILD_SHARED_LIBS)
 284   if (WIN32)
 285     set(CMAKE_FIND_LIBRARY_SUFFIXES .dll .lib .a)
 286   else()
 287     set(CMAKE_FIND_LIBRARY_SUFFIXES .so .dylib .a)
 288   endif()
 289 else()
 290   if (WIN32)
 291     set(CMAKE_FIND_LIBRARY_SUFFIXES .lib .a .dll)
 292   else()
 293     set(CMAKE_FIND_LIBRARY_SUFFIXES .a .so .dylib)
 294   endif()
 295 endif()
 296
 297 find_package(PythonInterp 3 REQUIRED)
 298 find_package(GMP 6.1 REQUIRED)
 299
 300 if(ENABLE_ASAN)
 301   # -fsanitize=address requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 302   # otherwise the -fsanitize=address check will fail while linking.
 303   set(CMAKE_REQUIRED_FLAGS -fsanitize=address)
 304   add_required_c_cxx_flag("-fsanitize=address")
 305   unset(CMAKE_REQUIRED_FLAGS)
 306   add_required_c_cxx_flag("-fno-omit-frame-pointer")
 307   add_check_c_cxx_flag("-fsanitize-recover=address")
 308 endif()
 309
 310 if(ENABLE_UBSAN)
 311   add_required_c_cxx_flag("-fsanitize=undefined")
 312   add_definitions(-DCVC5_USE_UBSAN)
 313 endif()
 314
 315 if(ENABLE_TSAN)
 316   # -fsanitize=thread requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 317   # otherwise the -fsanitize=thread check will fail while linking.
 318   set(CMAKE_REQUIRED_FLAGS -fsanitize=thread)
 319   add_required_c_cxx_flag("-fsanitize=thread")
 320   unset(CMAKE_REQUIRED_FLAGS)
 321 endif()
 322
 323 if(ENABLE_ASSERTIONS)
 324   add_definitions(-DCVC5_ASSERTIONS)
 325 else()
 326   add_definitions(-DNDEBUG)
 327 endif()
 328
 329 if(ENABLE_COVERAGE)
 330   include(CodeCoverage)
 331   append_coverage_compiler_flags()
 332   add_definitions(-DCVC5_COVERAGE)
 333   setup_code_coverage_fastcov(
 334     NAME coverage
 335     PATH "${PROJECT_SOURCE_DIR}"
 336     EXCLUDE "${CMAKE_BINARY_DIR}/deps/*"
 337     DEPENDENCIES cvc5-bin
 338   )
 339 endif()
 340
 341 if(ENABLE_DEBUG_CONTEXT_MM)
 342   add_definitions(-DCVC5_DEBUG_CONTEXT_MEMORY_MANAGER)
 343 endif()
 344
 345 if(ENABLE_DEBUG_SYMBOLS)
 346   add_check_c_cxx_flag("-ggdb3")
 347 endif()
 348
 349 if(ENABLE_COMP_INC_TRACK)
 350   add_definitions(-DCVC5_SMTCOMP_APPLICATION_TRACK)
 351 endif()
 352
 353 if(ENABLE_MUZZLE)
 354   add_definitions(-DCVC5_MUZZLE)
 355 endif()
 356
 357 if(ENABLE_PROFILING)
 358   add_definitions(-DCVC5_PROFILING)
 359   add_check_c_cxx_flag("-pg")
 360 endif()
 361
 362 if(ENABLE_TRACING)
 363   add_definitions(-DCVC5_TRACING)
 364 endif()
 365
 366 if(ENABLE_STATISTICS)
 367   add_definitions(-DCVC5_STATISTICS_ON)
 368 endif()
 369
 370 if(ENABLE_VALGRIND)
 371   find_package(Valgrind REQUIRED)
 372   add_definitions(-DCVC5_VALGRIND)
 373 endif()
 374
 375 find_package(CaDiCaL REQUIRED)
 376
 377 if(USE_CLN)
 378   set(GPL_LIBS "${GPL_LIBS} cln")
 379   find_package(CLN 1.2.2 REQUIRED)
 380   set(CVC5_USE_CLN_IMP 1)
 381   set(CVC5_USE_GMP_IMP 0)
 382 else()
 383   set(CVC5_USE_CLN_IMP 0)
 384   set(CVC5_USE_GMP_IMP 1)
 385 endif()
 386
 387 if(USE_CRYPTOMINISAT)
 388   # CryptoMiniSat requires pthreads support
 389   set(THREADS_PREFER_PTHREAD_FLAG ON)
 390   find_package(Threads REQUIRED)
 391   if(THREADS_HAVE_PTHREAD_ARG)
 392     add_c_cxx_flag(-pthread)
 393   endif()
 394   find_package(CryptoMiniSat 5.8 REQUIRED)
 395   add_definitions(-DCVC5_USE_CRYPTOMINISAT)
 396 endif()
 397
 398 if(USE_GLPK)
 399   set(GPL_LIBS "${GPL_LIBS} glpk")
 400   find_package(GLPK REQUIRED)
 401   add_definitions(-DCVC5_USE_GLPK)
 402 endif()
 403
 404 if(USE_KISSAT)
 405   find_package(Kissat REQUIRED)
 406   add_definitions(-DCVC5_USE_KISSAT)
 407 endif()
 408
 409 if(USE_POLY)
 410   find_package(Poly REQUIRED)
 411   add_definitions(-DCVC5_USE_POLY)
 412   set(CVC5_USE_POLY_IMP 1)
 413 else()
 414   set(CVC5_USE_POLY_IMP 0)
 415 endif()
 416
 417 if(USE_COCOA)
 418   find_package(CoCoA REQUIRED 0.99711)
 419   add_definitions(-DCVC5_USE_COCOA)
 420 endif()
 421
 422 if(USE_EDITLINE)
 423   find_package(Editline REQUIRED)
 424   set(HAVE_LIBEDITLINE 1)
 425   if(Editline_COMPENTRY_FUNC_RETURNS_CHARPTR)
 426     set(EDITLINE_COMPENTRY_FUNC_RETURNS_CHARP 1)
 427   endif()
 428 endif()
 429
 430 find_package(SymFPU REQUIRED)
 431
 432 if(GPL_LIBS)
 433   if(NOT ENABLE_GPL)
 434     message(FATAL_ERROR
 435       "Bad configuration detected: BSD-licensed code only, but also requested "
 436       "GPLed libraries: ${GPL_LIBS}")
 437   endif()
 438   set(CVC5_GPL_DEPS 1)
 439 endif()
 440
 441 #-----------------------------------------------------------------------------#
 442 # Provide targets to inspect iwyu suggestions
 443
 444 include(IWYU)
 445 include(fuzzing-murxla)
 446
 447 #-----------------------------------------------------------------------------#
 448
 449 include(ConfigureCvc5)
 450 if(BUILD_SHARED_LIBS)
 451   set(CVC5_STATIC_BUILD OFF)
 452 else()
 453   set(CVC5_STATIC_BUILD ON)
 454   if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 455     cvc5_set_option(STATIC_BINARY ON)
 456   endif()
 457 endif()
 458
 459 #-----------------------------------------------------------------------------#
 460 # Add subdirectories
 461
 462 add_subdirectory(src)
 463
 464 if(BUILD_BINDINGS_PYTHON AND NOT BUILD_SHARED_LIBS)
 465   message(STATUS "Python bindings can only be built in a shared build.")
 466   set(BUILD_BINDINGS_PYTHON OFF)
 467 endif()
 468 if(BUILD_BINDINGS_PYTHON)
 469   set(BUILD_BINDINGS_PYTHON_VERSION ${PYTHON_VERSION_MAJOR})
 470   add_subdirectory(src/api/python)
 471 endif()
 472
 473 if(BUILD_BINDINGS_JAVA)
 474   add_subdirectory(src/api/java)
 475 endif()
 476
 477 if(BUILD_DOCS)
 478   add_subdirectory(docs)
 479 endif()
 480
 481 add_subdirectory(test)
 482
 483 include(target-graphs)
 484
 485 #-----------------------------------------------------------------------------#
 486 # Package configuration
 487 #
 488 # Export cvc5 targets to support find_package(cvc5) in other cmake projects.
 489
 490 include(CMakePackageConfigHelpers)
 491
 492 # If we install a dynamically linked binary that also uses dynamically used
 493 # libraries from deps/install/lib, we need to be cautious. Changing these
 494 # shared libraries from deps/install/lib most probably breaks the binary.
 495 # We only allow such an installation for custom installation prefixes
 496 # (in the assumption that only reasonably experienced users use this and
 497 # also that custom installation prefixes are not used for longer periods of
 498 # time anyway). Also, we print a big warning with further instructions.
 499 if(BUILD_SHARED_LIBS)
 500   # Get the libraries that cvc5 links against
 501   get_target_property(libs cvc5 INTERFACE_LINK_LIBRARIES)
 502   set(LIBS_SHARED_FROM_DEPS "")
 503   foreach(lib ${libs})
 504     # Filter out those that are linked dynamically and come from deps/install
 505     if(lib MATCHES ".*/deps/install/lib/.*\.so")
 506       list(APPEND LIBS_SHARED_FROM_DEPS ${lib})
 507     endif()
 508   endforeach()
 509   list(LENGTH LIBS_SHARED_FROM_DEPS list_len)
 510   # Check if we actually use such "dangerous" libraries
 511   if(list_len GREATER 0)
 512     # Print a generic warning
 513     install(CODE "message(WARNING \"You are installing a dynamically linked \
 514     binary of cvc5 which may be a problem if you are using any dynamically \
 515     linked third-party library that you obtained through one of the \
 516     contrib/get-xxx scripts. The binary uses the rpath mechanism to find these \
 517     locally, hence executing such a contrib script removing the \
 518     \\\"deps/install\\\" folder most probably breaks the installed binary! \
 519     Consider installing the dynamically linked dependencies on your system \
 520     manually or link cvc5 statically.\")")
 521     # Print the libraries in question
 522     foreach(lib ${LIBS_SHARED_FROM_DEPS})
 523       install(CODE "message(WARNING \"The following library is used by the cvc5 binary: ${lib}\")")
 524     endforeach()
 525     # Check if we use a custom installation prefix
 526     if(CMAKE_INSTALL_PREFIX STREQUAL "/usr/local")
 527       install(CODE "message(FATAL_ERROR \"To avoid installing a \
 528       soon-to-be-broken binary, system-wide installation is disabled if the \
 529       binary depends on locally-built shared libraries.\")")
 530     else()
 531       install(CODE "message(WARNING \"You have selected a custom install \
 532       directory ${CMAKE_INSTALL_PREFIX}, so we expect you understood the \
 533       previous warning and know what you are doing.\")")
 534     endif()
 535   endif()
 536 endif()
 537
 538 install(EXPORT cvc5-targets
 539   FILE cvc5Targets.cmake
 540   NAMESPACE cvc5::
 541   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5)
 542
 543 configure_package_config_file(
 544   ${CMAKE_SOURCE_DIR}/cmake/cvc5Config.cmake.in
 545   ${CMAKE_BINARY_DIR}/cmake/cvc5Config.cmake
 546   INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5
 547   PATH_VARS CMAKE_INSTALL_LIBDIR
 548 )
 549
 550 write_basic_package_version_file(
 551   ${CMAKE_CURRENT_BINARY_DIR}/cvc5ConfigVersion.cmake
 552   VERSION ${CVC5_VERSION}
 553   COMPATIBILITY ExactVersion
 554 )
 555
 556 install(FILES
 557   ${CMAKE_BINARY_DIR}/cmake/cvc5Config.cmake
 558   ${CMAKE_BINARY_DIR}/cvc5ConfigVersion.cmake
 559   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5
 560 )
 561
 562
 563 #-----------------------------------------------------------------------------#
 564 # Print build configuration
 565
 566 # Set colors.
 567 if(NOT WIN32)
 568   string(ASCII 27 Esc)
 569   set(Green "${Esc}[32m")
 570   set(Blue "${Esc}[1;34m")
 571   set(ResetColor "${Esc}[m")
 572 endif()
 573
 574 # Convert build type to lower case.
 575 string(TOLOWER ${CMAKE_BUILD_TYPE} CVC5_BUILD_PROFILE_STRING)
 576
 577 # Get all definitions added via add_definitions.
 578 get_directory_property(CVC5_DEFINITIONS COMPILE_DEFINITIONS)
 579 string(REPLACE ";" " " CVC5_DEFINITIONS "${CVC5_DEFINITIONS}")
 580
 581 message("")
 582 print_info("cvc5 ${CVC5_VERSION}")
 583 message("")
 584 if(ENABLE_COMP_INC_TRACK)
 585   print_config("Build profile             " "${CVC5_BUILD_PROFILE_STRING} (incremental)")
 586 else()
 587   print_config("Build profile             " "${CVC5_BUILD_PROFILE_STRING}")
 588 endif()
 589 message("")
 590 print_config("GPL                       " ${ENABLE_GPL})
 591 print_config("Best configuration        " ${ENABLE_BEST})
 592 message("")
 593 print_config("Assertions                " ${ENABLE_ASSERTIONS})
 594 print_config("Debug symbols             " ${ENABLE_DEBUG_SYMBOLS})
 595 print_config("Debug context mem mgr     " ${ENABLE_DEBUG_CONTEXT_MM})
 596 message("")
 597 print_config("Muzzle                    " ${ENABLE_MUZZLE})
 598 print_config("Statistics                " ${ENABLE_STATISTICS})
 599 print_config("Tracing                   " ${ENABLE_TRACING})
 600 message("")
 601 print_config("ASan                      " ${ENABLE_ASAN})
 602 print_config("UBSan                     " ${ENABLE_UBSAN})
 603 print_config("TSan                      " ${ENABLE_TSAN})
 604 print_config("Coverage (gcov)           " ${ENABLE_COVERAGE})
 605 print_config("Profiling (gprof)         " ${ENABLE_PROFILING})
 606 print_config("Unit tests                " ${ENABLE_UNIT_TESTING})
 607 print_config("Valgrind                  " ${ENABLE_VALGRIND})
 608 message("")
 609 print_config("Shared build              " ${BUILD_SHARED_LIBS})
 610 print_config("Python bindings           " ${BUILD_BINDINGS_PYTHON})
 611 print_config("Java bindings             " ${BUILD_BINDINGS_JAVA})
 612 print_config("Interprocedural opt.      " ${ENABLE_IPO})
 613 message("")
 614 print_config("CryptoMiniSat             " ${USE_CRYPTOMINISAT} FOUND_SYSTEM ${CryptoMiniSat_FOUND_SYSTEM})
 615 print_config("GLPK                      " ${USE_GLPK})
 616 print_config("Kissat                    " ${USE_KISSAT} FOUND_SYSTEM ${Kissat_FOUND_SYSTEM})
 617 print_config("LibPoly                   " ${USE_POLY} FOUND_SYSTEM ${Poly_FOUND_SYSTEM})
 618 print_config("CoCoALib                  " ${USE_COCOA} FOUND_SYSTEM ${CoCoA_FOUND_SYSTEM})
 619
 620 if(CVC5_USE_CLN_IMP)
 621   print_config("MP library                " "cln" FOUND_SYSTEM ${CLN_FOUND_SYSTEM})
 622 else()
 623   print_config("MP library                " "gmp" FOUND_SYSTEM ${GMP_FOUND_SYSTEM})
 624 endif()
 625 print_config("Editline                  " ${USE_EDITLINE})
 626 message("")
 627 print_config("Api docs                  " ${BUILD_DOCS})
 628 message("")
 629 if(GLPK_DIR)
 630   print_config("GLPK dir                  " ${GLPK_DIR})
 631 endif()
 632 message("")
 633 print_config("CPPLAGS (-D...)" "${CVC5_DEFINITIONS}")
 634 print_config("CXXFLAGS       " "${CMAKE_CXX_FLAGS}")
 635 print_config("CFLAGS         " "${CMAKE_C_FLAGS}")
 636 print_config("Linker flags   " "${CMAKE_EXE_LINKER_FLAGS}")
 637 message("")
 638 print_config("Install prefix " "${CMAKE_INSTALL_PREFIX}")
 639 message("")
 640
 641 if(GPL_LIBS)
 642   message(
 643   "${Blue}cvc5 license: "
 644   "${Yellow}GPLv3 (due to optional libraries; see below)${ResetColor}"
 645   "\n"
 646   "\n"
 647   "Please note that cvc5 will be built against the following GPLed libraries:"
 648   "\n"
 649   "${GPL_LIBS}"
 650   "\n"
 651   "As these libraries are covered under the GPLv3, so is this build of cvc5."
 652   "\n"
 653   "cvc5 is also available to you under the terms of the (modified) BSD license."
 654   "\n"
 655   "If you prefer to license cvc5 under those terms, please configure cvc5 to"
 656   "\n"
 657   "disable all optional GPLed library dependencies (-DENABLE_BSD_ONLY=ON)."
 658   )
 659 else()
 660   message(
 661   "${Blue}cvc5 license:${ResetColor} modified BSD"
 662   "\n"
 663   "\n"
 664   "Note that this configuration is NOT built against any GPL'ed libraries, so"
 665   "\n"
 666   "it is covered by the (modified) BSD license.  To build against GPL'ed"
 667   "\n"
 668   "libraries which can improve cvc5's performance on arithmetic and bitvector"
 669   "\n"
 670   "logics, re-configure with '-DENABLE_GPL -DENABLE_BEST'."
 671   )
 672 endif()
 673
 674 if("${CMAKE_GENERATOR}" STREQUAL "Ninja")
 675   set(BUILD_COMMAND_NAME "ninja")
 676 else()
 677   set(BUILD_COMMAND_NAME "make")
 678 endif()
 679
 680 message("")
 681 message("Now just type '${BUILD_COMMAND_NAME}', "
 682         "followed by '${BUILD_COMMAND_NAME} check' "
 683         "or '${BUILD_COMMAND_NAME} install'.")
 684 message("")