configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-libcilkrts \
 154                 target-liboffloadmic \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libmpx \
 161                 target-libssp \
 162                 target-libquadmath \
 163                 target-libgfortran \
 164                 target-libffi \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable libcilkrts on unsupported systems.
 540 if test -d ${srcdir}/libcilkrts; then
 541     if test x$enable_libcilkrts = x; then
 542         AC_MSG_CHECKING([for libcilkrts support])
 543         if (srcdir=${srcdir}/libcilkrts; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-libcilkrts"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable liboffloadmic on unsupported systems.
 556 if test -d ${srcdir}/liboffloadmic; then
 557     if test x$enable_liboffloadmic != xno; then
 558         AC_MSG_CHECKING([for liboffloadmic support])
 559         if (srcdir=${srcdir}/liboffloadmic; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-liboffloadmic"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libitm on unsupported systems.
 572 if test -d ${srcdir}/libitm; then
 573     if test x$enable_libitm = x; then
 574         AC_MSG_CHECKING([for libitm support])
 575         if (srcdir=${srcdir}/libitm; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libitm"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libsanitizer on unsupported systems.
 588 if test -d ${srcdir}/libsanitizer; then
 589     if test x$enable_libsanitizer = x; then
 590         AC_MSG_CHECKING([for libsanitizer support])
 591         if (srcdir=${srcdir}/libsanitizer; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test -n "$UNSUPPORTED")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libsanitizer"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603 # Disable libvtv on unsupported systems.
 604 if test -d ${srcdir}/libvtv; then
 605     if test x$enable_libvtv = x; then
 606         AC_MSG_CHECKING([for libvtv support])
 607         if (srcdir=${srcdir}/libvtv; \
 608                 . ${srcdir}/configure.tgt; \
 609                 test "$VTV_SUPPORTED" != "yes")
 610         then
 611             AC_MSG_RESULT([no])
 612             noconfigdirs="$noconfigdirs target-libvtv"
 613         else
 614             AC_MSG_RESULT([yes])
 615         fi
 616     fi
 617 fi
 618
 619
 620 # Enable libmpx on supported systems by request.
 621 if test -d ${srcdir}/libmpx; then
 622     if test x$enable_libmpx = x; then
 623        AC_MSG_CHECKING([for libmpx support])
 624        if (srcdir=${srcdir}/libmpx; \
 625                . ${srcdir}/configure.tgt; \
 626                test "$LIBMPX_SUPPORTED" != "yes")
 627        then
 628            AC_MSG_RESULT([no])
 629            noconfigdirs="$noconfigdirs target-libmpx"
 630        else
 631            AC_MSG_RESULT([yes])
 632        fi
 633     fi
 634 fi
 635
 636
 637
 638 # Disable libquadmath for some systems.
 639 case "${target}" in
 640   avr-*-*)
 641     noconfigdirs="$noconfigdirs target-libquadmath"
 642     ;;
 643   # libquadmath is unused on AIX and libquadmath build process use of
 644   # LD_LIBRARY_PATH can break AIX bootstrap.
 645   powerpc-*-aix* | rs6000-*-aix*)
 646     noconfigdirs="$noconfigdirs target-libquadmath"
 647     ;;
 648 esac
 649
 650 # Disable libssp for some systems.
 651 case "${target}" in
 652   avr-*-*)
 653     # No hosted I/O support.
 654     noconfigdirs="$noconfigdirs target-libssp"
 655     ;;
 656   powerpc-*-aix* | rs6000-*-aix*)
 657     noconfigdirs="$noconfigdirs target-libssp"
 658     ;;
 659   rl78-*-*)
 660     # libssp uses a misaligned load to trigger a fault, but the RL78
 661     # doesn't fault for those - instead, it gives a build-time error
 662     # for explicit misaligned loads.
 663     noconfigdirs="$noconfigdirs target-libssp"
 664     ;;
 665   visium-*-*)
 666     # No hosted I/O support.
 667     noconfigdirs="$noconfigdirs target-libssp"
 668     ;;
 669 esac
 670
 671 # Disable libstdc++-v3 for some systems.
 672 # Allow user to override this if they pass --enable-libstdc++-v3
 673 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 674   case "${target}" in
 675     *-*-vxworks*)
 676       # VxWorks uses the Dinkumware C++ library.
 677       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 678       ;;
 679     arm*-wince-pe*)
 680       # the C++ libraries don't build on top of CE's C libraries
 681       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 682       ;;
 683     avr-*-*)
 684       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 685       ;;
 686     ft32-*-*)
 687       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 688       ;;
 689   esac
 690 fi
 691
 692 # Disable Fortran for some systems.
 693 case "${target}" in
 694   mmix-*-*)
 695     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 696     unsupported_languages="$unsupported_languages fortran"
 697     ;;
 698 esac
 699
 700 # Disable libffi for some systems.
 701 case "${target}" in
 702   powerpc-*-darwin*)
 703     ;;
 704   i[[3456789]]86-*-darwin*)
 705     ;;
 706   x86_64-*-darwin[[912]]*)
 707     ;;
 708   *-*-darwin*)
 709     noconfigdirs="$noconfigdirs target-libffi"
 710     ;;
 711   *-*-netware*)
 712     noconfigdirs="$noconfigdirs target-libffi"
 713     ;;
 714   *-*-phoenix*)
 715     noconfigdirs="$noconfigdirs target-libffi"
 716     ;;
 717   *-*-rtems*)
 718     noconfigdirs="$noconfigdirs target-libffi"
 719     ;;
 720   *-*-tpf*)
 721     noconfigdirs="$noconfigdirs target-libffi"
 722     ;;
 723   *-*-uclinux*)
 724     noconfigdirs="$noconfigdirs target-libffi"
 725     ;;
 726   *-*-vxworks*)
 727     noconfigdirs="$noconfigdirs target-libffi"
 728     ;;
 729   alpha*-*-*vms*)
 730     noconfigdirs="$noconfigdirs target-libffi"
 731     ;;
 732   arm*-*-freebsd*)
 733     noconfigdirs="$noconfigdirs target-libffi"
 734     ;;
 735   arm-wince-pe)
 736     noconfigdirs="$noconfigdirs target-libffi"
 737     ;;
 738   arm*-*-symbianelf*)
 739     noconfigdirs="$noconfigdirs target-libffi"
 740     ;;
 741   cris-*-* | crisv32-*-*)
 742     case "${target}" in
 743       *-*-linux*)
 744         ;;
 745       *) # See PR46792 regarding target-libffi.
 746         noconfigdirs="$noconfigdirs target-libffi";;
 747     esac
 748     ;;
 749   hppa*64*-*-hpux*)
 750     noconfigdirs="$noconfigdirs target-libffi"
 751     ;;
 752   hppa*-hp-hpux11*)
 753     ;;
 754   hppa*-*-hpux*)
 755     noconfigdirs="$noconfigdirs target-libffi"
 756     ;;
 757   ia64*-*-*vms*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   i[[3456789]]86-w64-mingw*)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   i[[3456789]]86-*-mingw*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   x86_64-*-mingw*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   mmix-*-*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   powerpc-*-aix*)
 773     # copied from rs6000-*-* entry
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   rs6000-*-aix*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   ft32-*-*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   *-*-lynxos*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785 esac
 786
 787 # Disable the go frontend on systems where it is known to not work. Please keep
 788 # this in sync with contrib/config-list.mk.
 789 case "${target}" in
 790 *-*-darwin* | *-*-cygwin* | *-*-mingw* | *-*-aix*)
 791     unsupported_languages="$unsupported_languages go"
 792     ;;
 793 esac
 794
 795 # Disable libgo for some systems where it is known to not work.
 796 # For testing, you can easily override this with --enable-libgo.
 797 if test x$enable_libgo = x; then
 798     case "${target}" in
 799     *-*-darwin*)
 800         # PR 46986
 801         noconfigdirs="$noconfigdirs target-libgo"
 802         ;;
 803     *-*-cygwin* | *-*-mingw*)
 804         noconfigdirs="$noconfigdirs target-libgo"
 805         ;;
 806     *-*-aix*)
 807         noconfigdirs="$noconfigdirs target-libgo"
 808         ;;
 809     esac
 810 fi
 811
 812 # Default libgloss CPU subdirectory.
 813 libgloss_dir="$target_cpu"
 814
 815 case "${target}" in
 816   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 817     libgloss_dir=wince
 818     ;;
 819   aarch64*-*-* )
 820     libgloss_dir=aarch64
 821     ;;
 822   arm*-*-*)
 823     libgloss_dir=arm
 824     ;;
 825   cris-*-* | crisv32-*-*)
 826     libgloss_dir=cris
 827     ;;
 828   hppa*-*-*)
 829     libgloss_dir=pa
 830     ;;
 831   i[[3456789]]86-*-*)
 832     libgloss_dir=i386
 833     ;;
 834   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 835     libgloss_dir=m68hc11
 836     ;;
 837   m68*-*-* | fido-*-*)
 838     libgloss_dir=m68k
 839     ;;
 840   mips*-*-*)
 841     libgloss_dir=mips
 842     ;;
 843   powerpc*-*-*)
 844     libgloss_dir=rs6000
 845     ;;
 846   sparc*-*-*)
 847     libgloss_dir=sparc
 848     ;;
 849 esac
 850
 851 # Disable newlib and libgloss for various target OSes.
 852 case "${target}" in
 853   alpha*-dec-osf*)
 854     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 855     ;;
 856   i[[3456789]]86-*-linux*)
 857     # This section makes it possible to build newlib natively on linux.
 858     # If we are using a cross compiler then don't configure newlib.
 859     if test x${is_cross_compiler} != xno ; then
 860       noconfigdirs="$noconfigdirs target-newlib"
 861     fi
 862     noconfigdirs="$noconfigdirs target-libgloss"
 863     # If we are not using a cross compiler, do configure newlib.
 864     # Note however, that newlib will only be configured in this situation
 865     # if the --with-newlib option has been given, because otherwise
 866     # 'target-newlib' will appear in skipdirs.
 867     ;;
 868   i[[3456789]]86-*-rdos*)
 869     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 870     ;;
 871   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 872     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 873     ;;
 874   sparc-*-sunos4*)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   *-*-aix*)
 878     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 879     ;;
 880   *-*-beos*)
 881     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 882     ;;
 883   *-*-chorusos)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   *-*-dragonfly*)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   *-*-freebsd*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   *-*-lynxos*)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898   *-*-mingw*)
 899     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 900     ;;
 901   *-*-netbsd*)
 902     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 903     ;;
 904   *-*-netware*)
 905     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 906     ;;
 907   *-*-tpf*)
 908     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     ;;
 910   *-*-uclinux*)
 911     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 912     ;;
 913   *-*-vxworks*)
 914     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 915     ;;
 916 esac
 917
 918 case "${target}" in
 919   *-*-chorusos)
 920     ;;
 921   aarch64-*-darwin*)
 922     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 923     noconfigdirs="$noconfigdirs sim target-rda"
 924     ;;
 925   arm-*-darwin*)
 926     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 927     noconfigdirs="$noconfigdirs sim target-rda"
 928     ;;
 929   powerpc-*-darwin*)
 930     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 931     noconfigdirs="$noconfigdirs sim target-rda"
 932     ;;
 933   i[[3456789]]86-*-darwin*)
 934     noconfigdirs="$noconfigdirs ld gprof"
 935     noconfigdirs="$noconfigdirs sim target-rda"
 936     ;;
 937   x86_64-*-darwin[[912]]*)
 938     noconfigdirs="$noconfigdirs ld gas gprof"
 939     noconfigdirs="$noconfigdirs sim target-rda"
 940     ;;
 941   *-*-darwin*)
 942     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 943     noconfigdirs="$noconfigdirs sim target-rda"
 944     ;;
 945   *-*-dragonfly*)
 946     ;;
 947   *-*-freebsd*)
 948     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 949         && test -f /usr/local/include/gmp.h; then
 950       with_gmp=/usr/local
 951     fi
 952     ;;
 953   *-*-kaos*)
 954     # Remove unsupported stuff on all kaOS configurations.
 955     noconfigdirs="$noconfigdirs target-libgloss"
 956     ;;
 957   *-*-netbsd*)
 958     ;;
 959   *-*-netware*)
 960     ;;
 961   *-*-phoenix*)
 962     noconfigdirs="$noconfigdirs target-libgloss"
 963     ;;
 964   *-*-rtems*)
 965     noconfigdirs="$noconfigdirs target-libgloss"
 966     # this is not caught below because this stanza matches earlier
 967     case $target in
 968       or1k*-*-*) noconfigdirs="$noconfigdirs gdb" ;;
 969     esac
 970     ;;
 971     # The tpf target doesn't support gdb yet.
 972   *-*-tpf*)
 973     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 974     ;;
 975   *-*-uclinux*)
 976     noconfigdirs="$noconfigdirs target-rda"
 977     ;;
 978   *-*-vxworks*)
 979     ;;
 980   alpha*-dec-osf*)
 981     # ld works, but does not support shared libraries.
 982     # gas doesn't generate exception information.
 983     noconfigdirs="$noconfigdirs gas ld"
 984     ;;
 985   alpha*-*-*vms*)
 986     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 987     ;;
 988   alpha*-*-*)
 989     # newlib is not 64 bit ready
 990     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 991     ;;
 992   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 993     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 994     ;;
 995   arc*-*-*)
 996     noconfigdirs="$noconfigdirs sim"
 997     ;;
 998   arm-*-pe*)
 999     noconfigdirs="$noconfigdirs target-libgloss"
1000     ;;
1001   arm-*-riscix*)
1002     noconfigdirs="$noconfigdirs ld target-libgloss"
1003     ;;
1004   avr-*-*)
1005     if test x${with_avrlibc} != xno; then
1006       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1007     fi
1008     ;;
1009   c4x-*-* | tic4x-*-*)
1010     noconfigdirs="$noconfigdirs target-libgloss"
1011     ;;
1012   tic54x-*-*)
1013     noconfigdirs="$noconfigdirs target-libgloss gdb"
1014     ;;
1015   d10v-*-*)
1016     noconfigdirs="$noconfigdirs target-libgloss"
1017     ;;
1018   d30v-*-*)
1019     noconfigdirs="$noconfigdirs gdb"
1020     ;;
1021   fr30-*-elf*)
1022     noconfigdirs="$noconfigdirs gdb"
1023     ;;
1024   ft32-*-*)
1025     noconfigdirs="$noconfigdirs target-rda gprof"
1026     ;;
1027   moxie-*-*)
1028     noconfigdirs="$noconfigdirs"
1029     ;;
1030   h8300*-*-*)
1031     noconfigdirs="$noconfigdirs target-libgloss"
1032     ;;
1033   h8500-*-*)
1034     noconfigdirs="$noconfigdirs target-libgloss"
1035     ;;
1036   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1037     ;;
1038   hppa*64*-*-hpux*)
1039     noconfigdirs="$noconfigdirs gdb"
1040     ;;
1041   hppa*-*-hpux11*)
1042     noconfigdirs="$noconfigdirs gdb ld"
1043     ;;
1044   hppa*64*-*-linux*)
1045     ;;
1046   hppa*-*-linux*)
1047     ;;
1048   hppa*-*-*elf* | \
1049   hppa*-*-lites* | \
1050   hppa*-*-openbsd* | \
1051   hppa*64*-*-*)
1052     ;;
1053   hppa*-*-pro*)
1054     ;;
1055   hppa*-*-*)
1056     noconfigdirs="$noconfigdirs ld"
1057     ;;
1058   i960-*-*)
1059     noconfigdirs="$noconfigdirs gdb"
1060     ;;
1061   ia64*-*-elf*)
1062     # No gdb support yet.
1063     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1064     ;;
1065   ia64*-**-hpux*)
1066     # No ld support yet.
1067     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1068     ;;
1069   ia64*-*-*vms*)
1070     # No ld support yet.
1071     noconfigdirs="$noconfigdirs libgui itcl ld"
1072     ;;
1073   i[[3456789]]86-w64-mingw*)
1074     ;;
1075   i[[3456789]]86-*-mingw*)
1076     target_configdirs="$target_configdirs target-winsup"
1077     ;;
1078   *-*-cygwin*)
1079     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1080     noconfigdirs="$noconfigdirs target-libgloss"
1081     # always build newlib if winsup directory is present.
1082     if test -d "$srcdir/winsup/cygwin"; then
1083       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1084     elif test -d "$srcdir/newlib"; then
1085       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1086     fi
1087     ;;
1088   i[[3456789]]86-*-pe)
1089     noconfigdirs="$noconfigdirs target-libgloss"
1090     ;;
1091   i[[3456789]]86-*-sco3.2v5*)
1092     # The linker does not yet know about weak symbols in COFF,
1093     # and is not configured to handle mixed ELF and COFF.
1094     noconfigdirs="$noconfigdirs ld target-libgloss"
1095     ;;
1096   i[[3456789]]86-*-sco*)
1097     noconfigdirs="$noconfigdirs gprof target-libgloss"
1098     ;;
1099   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1100     noconfigdirs="$noconfigdirs target-libgloss"
1101     ;;
1102   i[[3456789]]86-*-sysv4*)
1103     noconfigdirs="$noconfigdirs target-libgloss"
1104     ;;
1105   i[[3456789]]86-*-beos*)
1106     noconfigdirs="$noconfigdirs gdb"
1107     ;;
1108   i[[3456789]]86-*-rdos*)
1109     noconfigdirs="$noconfigdirs gdb"
1110     ;;
1111   mmix-*-*)
1112     noconfigdirs="$noconfigdirs gdb"
1113     ;;
1114   mt-*-*)
1115     noconfigdirs="$noconfigdirs sim"
1116     ;;
1117   powerpc-*-aix*)
1118     # copied from rs6000-*-* entry
1119     noconfigdirs="$noconfigdirs gprof"
1120     ;;
1121   powerpc*-*-winnt* | powerpc*-*-pe*)
1122     target_configdirs="$target_configdirs target-winsup"
1123     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1124     # always build newlib.
1125     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1126     ;;
1127     # This is temporary until we can link against shared libraries
1128   powerpcle-*-solaris*)
1129     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1130     ;;
1131   powerpc-*-beos*)
1132     noconfigdirs="$noconfigdirs gdb"
1133     ;;
1134   rs6000-*-lynxos*)
1135     noconfigdirs="$noconfigdirs gprof"
1136     ;;
1137   rs6000-*-aix*)
1138     noconfigdirs="$noconfigdirs gprof"
1139     ;;
1140   rs6000-*-*)
1141     noconfigdirs="$noconfigdirs gprof"
1142     ;;
1143   m68k-apollo-*)
1144     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1145     ;;
1146   microblaze*)
1147     noconfigdirs="$noconfigdirs gprof"
1148     ;;
1149   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1150     if test x$with_newlib = xyes; then
1151       noconfigdirs="$noconfigdirs gprof"
1152     fi
1153     ;;
1154   mips*-*-irix5*)
1155     noconfigdirs="$noconfigdirs gprof target-libgloss"
1156     ;;
1157   mips*-*-irix6*)
1158     noconfigdirs="$noconfigdirs gprof target-libgloss"
1159     ;;
1160   mips*-*-bsd*)
1161     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1162     ;;
1163   mips*-*-linux*)
1164     ;;
1165   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1166   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1167     noconfigdirs="$noconfigdirs ld gas gprof"
1168     ;;
1169   mips*-*-*)
1170     noconfigdirs="$noconfigdirs gprof"
1171     ;;
1172   nvptx*-*-*)
1173     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1174     ;;
1175   or1k*-*-*)
1176     noconfigdirs="$noconfigdirs gdb"
1177     ;;
1178   sh-*-*)
1179     case "${target}" in
1180       sh*-*-elf)
1181          ;;
1182       *)
1183          noconfigdirs="$noconfigdirs target-libgloss" ;;
1184     esac
1185     ;;
1186   sparc-*-sunos4*)
1187     if test x${is_cross_compiler} = xno ; then
1188            use_gnu_ld=no
1189     fi
1190     ;;
1191   tic6x-*-*)
1192     noconfigdirs="$noconfigdirs sim"
1193     ;;
1194   tilepro*-*-* | tilegx*-*-*)
1195     noconfigdirs="$noconfigdirs sim"
1196     ;;
1197   v810-*-*)
1198     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1199     ;;
1200   vax-*-*)
1201     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1202     ;;
1203 esac
1204
1205 # If we aren't building newlib, then don't build libgloss, since libgloss
1206 # depends upon some newlib header files.
1207 case "${noconfigdirs}" in
1208   *target-libgloss*) ;;
1209   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1210 esac
1211
1212 # Work in distributions that contain no compiler tools, like Autoconf.
1213 host_makefile_frag=/dev/null
1214 if test -d ${srcdir}/config ; then
1215 case "${host}" in
1216   i[[3456789]]86-*-msdosdjgpp*)
1217     host_makefile_frag="config/mh-djgpp"
1218     ;;
1219   *-cygwin*)
1220     ACX_CHECK_CYGWIN_CAT_WORKS
1221     host_makefile_frag="config/mh-cygwin"
1222     ;;
1223   *-mingw*)
1224     host_makefile_frag="config/mh-mingw"
1225     ;;
1226   alpha*-linux*)
1227     host_makefile_frag="config/mh-alpha-linux"
1228     ;;
1229   hppa*-hp-hpux10*)
1230     host_makefile_frag="config/mh-pa-hpux10"
1231     ;;
1232   hppa*-hp-hpux*)
1233     host_makefile_frag="config/mh-pa"
1234     ;;
1235   hppa*-*)
1236     host_makefile_frag="config/mh-pa"
1237     ;;
1238   *-*-darwin*)
1239     host_makefile_frag="config/mh-darwin"
1240     ;;
1241   powerpc-*-aix*)
1242     host_makefile_frag="config/mh-ppc-aix"
1243     ;;
1244   rs6000-*-aix*)
1245     host_makefile_frag="config/mh-ppc-aix"
1246     ;;
1247 esac
1248 fi
1249
1250 if test "${build}" != "${host}" ; then
1251   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1252   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1253   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1254   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1255   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1256   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1257   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1258   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1259   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1260   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1261   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1262   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1263   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1264 else
1265   AR_FOR_BUILD="\$(AR)"
1266   AS_FOR_BUILD="\$(AS)"
1267   CC_FOR_BUILD="\$(CC)"
1268   CXX_FOR_BUILD="\$(CXX)"
1269   GCJ_FOR_BUILD="\$(GCJ)"
1270   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1271   GOC_FOR_BUILD="\$(GOC)"
1272   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1273   LD_FOR_BUILD="\$(LD)"
1274   NM_FOR_BUILD="\$(NM)"
1275   RANLIB_FOR_BUILD="\$(RANLIB)"
1276   WINDRES_FOR_BUILD="\$(WINDRES)"
1277   WINDMC_FOR_BUILD="\$(WINDMC)"
1278 fi
1279
1280 AC_PROG_CC
1281 AC_PROG_CXX
1282
1283 # We must set the default linker to the linker used by gcc for the correct
1284 # operation of libtool.  If LD is not defined and we are using gcc, try to
1285 # set the LD default to the ld used by gcc.
1286 if test -z "$LD"; then
1287   if test "$GCC" = yes; then
1288     case $build in
1289     *-*-mingw*)
1290       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1291     *)
1292       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1293     esac
1294     case $gcc_prog_ld in
1295     # Accept absolute paths.
1296     [[\\/]* | [A-Za-z]:[\\/]*)]
1297       LD="$gcc_prog_ld" ;;
1298     esac
1299   fi
1300 fi
1301
1302 # Check whether -static-libstdc++ -static-libgcc is supported.
1303 have_static_libs=no
1304 if test "$GCC" = yes; then
1305   saved_LDFLAGS="$LDFLAGS"
1306
1307   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1308   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1309   AC_LANG_PUSH(C++)
1310   AC_LINK_IFELSE([
1311 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1312 #error -static-libstdc++ not implemented
1313 #endif
1314 int main() {}],
1315     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1316     [AC_MSG_RESULT([no])])
1317   AC_LANG_POP(C++)
1318
1319   LDFLAGS="$saved_LDFLAGS"
1320 fi
1321
1322 ACX_PROG_GNAT
1323 ACX_PROG_CMP_IGNORE_INITIAL
1324
1325 AC_ARG_ENABLE([bootstrap],
1326 [AS_HELP_STRING([--enable-bootstrap],
1327                 [enable bootstrapping @<:@yes if native build@:>@])],,
1328 enable_bootstrap=default)
1329
1330 # Issue errors and warnings for invalid/strange bootstrap combinations.
1331 if test -r $srcdir/gcc/configure; then
1332   have_compiler=yes
1333 else
1334   have_compiler=no
1335 fi
1336
1337 case "$have_compiler:$host:$target:$enable_bootstrap" in
1338   *:*:*:no) ;;
1339
1340   # Default behavior.  Enable bootstrap if we have a compiler
1341   # and we are in a native configuration.
1342   yes:$build:$build:default)
1343     enable_bootstrap=yes ;;
1344
1345   *:*:*:default)
1346     enable_bootstrap=no ;;
1347
1348   # We have a compiler and we are in a native configuration, bootstrap is ok
1349   yes:$build:$build:yes)
1350     ;;
1351
1352   # Other configurations, but we have a compiler.  Assume the user knows
1353   # what he's doing.
1354   yes:*:*:yes)
1355     AC_MSG_WARN([trying to bootstrap a cross compiler])
1356     ;;
1357
1358   # No compiler: if they passed --enable-bootstrap explicitly, fail
1359   no:*:*:yes)
1360     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1361
1362   # Fail if wrong command line
1363   *)
1364     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1365     ;;
1366 esac
1367
1368 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1369 # C++98 compiler can still start the bootstrap.
1370 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1371   CXX="$CXX -std=gnu++98"
1372 fi
1373
1374 # Used for setting $lt_cv_objdir
1375 _LT_CHECK_OBJDIR
1376
1377 # Check for GMP, MPFR and MPC
1378 gmplibs="-lmpc -lmpfr -lgmp"
1379 gmpinc=
1380 have_gmp=no
1381
1382 # Specify a location for mpc
1383 # check for this first so it ends up on the link line before mpfr.
1384 AC_ARG_WITH(mpc,
1385 [AS_HELP_STRING([--with-mpc=PATH],
1386                 [specify prefix directory for installed MPC package.
1387                  Equivalent to --with-mpc-include=PATH/include
1388                  plus --with-mpc-lib=PATH/lib])])
1389 AC_ARG_WITH(mpc-include,
1390 [AS_HELP_STRING([--with-mpc-include=PATH],
1391                 [specify directory for installed MPC include files])])
1392 AC_ARG_WITH(mpc-lib,
1393 [AS_HELP_STRING([--with-mpc-lib=PATH],
1394                 [specify directory for the installed MPC library])])
1395
1396 if test "x$with_mpc" != x; then
1397   gmplibs="-L$with_mpc/lib $gmplibs"
1398   gmpinc="-I$with_mpc/include $gmpinc"
1399 fi
1400 if test "x$with_mpc_include" != x; then
1401   gmpinc="-I$with_mpc_include $gmpinc"
1402 fi
1403 if test "x$with_mpc_lib" != x; then
1404   gmplibs="-L$with_mpc_lib $gmplibs"
1405 fi
1406 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1407   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1408   gmpinc='-I$$s/mpc/src '"$gmpinc"
1409   # Do not test the mpc version.  Assume that it is sufficient, since
1410   # it is in the source tree, and the library has not been built yet
1411   # but it would be included on the link line in the version check below
1412   # hence making the test fail.
1413   have_gmp=yes
1414 fi
1415
1416 # Specify a location for mpfr
1417 # check for this first so it ends up on the link line before gmp.
1418 AC_ARG_WITH(mpfr-dir,
1419 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1420 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1421 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1422
1423 AC_ARG_WITH(mpfr,
1424 [AS_HELP_STRING([--with-mpfr=PATH],
1425                 [specify prefix directory for installed MPFR package.
1426                  Equivalent to --with-mpfr-include=PATH/include
1427                  plus --with-mpfr-lib=PATH/lib])])
1428 AC_ARG_WITH(mpfr-include,
1429 [AS_HELP_STRING([--with-mpfr-include=PATH],
1430                 [specify directory for installed MPFR include files])])
1431 AC_ARG_WITH(mpfr-lib,
1432 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1433                 [specify directory for the installed MPFR library])])
1434
1435 if test "x$with_mpfr" != x; then
1436   gmplibs="-L$with_mpfr/lib $gmplibs"
1437   gmpinc="-I$with_mpfr/include $gmpinc"
1438 fi
1439 if test "x$with_mpfr_include" != x; then
1440   gmpinc="-I$with_mpfr_include $gmpinc"
1441 fi
1442 if test "x$with_mpfr_lib" != x; then
1443   gmplibs="-L$with_mpfr_lib $gmplibs"
1444 fi
1445 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1446   # MPFR v3.1.0 moved the sources into a src sub-directory.
1447   if ! test -d ${srcdir}/mpfr/src; then
1448     AC_MSG_ERROR([dnl
1449 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1450   fi
1451   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1452   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1453   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1454   # Do not test the mpfr version.  Assume that it is sufficient, since
1455   # it is in the source tree, and the library has not been built yet
1456   # but it would be included on the link line in the version check below
1457   # hence making the test fail.
1458   have_gmp=yes
1459 fi
1460
1461 # Specify a location for gmp
1462 AC_ARG_WITH(gmp-dir,
1463 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1464 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1465 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1466
1467 AC_ARG_WITH(gmp,
1468 [AS_HELP_STRING([--with-gmp=PATH],
1469                 [specify prefix directory for the installed GMP package.
1470                  Equivalent to --with-gmp-include=PATH/include
1471                  plus --with-gmp-lib=PATH/lib])])
1472 AC_ARG_WITH(gmp-include,
1473 [AS_HELP_STRING([--with-gmp-include=PATH],
1474                 [specify directory for installed GMP include files])])
1475 AC_ARG_WITH(gmp-lib,
1476 [AS_HELP_STRING([--with-gmp-lib=PATH],
1477                 [specify directory for the installed GMP library])])
1478
1479
1480 if test "x$with_gmp" != x; then
1481   gmplibs="-L$with_gmp/lib $gmplibs"
1482   gmpinc="-I$with_gmp/include $gmpinc"
1483 fi
1484 if test "x$with_gmp_include" != x; then
1485   gmpinc="-I$with_gmp_include $gmpinc"
1486 fi
1487 if test "x$with_gmp_lib" != x; then
1488   gmplibs="-L$with_gmp_lib $gmplibs"
1489 fi
1490 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1491   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1492   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1493   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1494   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1495   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1496   # Do not test the gmp version.  Assume that it is sufficient, since
1497   # it is in the source tree, and the library has not been built yet
1498   # but it would be included on the link line in the version check below
1499   # hence making the test fail.
1500   have_gmp=yes
1501 fi
1502
1503 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1504   have_gmp=yes
1505   saved_CFLAGS="$CFLAGS"
1506   CFLAGS="$CFLAGS $gmpinc"
1507   # Check for the recommended and required versions of GMP.
1508   AC_MSG_CHECKING([for the correct version of gmp.h])
1509   AC_TRY_COMPILE([#include "gmp.h"],[
1510   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1511   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1512   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1513   choke me
1514   #endif
1515   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1516   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1517   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1518   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1519   choke me
1520   #endif
1521   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1522    [AC_MSG_RESULT([no]); have_gmp=no])
1523
1524   # If we have GMP, check the MPFR version.
1525   if test x"$have_gmp" = xyes; then
1526     # Check for the recommended and required versions of MPFR.
1527     AC_MSG_CHECKING([for the correct version of mpfr.h])
1528     AC_TRY_COMPILE([#include <gmp.h>
1529     #include <mpfr.h>],[
1530     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1531     choke me
1532     #endif
1533     ], [AC_TRY_COMPILE([#include <gmp.h>
1534     #include <mpfr.h>],[
1535     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1536     choke me
1537     #endif
1538     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1539      [AC_MSG_RESULT([no]); have_gmp=no])
1540   fi
1541
1542   # Check for the MPC header version.
1543   if test x"$have_gmp" = xyes ; then
1544     # Check for the recommended and required versions of MPC.
1545     AC_MSG_CHECKING([for the correct version of mpc.h])
1546     AC_TRY_COMPILE([#include <mpc.h>],[
1547     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1548     choke me
1549     #endif
1550     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1551     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1552     choke me
1553     #endif
1554     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1555      [AC_MSG_RESULT([no]); have_gmp=no])
1556   fi
1557
1558   # Now check the MPFR library.
1559   if test x"$have_gmp" = xyes; then
1560     saved_LIBS="$LIBS"
1561     LIBS="$LIBS $gmplibs"
1562     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1563     AC_TRY_LINK([#include <mpc.h>],[
1564     mpfr_t n;
1565     mpfr_t x;
1566     mpc_t c;
1567     int t;
1568     mpfr_init (n);
1569     mpfr_init (x);
1570     mpfr_atan2 (n, n, x, GMP_RNDN);
1571     mpfr_erfc (n, x, GMP_RNDN);
1572     mpfr_subnormalize (x, t, GMP_RNDN);
1573     mpfr_clear(n);
1574     mpfr_clear(x);
1575     mpc_init2 (c, 53);
1576     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1577     mpc_cosh (c, c, MPC_RNDNN);
1578     mpc_pow (c, c, c, MPC_RNDNN);
1579     mpc_acosh (c, c, MPC_RNDNN);
1580     mpc_clear (c);
1581     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1582     LIBS="$saved_LIBS"
1583   fi
1584
1585   CFLAGS="$saved_CFLAGS"
1586
1587 # The library versions listed in the error message below should match
1588 # the HARD-minimums enforced above.
1589   if test x$have_gmp != xyes; then
1590     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1591 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1592 their locations.  Source code for these libraries can be found at
1593 their respective hosting sites as well as at
1594 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1595 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1596 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1597 make sure that you have installed both the libraries and the header
1598 files.  They may be located in separate packages.])
1599   fi
1600 fi
1601
1602 # Flags needed for both GMP, MPFR and/or MPC.
1603 AC_SUBST(gmplibs)
1604 AC_SUBST(gmpinc)
1605 AC_SUBST(extra_mpfr_configure_flags)
1606 AC_SUBST(extra_mpc_gmp_configure_flags)
1607 AC_SUBST(extra_mpc_mpfr_configure_flags)
1608 AC_SUBST(extra_isl_gmp_configure_flags)
1609
1610 # Libraries to use for stage1 or when not bootstrapping.
1611 AC_ARG_WITH(stage1-libs,
1612 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1613 [if test "$withval" = "no" -o "$withval" = "yes"; then
1614    stage1_libs=
1615  else
1616    stage1_libs=$withval
1617  fi],
1618 [stage1_libs=])
1619 AC_SUBST(stage1_libs)
1620
1621 # Linker flags to use for stage1 or when not bootstrapping.
1622 AC_ARG_WITH(stage1-ldflags,
1623 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1624 [if test "$withval" = "no" -o "$withval" = "yes"; then
1625    stage1_ldflags=
1626  else
1627    stage1_ldflags=$withval
1628  fi],
1629 [stage1_ldflags=
1630  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1631  # if supported.  But if the user explicitly specified the libraries to use,
1632  # trust that they are doing what they want.
1633  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1634    stage1_ldflags="-static-libstdc++ -static-libgcc"
1635  fi])
1636 AC_SUBST(stage1_ldflags)
1637
1638 # Libraries to use for stage2 and later builds.
1639 AC_ARG_WITH(boot-libs,
1640 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1641 [if test "$withval" = "no" -o "$withval" = "yes"; then
1642    poststage1_libs=
1643  else
1644    poststage1_libs=$withval
1645  fi],
1646 [poststage1_libs=])
1647 AC_SUBST(poststage1_libs)
1648
1649 # Linker flags to use for stage2 and later builds.
1650 AC_ARG_WITH(boot-ldflags,
1651 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1652                 [linker flags for stage2 and later])],
1653 [if test "$withval" = "no" -o "$withval" = "yes"; then
1654    poststage1_ldflags=
1655  else
1656    poststage1_ldflags=$withval
1657  fi],
1658 [poststage1_ldflags=
1659  # In stages 2 and 3, default to linking libstdc++ and libgcc
1660  # statically.  But if the user explicitly specified the libraries to
1661  # use, trust that they are doing what they want.
1662  if test "$poststage1_libs" = ""; then
1663    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1664  fi])
1665 AC_SUBST(poststage1_ldflags)
1666
1667 # GCC GRAPHITE dependency isl.
1668 # Basic setup is inlined here, actual checks are in config/isl.m4
1669
1670 AC_ARG_WITH(isl,
1671   [AS_HELP_STRING(
1672    [--with-isl=PATH],
1673    [Specify prefix directory for the installed isl package.
1674     Equivalent to --with-isl-include=PATH/include
1675     plus --with-isl-lib=PATH/lib])])
1676
1677 # Treat --without-isl as a request to disable
1678 # GRAPHITE support and skip all following checks.
1679 if test "x$with_isl" != "xno"; then
1680   # Check for isl
1681   dnl Provide configure switches and initialize islinc & isllibs
1682   dnl with user input.
1683   ISL_INIT_FLAGS
1684   dnl The versions of isl that work for Graphite
1685   ISL_CHECK_VERSION()
1686   dnl Only execute fail-action, if isl has been requested.
1687   ISL_IF_FAILED([
1688     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1689 fi
1690
1691 # If the isl check failed, disable builds of in-tree variant of isl
1692 if test "x$with_isl" = xno ||
1693    test "x$gcc_cv_isl" = xno; then
1694   noconfigdirs="$noconfigdirs isl"
1695   islinc=
1696 fi
1697
1698 AC_SUBST(isllibs)
1699 AC_SUBST(islinc)
1700
1701 # Check for LTO support.
1702 AC_ARG_ENABLE(lto,
1703 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1704 enable_lto=$enableval,
1705 enable_lto=yes; default_enable_lto=yes)
1706
1707 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1708   build_lto_plugin=yes
1709 ],[if test x"$default_enable_lto" = x"yes" ; then
1710     case $target in
1711       *-apple-darwin9* | *-cygwin* | *-mingw* | *djgpp*) ;;
1712       # On other non-ELF platforms, LTO has yet to be validated.
1713       *) enable_lto=no ;;
1714     esac
1715   else
1716   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1717   # It would also be nice to check the binutils support, but we don't
1718   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1719   # warn during gcc/ subconfigure; unless you're bootstrapping with
1720   # -flto it won't be needed until after installation anyway.
1721     case $target in
1722       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1723       *) if test x"$enable_lto" = x"yes"; then
1724         AC_MSG_ERROR([LTO support is not enabled for this target.])
1725         fi
1726       ;;
1727     esac
1728   fi
1729   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1730   # Build it unless LTO was explicitly disabled.
1731   case $target in
1732     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1733     *) ;;
1734   esac
1735 ])
1736
1737 AC_ARG_ENABLE(linker-plugin-configure-flags,
1738   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1739     [additional flags for configuring linker plugins @<:@none@:>@])],
1740   extra_linker_plugin_configure_flags=$enableval,
1741   extra_linker_plugin_configure_flags=)
1742 AC_SUBST(extra_linker_plugin_configure_flags)
1743 AC_ARG_ENABLE(linker-plugin-flags,
1744   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1745     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1746   extra_linker_plugin_flags=$enableval,
1747   extra_linker_plugin_flags=)
1748 AC_SUBST(extra_linker_plugin_flags)
1749
1750
1751 # By default, C and C++ are the only stage 1 languages.
1752 stage1_languages=,c,
1753
1754 # Target libraries that we bootstrap.
1755 bootstrap_target_libs=,target-libgcc,
1756
1757 # Figure out what language subdirectories are present.
1758 # Look if the user specified --enable-languages="..."; if not, use
1759 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1760 # go away some day.
1761 # NB:  embedded tabs in this IF block -- do not untabify
1762 if test -d ${srcdir}/gcc; then
1763   if test x"${enable_languages+set}" != xset; then
1764     if test x"${LANGUAGES+set}" = xset; then
1765       enable_languages="${LANGUAGES}"
1766         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1767     else
1768       enable_languages=all
1769     fi
1770   else
1771     if test x"${enable_languages}" = x ||
1772        test x"${enable_languages}" = xyes;
1773        then
1774       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1775       exit 1
1776     fi
1777   fi
1778   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1779
1780   # 'f95' is the old name for the 'fortran' language. We issue a warning
1781   # and make the substitution.
1782   case ,${enable_languages}, in
1783     *,f95,*)
1784       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1785       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1786       ;;
1787   esac
1788
1789   # If bootstrapping, C++ must be enabled.
1790   case ",$enable_languages,:$enable_bootstrap" in
1791     *,c++,*:*) ;;
1792     *:yes)
1793       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1794         enable_languages="${enable_languages},c++"
1795       else
1796         AC_MSG_ERROR([bootstrapping requires c++ sources])
1797       fi
1798       ;;
1799   esac
1800
1801   # First scan to see if an enabled language requires some other language.
1802   # We assume that a given config-lang.in will list all the language
1803   # front ends it requires, even if some are required indirectly.
1804   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1805     case ${lang_frag} in
1806       ..) ;;
1807       # The odd quoting in the next line works around
1808       # an apparent bug in bash 1.12 on linux.
1809       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1810       *)
1811         # From the config-lang.in, get $language, $lang_requires, and
1812         # $lang_requires_boot_languages.
1813         language=
1814         lang_requires=
1815         lang_requires_boot_languages=
1816         . ${lang_frag}
1817         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1818           case ,${enable_languages}, in
1819             *,$other,*) ;;
1820             *,all,*) ;;
1821             *,$language,*)
1822               echo " \`$other' language required by \`$language'; enabling" 1>&2
1823               enable_languages="${enable_languages},${other}"
1824               ;;
1825           esac
1826         done
1827         for other in ${lang_requires_boot_languages} ; do
1828           if test "$other" != "c"; then
1829             case ,${enable_stage1_languages}, in
1830               *,$other,*) ;;
1831               *,all,*) ;;
1832               *)
1833                 case ,${enable_languages}, in
1834                   *,$language,*)
1835                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1836                     enable_stage1_languages="$enable_stage1_languages,${other}"
1837                     ;;
1838                 esac
1839                 ;;
1840             esac
1841           fi
1842         done
1843         ;;
1844     esac
1845   done
1846
1847   new_enable_languages=,c,
1848
1849   # If LTO is enabled, add the LTO front end.
1850   if test "$enable_lto" = "yes" ; then
1851     case ,${enable_languages}, in
1852       *,lto,*) ;;
1853       *) enable_languages="${enable_languages},lto" ;;
1854     esac
1855     if test "${build_lto_plugin}" = "yes" ; then
1856       configdirs="$configdirs lto-plugin"
1857     fi
1858   fi
1859
1860   # If we're building an offloading compiler, add the LTO front end.
1861   if test x"$enable_as_accelerator_for" != x ; then
1862     case ,${enable_languages}, in
1863       *,lto,*) ;;
1864       *) enable_languages="${enable_languages},lto" ;;
1865     esac
1866   fi
1867
1868   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1869   potential_languages=,c,
1870
1871   enabled_target_libs=
1872   disabled_target_libs=
1873
1874   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1875     case ${lang_frag} in
1876       ..) ;;
1877       # The odd quoting in the next line works around
1878       # an apparent bug in bash 1.12 on linux.
1879       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1880       *)
1881         # From the config-lang.in, get $language, $target_libs,
1882         # $lang_dirs, $boot_language, and $build_by_default
1883         language=
1884         target_libs=
1885         lang_dirs=
1886         subdir_requires=
1887         boot_language=no
1888         build_by_default=yes
1889         . ${lang_frag}
1890         if test x${language} = x; then
1891           echo "${lang_frag} doesn't set \$language." 1>&2
1892           exit 1
1893         fi
1894
1895         if test "$language" = "c++"; then
1896           boot_language=yes
1897         fi
1898
1899         add_this_lang=no
1900         case ,${enable_languages}, in
1901           *,${language},*)
1902             # Language was explicitly selected; include it
1903             # unless it is C, which is enabled by default.
1904             if test "$language" != "c"; then
1905               add_this_lang=yes
1906             fi
1907             ;;
1908           *,all,*)
1909             # 'all' was selected, select it if it is a default language
1910             if test "$language" != "c"; then
1911               add_this_lang=${build_by_default}
1912             fi
1913             ;;
1914         esac
1915
1916         # Disable languages that need other directories if these aren't available.
1917         for i in $subdir_requires; do
1918           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1919           case ,${enable_languages}, in
1920             *,${language},*)
1921               # Specifically requested language; tell them.
1922               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1923               ;;
1924             *)
1925               # Silently disable.
1926               add_this_lang=unsupported
1927               ;;
1928           esac
1929         done
1930
1931         # Disable Ada if no preexisting GNAT is available.
1932         case ,${enable_languages},:${language}:${have_gnat} in
1933           *,${language},*:ada:no)
1934             # Specifically requested language; tell them.
1935             AC_MSG_ERROR([GNAT is required to build $language])
1936             ;;
1937           *:ada:no)
1938             # Silently disable.
1939             add_this_lang=unsupported
1940             ;;
1941         esac
1942
1943         # Disable a language that is unsupported by the target.
1944         case " $unsupported_languages " in
1945           *" $language "*)
1946             add_this_lang=unsupported
1947             ;;
1948         esac
1949
1950         case $add_this_lang in
1951           unsupported)
1952             # Remove language-dependent dirs.
1953             disabled_target_libs="$disabled_target_libs $target_libs"
1954             noconfigdirs="$noconfigdirs $lang_dirs"
1955             ;;
1956           no)
1957             # Remove language-dependent dirs; still show language as supported.
1958             disabled_target_libs="$disabled_target_libs $target_libs"
1959             noconfigdirs="$noconfigdirs $lang_dirs"
1960             potential_languages="${potential_languages}${language},"
1961             ;;
1962           yes)
1963             new_enable_languages="${new_enable_languages}${language},"
1964             potential_languages="${potential_languages}${language},"
1965             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1966             enabled_target_libs="$enabled_target_libs $target_libs"
1967             case "${boot_language}:,$enable_stage1_languages," in
1968               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1969                 # Add to (comma-separated) list of stage 1 languages.
1970                 case ",$stage1_languages," in
1971                   *,$language,* | ,yes, | ,all,) ;;
1972                   *) stage1_languages="${stage1_languages}${language}," ;;
1973                 esac
1974                 # We need to bootstrap any supporting libraries.
1975                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1976                 ;;
1977             esac
1978             ;;
1979         esac
1980         ;;
1981     esac
1982   done
1983
1984   # Add target libraries which are only needed for disabled languages
1985   # to noconfigdirs.
1986   if test -n "$disabled_target_libs"; then
1987     for dir in $disabled_target_libs; do
1988       case " $enabled_target_libs " in
1989       *" ${dir} "*) ;;
1990       *) noconfigdirs="$noconfigdirs $dir" ;;
1991       esac
1992     done
1993   fi
1994
1995   AC_ARG_ENABLE(stage1-languages,
1996   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1997                   [choose additional languages to build during
1998                   stage1.  Mostly useful for compiler development])],
1999   [case ,${enable_stage1_languages}, in
2000     ,no,|,,)
2001       # Set it to something that will have no effect in the loop below
2002       enable_stage1_languages=c ;;
2003     ,yes,)
2004       enable_stage1_languages=`echo $new_enable_languages | \
2005         sed -e "s/^,//" -e "s/,$//" ` ;;
2006     *,all,*)
2007       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2008         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2009   esac
2010
2011   # Add "good" languages from enable_stage1_languages to stage1_languages,
2012   # while "bad" languages go in missing_languages.  Leave no duplicates.
2013   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2014     case $potential_languages in
2015       *,$i,*)
2016         case $stage1_languages in
2017           *,$i,*) ;;
2018           *) stage1_languages="$stage1_languages$i," ;;
2019         esac ;;
2020       *)
2021         case $missing_languages in
2022           *,$i,*) ;;
2023           *) missing_languages="$missing_languages$i," ;;
2024         esac ;;
2025      esac
2026   done])
2027
2028   # Remove leading/trailing commas that were added for simplicity
2029   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2030   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2031   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2032   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2033
2034   if test "x$missing_languages" != x; then
2035     AC_MSG_ERROR([
2036 The following requested languages could not be built: ${missing_languages}
2037 Supported languages are: ${potential_languages}])
2038   fi
2039   if test "x$new_enable_languages" != "x$enable_languages"; then
2040     echo The following languages will be built: ${new_enable_languages}
2041     enable_languages="$new_enable_languages"
2042   fi
2043
2044   AC_SUBST(stage1_languages)
2045   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2046 fi
2047
2048 # Handle --disable-<component> generically.
2049 for dir in $configdirs $build_configdirs $target_configdirs ; do
2050   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2051   varname=`echo $dirname | sed -e s/+/_/g`
2052   if eval test x\${enable_${varname}} "=" xno ; then
2053     noconfigdirs="$noconfigdirs $dir"
2054   fi
2055 done
2056
2057 # Disable libcilkrts, libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2058 case ,${enable_languages}, in
2059   *,c++,*)
2060     # Disable libcilkrts, libitm, libsanitizer if we're not building libstdc++
2061     case "${noconfigdirs}" in
2062       *target-libstdc++-v3*)
2063         noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer"
2064         ;;
2065       *) ;;
2066     esac
2067     ;;
2068   *)
2069     noconfigdirs="$noconfigdirs target-libcilkrts target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2070     ;;
2071 esac
2072
2073 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2074 # $build_configdirs and $target_configdirs.
2075 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2076
2077 notsupp=""
2078 for dir in . $skipdirs $noconfigdirs ; do
2079   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2080   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2081     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2082     if test -r $srcdir/$dirname/configure ; then
2083       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2084         true
2085       else
2086         notsupp="$notsupp $dir"
2087       fi
2088     fi
2089   fi
2090   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2091     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2092     if test -r $srcdir/$dirname/configure ; then
2093       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2094         true
2095       else
2096         notsupp="$notsupp $dir"
2097       fi
2098     fi
2099   fi
2100   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2101     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2102     if test -r $srcdir/$dirname/configure ; then
2103       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2104         true
2105       else
2106         notsupp="$notsupp $dir"
2107       fi
2108     fi
2109   fi
2110 done
2111
2112 # Quietly strip out all directories which aren't configurable in this tree.
2113 # This relies on all configurable subdirectories being autoconfiscated, which
2114 # is now the case.
2115 build_configdirs_all="$build_configdirs"
2116 build_configdirs=
2117 for i in ${build_configdirs_all} ; do
2118   j=`echo $i | sed -e s/build-//g`
2119   if test -f ${srcdir}/$j/configure ; then
2120     build_configdirs="${build_configdirs} $i"
2121   fi
2122 done
2123
2124 configdirs_all="$configdirs"
2125 configdirs=
2126 for i in ${configdirs_all} ; do
2127   if test -f ${srcdir}/$i/configure ; then
2128     configdirs="${configdirs} $i"
2129   fi
2130 done
2131
2132 target_configdirs_all="$target_configdirs"
2133 target_configdirs=
2134 for i in ${target_configdirs_all} ; do
2135   j=`echo $i | sed -e s/target-//g`
2136   if test -f ${srcdir}/$j/configure ; then
2137     target_configdirs="${target_configdirs} $i"
2138   fi
2139 done
2140
2141 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2142 # so we have to add it after the preceding checks.
2143 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2144 then
2145   case " $configdirs " in
2146     *" libiberty "*)
2147       # If we can build libiberty, we can also build libiberty-linker-plugin.
2148       configdirs="$configdirs libiberty-linker-plugin"
2149       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2150         --with-libiberty=../libiberty-linker-plugin";;
2151     *)
2152       AC_MSG_ERROR([libiberty missing]);;
2153   esac
2154 fi
2155
2156 # Sometimes we have special requirements for the host libiberty.
2157 extra_host_libiberty_configure_flags=
2158 extra_host_zlib_configure_flags=
2159 case " $configdirs " in
2160   *" lto-plugin "* | *" libcc1 "*)
2161     # When these are to be built as shared libraries, the same applies to
2162     # libiberty.
2163     extra_host_libiberty_configure_flags=--enable-shared
2164     ;;
2165   *" bfd "*)
2166     # When bfd is to be built as a shared library, the same applies to
2167     # zlib.
2168     if test "$enable_shared" = "yes"; then
2169       extra_host_zlib_configure_flags=--enable-host-shared
2170     fi
2171     ;;
2172 esac
2173 AC_SUBST(extra_host_libiberty_configure_flags)
2174 AC_SUBST(extra_host_zlib_configure_flags)
2175
2176 # Produce a warning message for the subdirs we can't configure.
2177 # This isn't especially interesting in the Cygnus tree, but in the individual
2178 # FSF releases, it's important to let people know when their machine isn't
2179 # supported by the one or two programs in a package.
2180
2181 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2182   # If $appdirs is non-empty, at least one of those directories must still
2183   # be configured, or we error out.  (E.g., if the gas release supports a
2184   # specified target in some subdirs but not the gas subdir, we shouldn't
2185   # pretend that all is well.)
2186   if test -n "$appdirs" ; then
2187     for dir in $appdirs ; do
2188       if test -r $dir/Makefile.in ; then
2189         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2190           appdirs=""
2191           break
2192         fi
2193         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2194           appdirs=""
2195           break
2196         fi
2197       fi
2198     done
2199     if test -n "$appdirs" ; then
2200       echo "*** This configuration is not supported by this package." 1>&2
2201       exit 1
2202     fi
2203   fi
2204   # Okay, some application will build, or we don't care to check.  Still
2205   # notify of subdirs not getting built.
2206   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2207   echo "    ${notsupp}" 1>&2
2208   echo "    (Any other directories should still work fine.)" 1>&2
2209 fi
2210
2211 case "$host" in
2212   *msdosdjgpp*)
2213     enable_gdbtk=no ;;
2214 esac
2215
2216 # To find our prefix, in gcc_cv_tool_prefix.
2217 ACX_TOOL_DIRS
2218
2219 copy_dirs=
2220
2221 AC_ARG_WITH([build-sysroot],
2222   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2223                   [use sysroot as the system root during the build])],
2224   [if test x"$withval" != x ; then
2225      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2226    fi],
2227   [SYSROOT_CFLAGS_FOR_TARGET=])
2228 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2229
2230 AC_ARG_WITH([debug-prefix-map],
2231   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2232                   [map A to B, C to D ... in debug information])],
2233   [if test x"$withval" != x; then
2234      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2235      for debug_map in $withval; do
2236        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2237      done
2238    fi],
2239   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2240 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2241
2242 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2243 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2244 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2245 # We want to ensure that TARGET libraries (which we know are built with
2246 # gcc) are built with "-O2 -g", so include those options when setting
2247 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2248 if test "x$CFLAGS_FOR_TARGET" = x; then
2249   if test "x${is_cross_compiler}" = xyes; then
2250     CFLAGS_FOR_TARGET="-g -O2"
2251   else
2252     CFLAGS_FOR_TARGET=$CFLAGS
2253     case " $CFLAGS " in
2254       *" -O2 "*) ;;
2255       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2256     esac
2257     case " $CFLAGS " in
2258       *" -g "* | *" -g3 "*) ;;
2259       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2260     esac
2261   fi
2262 fi
2263 AC_SUBST(CFLAGS_FOR_TARGET)
2264
2265 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2266   if test "x${is_cross_compiler}" = xyes; then
2267     CXXFLAGS_FOR_TARGET="-g -O2"
2268   else
2269     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2270     case " $CXXFLAGS " in
2271       *" -O2 "*) ;;
2272       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2273     esac
2274     case " $CXXFLAGS " in
2275       *" -g "* | *" -g3 "*) ;;
2276       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2277     esac
2278   fi
2279 fi
2280 AC_SUBST(CXXFLAGS_FOR_TARGET)
2281
2282 AC_SUBST(LDFLAGS_FOR_TARGET)
2283
2284 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2285 # the named directory are copied to $(tooldir)/sys-include.
2286 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2287   if test x${is_cross_compiler} = xno ; then
2288     echo 1>&2 '***' --with-headers is only supported when cross compiling
2289     exit 1
2290   fi
2291   if test x"${with_headers}" != xyes ; then
2292     x=${gcc_cv_tool_prefix}
2293     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2294   fi
2295 fi
2296
2297 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2298 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2299 # are permitted.
2300 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2301   if test x${is_cross_compiler} = xno ; then
2302     echo 1>&2 '***' --with-libs is only supported when cross compiling
2303     exit 1
2304   fi
2305   if test x"${with_libs}" != xyes ; then
2306     # Copy the libraries in reverse order, so that files in the first named
2307     # library override files in subsequent libraries.
2308     x=${gcc_cv_tool_prefix}
2309     for l in ${with_libs}; do
2310       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2311     done
2312   fi
2313 fi
2314
2315 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2316 #
2317 # This is done by determining whether or not the appropriate directory
2318 # is available, and by checking whether or not specific configurations
2319 # have requested that this magic not happen.
2320 #
2321 # The command line options always override the explicit settings in
2322 # configure.ac, and the settings in configure.ac override this magic.
2323 #
2324 # If the default for a toolchain is to use GNU as and ld, and you don't
2325 # want to do that, then you should use the --without-gnu-as and
2326 # --without-gnu-ld options for the configure script.  Similarly, if
2327 # the default is to use the included zlib and you don't want to do that,
2328 # you should use the --with-system-zlib option for the configure script.
2329
2330 if test x${use_gnu_as} = x &&
2331    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2332   with_gnu_as=yes
2333   extra_host_args="$extra_host_args --with-gnu-as"
2334 fi
2335
2336 if test x${use_gnu_ld} = x &&
2337    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2338   with_gnu_ld=yes
2339   extra_host_args="$extra_host_args --with-gnu-ld"
2340 fi
2341
2342 if test x${use_included_zlib} = x &&
2343    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2344   :
2345 else
2346   with_system_zlib=yes
2347   extra_host_args="$extra_host_args --with-system-zlib"
2348 fi
2349
2350 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2351 # can detect this case.
2352
2353 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2354   with_newlib=yes
2355   extra_host_args="$extra_host_args --with-newlib"
2356 fi
2357
2358 # Handle ${copy_dirs}
2359 set fnord ${copy_dirs}
2360 shift
2361 while test $# != 0 ; do
2362   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2363     :
2364   else
2365     echo Copying $1 to $2
2366
2367     # Use the install script to create the directory and all required
2368     # parent directories.
2369     if test -d $2 ; then
2370       :
2371     else
2372       echo >config.temp
2373       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2374     fi
2375
2376     # Copy the directory, assuming we have tar.
2377     # FIXME: Should we use B in the second tar?  Not all systems support it.
2378     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2379
2380     # It is the responsibility of the user to correctly adjust all
2381     # symlinks.  If somebody can figure out how to handle them correctly
2382     # here, feel free to add the code.
2383
2384     echo $1 > $2/COPIED
2385   fi
2386   shift; shift
2387 done
2388
2389 # Determine a target-dependent exec_prefix that the installed
2390 # gcc will search in.  Keep this list sorted by triplet, with
2391 # the *-*-osname triplets last.
2392 md_exec_prefix=
2393 case "${target}" in
2394   i[[34567]]86-pc-msdosdjgpp*)
2395     md_exec_prefix=/dev/env/DJDIR/bin
2396     ;;
2397   *-*-hpux* | \
2398   *-*-nto-qnx* | \
2399   *-*-solaris2*)
2400     md_exec_prefix=/usr/ccs/bin
2401     ;;
2402 esac
2403
2404 extra_arflags_for_target=
2405 extra_nmflags_for_target=
2406 extra_ranlibflags_for_target=
2407 target_makefile_frag=/dev/null
2408 case "${target}" in
2409   spu-*-*)
2410     target_makefile_frag="config/mt-spu"
2411     ;;
2412   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2413     target_makefile_frag="config/mt-sde"
2414     ;;
2415   mipsisa*-*-elfoabi*)
2416     target_makefile_frag="config/mt-mips-elfoabi"
2417     ;;
2418   mips*-*-*linux* | mips*-*-gnu*)
2419     target_makefile_frag="config/mt-mips-gnu"
2420     ;;
2421   nios2-*-elf*)
2422     target_makefile_frag="config/mt-nios2-elf"
2423     ;;
2424   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2425     target_makefile_frag="config/mt-gnu"
2426     ;;
2427   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2428     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2429     # commands to handle both 32-bit and 64-bit objects.  These flags are
2430     # harmless if we're using GNU nm or ar.
2431     extra_arflags_for_target=" -X32_64"
2432     extra_nmflags_for_target=" -B -X32_64"
2433     ;;
2434 esac
2435
2436 alphaieee_frag=/dev/null
2437 case $target in
2438   alpha*-*-*)
2439     # This just makes sure to use the -mieee option to build target libs.
2440     # This should probably be set individually by each library.
2441     alphaieee_frag="config/mt-alphaieee"
2442     ;;
2443 esac
2444
2445 # If --enable-target-optspace always use -Os instead of -O2 to build
2446 # the target libraries, similarly if it is not specified, use -Os
2447 # on selected platforms.
2448 ospace_frag=/dev/null
2449 case "${enable_target_optspace}:${target}" in
2450   yes:*)
2451     ospace_frag="config/mt-ospace"
2452     ;;
2453   :d30v-*)
2454     ospace_frag="config/mt-d30v"
2455     ;;
2456   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2457     ospace_frag="config/mt-ospace"
2458     ;;
2459   no:* | :*)
2460     ;;
2461   *)
2462     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2463     ;;
2464 esac
2465
2466 # Some systems (e.g., one of the i386-aix systems the gas testers are
2467 # using) don't handle "\$" correctly, so don't use it here.
2468 tooldir='${exec_prefix}'/${target_noncanonical}
2469 build_tooldir=${tooldir}
2470
2471 # Create a .gdbinit file which runs the one in srcdir
2472 # and tells GDB to look there for source files.
2473
2474 if test -r ${srcdir}/.gdbinit ; then
2475   case ${srcdir} in
2476     .) ;;
2477     *) cat > ./.gdbinit <<EOF
2478 # ${NO_EDIT}
2479 dir ${srcdir}
2480 dir .
2481 source ${srcdir}/.gdbinit
2482 EOF
2483     ;;
2484   esac
2485 fi
2486
2487 # Make sure that the compiler is able to generate an executable.  If it
2488 # can't, we are probably in trouble.  We don't care whether we can run the
2489 # executable--we might be using a cross compiler--we only care whether it
2490 # can be created.  At this point the main configure script has set CC.
2491 we_are_ok=no
2492 echo "int main () { return 0; }" > conftest.c
2493 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2494 if test $? = 0 ; then
2495   if test -s conftest || test -s conftest.exe ; then
2496     we_are_ok=yes
2497   fi
2498 fi
2499 case $we_are_ok in
2500   no)
2501     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2502     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2503     rm -f conftest*
2504     exit 1
2505     ;;
2506 esac
2507 rm -f conftest*
2508
2509 # Decide which environment variable is used to find dynamic libraries.
2510 case "${host}" in
2511   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2512   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2513   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2514   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2515 esac
2516
2517 # On systems where the dynamic library environment variable is PATH,
2518 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2519 # built executables to PATH.
2520 if test "$RPATH_ENVVAR" = PATH; then
2521   GCC_SHLIB_SUBDIR=/shlib
2522 else
2523   GCC_SHLIB_SUBDIR=
2524 fi
2525
2526 # Adjust the toplevel makefile according to whether bootstrap was selected.
2527 case $enable_bootstrap in
2528   yes)
2529     bootstrap_suffix=bootstrap
2530     BUILD_CONFIG=bootstrap-debug
2531     ;;
2532   no)
2533     bootstrap_suffix=no-bootstrap
2534     BUILD_CONFIG=
2535     ;;
2536 esac
2537
2538 AC_MSG_CHECKING(for default BUILD_CONFIG)
2539
2540 AC_ARG_WITH([build-config],
2541   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2542                   [use config/NAME.mk build configuration])],
2543   [case $with_build_config in
2544    yes) with_build_config= ;;
2545    no) with_build_config= BUILD_CONFIG= ;;
2546    esac])
2547
2548 if test "x${with_build_config}" != x; then
2549   BUILD_CONFIG=$with_build_config
2550 else
2551   case $BUILD_CONFIG in
2552   bootstrap-debug)
2553     if echo "int f (void) { return 0; }" > conftest.c &&
2554        ${CC} -c conftest.c &&
2555        mv conftest.o conftest.o.g0 &&
2556        ${CC} -c -g conftest.c &&
2557        mv conftest.o conftest.o.g &&
2558        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2559       :
2560     else
2561       BUILD_CONFIG=
2562     fi
2563     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2564     ;;
2565   esac
2566 fi
2567 AC_MSG_RESULT($BUILD_CONFIG)
2568 AC_SUBST(BUILD_CONFIG)
2569
2570 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2571 AC_MSG_CHECKING([for --enable-vtable-verify])
2572 AC_ARG_ENABLE(vtable-verify,
2573 [AS_HELP_STRING([--enable-vtable-verify],
2574                 [Enable vtable verification feature])],
2575 [case "$enableval" in
2576  yes) enable_vtable_verify=yes ;;
2577  no)  enable_vtable_verify=no ;;
2578  *)   enable_vtable_verify=no;;
2579  esac],
2580 [enable_vtable_verify=no])
2581 AC_MSG_RESULT($enable_vtable_verify)
2582
2583 # Record target_configdirs and the configure arguments for target and
2584 # build configuration in Makefile.
2585 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2586 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2587 bootstrap_fixincludes=no
2588
2589 # If we are building libgomp, bootstrap it.
2590 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2591   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2592 fi
2593
2594 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2595 # or bootstrap-ubsan, bootstrap it.
2596 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2597   case "$BUILD_CONFIG" in
2598     *bootstrap-asan* | *bootstrap-ubsan* )
2599       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2600       bootstrap_fixincludes=yes
2601       ;;
2602   esac
2603 fi
2604
2605 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2606 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2607    test "$enable_vtable_verify" != no; then
2608   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2609 fi
2610
2611 # If we are building libmpx, bootstrap it.
2612 if echo " ${target_configdirs} " | grep " libmpx " > /dev/null 2>&1; then
2613   bootstrap_target_libs=${bootstrap_target_libs}target-libmpx,
2614 fi
2615
2616 # Determine whether gdb needs tk/tcl or not.
2617 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2618 # and in that case we want gdb to be built without tk.  Ugh!
2619 # In fact I believe gdb is the *only* package directly dependent on tk,
2620 # so we should be able to put the 'maybe's in unconditionally and
2621 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2622 # 100% sure that that's safe though.
2623
2624 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2625 case "$enable_gdbtk" in
2626   no)
2627     GDB_TK="" ;;
2628   yes)
2629     GDB_TK="${gdb_tk}" ;;
2630   *)
2631     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2632     # distro.  Eventually someone will fix this and move Insight, nee
2633     # gdbtk to a separate directory.
2634     if test -d ${srcdir}/gdb/gdbtk ; then
2635       GDB_TK="${gdb_tk}"
2636     else
2637       GDB_TK=""
2638     fi
2639     ;;
2640 esac
2641 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2642 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2643
2644 # Strip out unwanted targets.
2645
2646 # While at that, we remove Makefiles if we were started for recursive
2647 # configuration, so that the top-level Makefile reconfigures them,
2648 # like we used to do when configure itself was recursive.
2649
2650 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2651 # but now we're fixing up the Makefile ourselves with the additional
2652 # commands passed to AC_CONFIG_FILES.  Use separate variables
2653 # extrasub-{build,host,target} not because there is any reason to split
2654 # the substitutions up that way, but only to remain below the limit of
2655 # 99 commands in a script, for HP-UX sed.
2656 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2657
2658 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2659   yes:yes:*\ gold\ *:*,c++,*) ;;
2660   yes:yes:*\ gold\ *:*)
2661     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2662     ;;
2663 esac
2664
2665 extrasub_build=
2666 for module in ${build_configdirs} ; do
2667   if test -z "${no_recursion}" \
2668      && test -f ${build_subdir}/${module}/Makefile; then
2669     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2670     rm -f ${build_subdir}/${module}/Makefile
2671   fi
2672   extrasub_build="$extrasub_build
2673 /^@if build-$module\$/d
2674 /^@endif build-$module\$/d
2675 /^@if build-$module-$bootstrap_suffix\$/d
2676 /^@endif build-$module-$bootstrap_suffix\$/d"
2677 done
2678 extrasub_host=
2679 for module in ${configdirs} ; do
2680   if test -z "${no_recursion}"; then
2681     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2682       if test -f ${file}; then
2683         echo 1>&2 "*** removing ${file} to force reconfigure"
2684         rm -f ${file}
2685       fi
2686     done
2687   fi
2688   case ${module},${bootstrap_fixincludes} in
2689     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2690     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2691   esac
2692   extrasub_host="$extrasub_host
2693 /^@if $module\$/d
2694 /^@endif $module\$/d
2695 /^@if $module-$host_bootstrap_suffix\$/d
2696 /^@endif $module-$host_bootstrap_suffix\$/d"
2697 done
2698 extrasub_target=
2699 for module in ${target_configdirs} ; do
2700   if test -z "${no_recursion}" \
2701      && test -f ${target_subdir}/${module}/Makefile; then
2702     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2703     rm -f ${target_subdir}/${module}/Makefile
2704   fi
2705
2706   # We only bootstrap target libraries listed in bootstrap_target_libs.
2707   case $bootstrap_target_libs in
2708     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2709     *) target_bootstrap_suffix=no-bootstrap ;;
2710   esac
2711
2712   extrasub_target="$extrasub_target
2713 /^@if target-$module\$/d
2714 /^@endif target-$module\$/d
2715 /^@if target-$module-$target_bootstrap_suffix\$/d
2716 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2717 done
2718
2719 # Do the final fixup along with target modules.
2720 extrasub_target="$extrasub_target
2721 /^@if /,/^@endif /d"
2722
2723 # Create the serialization dependencies.  This uses a temporary file.
2724
2725 AC_ARG_ENABLE([serial-configure],
2726 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2727                 [force sequential configuration of
2728                  sub-packages for the host, target or build
2729                  machine, or all sub-packages])])
2730
2731 case ${enable_serial_configure} in
2732   yes)
2733     enable_serial_build_configure=yes
2734     enable_serial_host_configure=yes
2735     enable_serial_target_configure=yes
2736     ;;
2737 esac
2738
2739 # These force 'configure's to be done one at a time, to avoid problems
2740 # with contention over a shared config.cache.
2741 rm -f serdep.tmp
2742 echo '# serdep.tmp' > serdep.tmp
2743 olditem=
2744 test "x${enable_serial_build_configure}" = xyes &&
2745 for item in ${build_configdirs} ; do
2746   case ${olditem} in
2747     "") ;;
2748     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2749   esac
2750   olditem=${item}
2751 done
2752 olditem=
2753 test "x${enable_serial_host_configure}" = xyes &&
2754 for item in ${configdirs} ; do
2755   case ${olditem} in
2756     "") ;;
2757     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2758   esac
2759   olditem=${item}
2760 done
2761 olditem=
2762 test "x${enable_serial_target_configure}" = xyes &&
2763 for item in ${target_configdirs} ; do
2764   case ${olditem} in
2765     "") ;;
2766     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2767   esac
2768   olditem=${item}
2769 done
2770 serialization_dependencies=serdep.tmp
2771 AC_SUBST_FILE(serialization_dependencies)
2772
2773 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2774 # target, nonopt, and variable assignments.  These are the ones we
2775 # might not want to pass down to subconfigures.  The exception being
2776 # --cache-file=/dev/null, which is used to turn off the use of cache
2777 # files altogether, and which should be passed on to subconfigures.
2778 # Also strip program-prefix, program-suffix, and program-transform-name,
2779 # so that we can pass down a consistent program-transform-name.
2780 baseargs=
2781 tbaseargs=
2782 keep_next=no
2783 skip_next=no
2784 eval "set -- $ac_configure_args"
2785 for ac_arg
2786 do
2787   if test X"$skip_next" = X"yes"; then
2788     skip_next=no
2789     continue
2790   fi
2791   if test X"$keep_next" = X"yes"; then
2792     case $ac_arg in
2793       *\'*)
2794         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2795     esac
2796     baseargs="$baseargs '$ac_arg'"
2797     tbaseargs="$tbaseargs '$ac_arg'"
2798     keep_next=no
2799     continue
2800   fi
2801
2802   # Handle separated arguments.  Based on the logic generated by
2803   # autoconf 2.59.
2804   case $ac_arg in
2805     *=* | --config-cache | -C | -disable-* | --disable-* \
2806       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2807       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2808       | -with-* | --with-* | -without-* | --without-* | --x)
2809       separate_arg=no
2810       ;;
2811     -*)
2812       separate_arg=yes
2813       ;;
2814     *)
2815       separate_arg=no
2816       ;;
2817   esac
2818
2819   skip_targ=no
2820   case $ac_arg in
2821 changequote(,)
2822   --with-* | --without-*)
2823     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2824
2825     case $libopt in
2826     *[-_]include)
2827       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2828       ;;
2829     *[-_]lib)
2830       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2831       ;;
2832     *)
2833       lib=$libopt
2834       ;;
2835     esac
2836 changequote([,])
2837
2838     case $lib in
2839     mpc | mpfr | gmp | isl)
2840       # If we're processing --with-$lib, --with-$lib-include or
2841       # --with-$lib-lib, for one of the libs above, and target is
2842       # different from host, don't pass the current argument to any
2843       # target library's configure.
2844       if test x$is_cross_compiler = xyes; then
2845         skip_targ=yes
2846       fi
2847       ;;
2848     esac
2849     ;;
2850   esac
2851
2852   case "$ac_arg" in
2853     --cache-file=/dev/null | \
2854     -cache-file=/dev/null )
2855       # Handled here to avoid the test to skip args below.
2856       baseargs="$baseargs '$ac_arg'"
2857       tbaseargs="$tbaseargs '$ac_arg'"
2858       # Assert: $separate_arg should always be no.
2859       keep_next=$separate_arg
2860       ;;
2861     --no*)
2862       continue
2863       ;;
2864     --c* | \
2865     --sr* | \
2866     --ho* | \
2867     --bu* | \
2868     --t* | \
2869     --program-* | \
2870     -cache_file* | \
2871     -srcdir* | \
2872     -host* | \
2873     -build* | \
2874     -target* | \
2875     -program-prefix* | \
2876     -program-suffix* | \
2877     -program-transform-name* )
2878       skip_next=$separate_arg
2879       continue
2880       ;;
2881     -*)
2882       # An option.  Add it.
2883       case $ac_arg in
2884         *\'*)
2885           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2886       esac
2887       baseargs="$baseargs '$ac_arg'"
2888       if test X"$skip_targ" = Xno; then
2889         tbaseargs="$tbaseargs '$ac_arg'"
2890       fi
2891       keep_next=$separate_arg
2892       ;;
2893     *)
2894       # Either a variable assignment, or a nonopt (triplet).  Don't
2895       # pass it down; let the Makefile handle this.
2896       continue
2897       ;;
2898   esac
2899 done
2900 # Remove the initial space we just introduced and, as these will be
2901 # expanded by make, quote '$'.
2902 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2903
2904 # Add in --program-transform-name, after --program-prefix and
2905 # --program-suffix have been applied to it.  Autoconf has already
2906 # doubled dollar signs and backslashes in program_transform_name; we want
2907 # the backslashes un-doubled, and then the entire thing wrapped in single
2908 # quotes, because this will be expanded first by make and then by the shell.
2909 # Also, because we want to override the logic in subdir configure scripts to
2910 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2911 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2912 ${program_transform_name}
2913 EOF_SED
2914 gcc_transform_name=`cat conftestsed.out`
2915 rm -f conftestsed.out
2916 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2917 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2918 if test "$silent" = yes; then
2919   baseargs="$baseargs --silent"
2920   tbaseargs="$tbaseargs --silent"
2921 fi
2922 baseargs="$baseargs --disable-option-checking"
2923 tbaseargs="$tbaseargs --disable-option-checking"
2924
2925 # Record and document user additions to sub configure arguments.
2926 AC_ARG_VAR([build_configargs],
2927            [additional configure arguments for build directories])
2928 AC_ARG_VAR([host_configargs],
2929            [additional configure arguments for host directories])
2930 AC_ARG_VAR([target_configargs],
2931            [additional configure arguments for target directories])
2932
2933 # For the build-side libraries, we just need to pretend we're native,
2934 # and not use the same cache file.  Multilibs are neither needed nor
2935 # desired.  We can't even use the same cache file for all build-side
2936 # libraries, as they're compiled differently; some with C, some with
2937 # C++ or with different feature-enabling options.
2938 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
2939
2940 # For host modules, accept cache file option, or specification as blank.
2941 case "${cache_file}" in
2942 "") # empty
2943   cache_file_option="" ;;
2944 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2945   cache_file_option="--cache-file=${cache_file}" ;;
2946 *) # relative path
2947   cache_file_option="--cache-file=../${cache_file}" ;;
2948 esac
2949
2950 # Host dirs don't like to share a cache file either, horribly enough.
2951 # This seems to be due to autoconf 2.5x stupidity.
2952 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2953
2954 target_configargs="$target_configargs ${tbaseargs}"
2955
2956 # Passing a --with-cross-host argument lets the target libraries know
2957 # whether they are being built with a cross-compiler or being built
2958 # native.  However, it would be better to use other mechanisms to make the
2959 # sorts of decisions they want to make on this basis.  Please consider
2960 # this option to be deprecated.  FIXME.
2961 if test x${is_cross_compiler} = xyes ; then
2962   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2963 fi
2964
2965 # Special user-friendly check for native x86_64-linux build, if
2966 # multilib is not explicitly enabled.
2967 case "$target:$have_compiler:$host:$target:$enable_multilib" in
2968   x86_64-*linux*:yes:$build:$build:)
2969     # Make sure we have a development environment that handles 32-bit
2970     dev64=no
2971     echo "int main () { return 0; }" > conftest.c
2972     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2973     if test $? = 0 ; then
2974       if test -s conftest || test -s conftest.exe ; then
2975         dev64=yes
2976       fi
2977     fi
2978     rm -f conftest*
2979     if test x${dev64} != xyes ; then
2980       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
2981     fi
2982     ;;
2983 esac
2984
2985 # Default to --enable-multilib.
2986 if test x${enable_multilib} = x ; then
2987   target_configargs="--enable-multilib ${target_configargs}"
2988 fi
2989
2990 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2991 # changed from the earlier setting of with_newlib.
2992 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2993   target_configargs="--with-newlib ${target_configargs}"
2994 fi
2995
2996 # Different target subdirs use different values of certain variables
2997 # (notably CXX).  Worse, multilibs use *lots* of different values.
2998 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2999 # it doesn't automatically accept command-line overrides of them.
3000 # This means it's not safe for target subdirs to share a cache file,
3001 # which is disgusting, but there you have it.  Hopefully this can be
3002 # fixed in future.  It's still worthwhile to use a cache file for each
3003 # directory.  I think.
3004
3005 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3006 # We need to pass --target, as newer autoconf's requires consistency
3007 # for target_alias and gcc doesn't manage it consistently.
3008 target_configargs="--cache-file=./config.cache ${target_configargs}"
3009
3010 FLAGS_FOR_TARGET=
3011 case " $target_configdirs " in
3012  *" newlib "*)
3013   case " $target_configargs " in
3014   *" --with-newlib "*)
3015    case "$target" in
3016     *-cygwin*)
3017       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3018       ;;
3019    esac
3020
3021    # If we're not building GCC, don't discard standard headers.
3022    if test -d ${srcdir}/gcc; then
3023      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3024
3025      if test "${build}" != "${host}"; then
3026        # On Canadian crosses, CC_FOR_TARGET will have already been set
3027        # by `configure', so we won't have an opportunity to add -Bgcc/
3028        # to it.  This is right: we don't want to search that directory
3029        # for binaries, but we want the header files in there, so add
3030        # them explicitly.
3031        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3032
3033        # Someone might think of using the pre-installed headers on
3034        # Canadian crosses, in case the installed compiler is not fully
3035        # compatible with the compiler being built.  In this case, it
3036        # would be better to flag an error than risking having
3037        # incompatible object files being constructed.  We can't
3038        # guarantee that an error will be flagged, but let's hope the
3039        # compiler will do it, when presented with incompatible header
3040        # files.
3041      fi
3042    fi
3043
3044    case "${target}-${is_cross_compiler}" in
3045    i[[3456789]]86-*-linux*-no)
3046       # Here host == target, so we don't need to build gcc,
3047       # so we don't want to discard standard headers.
3048       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3049       ;;
3050    *)
3051       # If we're building newlib, use its generic headers last, but search
3052       # for any libc-related directories first (so make it the last -B
3053       # switch).
3054       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3055
3056       # If we're building libgloss, find the startup file, simulator library
3057       # and linker script.
3058       case " $target_configdirs " in
3059         *" libgloss "*)
3060         # Look for startup file, simulator library and maybe linker script.
3061         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3062         # Look for libnosys.a in case the target needs it.
3063         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3064         # Most targets have the linker script in the source directory.
3065         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3066         ;;
3067       esac
3068       ;;
3069    esac
3070    ;;
3071   esac
3072   ;;
3073 esac
3074
3075 case "$target" in
3076   x86_64-*mingw* | *-w64-mingw*)
3077   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3078   # however, use a symlink named 'mingw' in ${prefix} .
3079     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3080     ;;
3081   *-mingw*)
3082   # MinGW can't be handled as Cygwin above since it does not use newlib.
3083     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3084     ;;
3085 esac
3086
3087 # Allow the user to override the flags for
3088 # our build compiler if desired.
3089 if test x"${build}" = x"${host}" ; then
3090   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3091   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3092   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3093 fi
3094
3095 # On Canadian crosses, we'll be searching the right directories for
3096 # the previously-installed cross compiler, so don't bother to add
3097 # flags for directories within the install tree of the compiler
3098 # being built; programs in there won't even run.
3099 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3100   # Search for pre-installed headers if nothing else fits.
3101   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3102 fi
3103
3104 if test "x${use_gnu_ld}" = x &&
3105    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3106   # Arrange for us to find uninstalled linker scripts.
3107   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3108 fi
3109
3110 # Search for other target-specific linker scripts and such.
3111 case "${target}" in
3112   mep*)
3113     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3114     ;;
3115 esac
3116
3117 # Makefile fragments.
3118 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3119 do
3120   eval fragval=\$$frag
3121   if test $fragval != /dev/null; then
3122     eval $frag=${srcdir}/$fragval
3123   fi
3124 done
3125 AC_SUBST_FILE(host_makefile_frag)
3126 AC_SUBST_FILE(target_makefile_frag)
3127 AC_SUBST_FILE(alphaieee_frag)
3128 AC_SUBST_FILE(ospace_frag)
3129
3130 # Miscellanea: directories, flags, etc.
3131 AC_SUBST(RPATH_ENVVAR)
3132 AC_SUBST(GCC_SHLIB_SUBDIR)
3133 AC_SUBST(tooldir)
3134 AC_SUBST(build_tooldir)
3135 AC_SUBST(CONFIGURE_GDB_TK)
3136 AC_SUBST(GDB_TK)
3137 AC_SUBST(INSTALL_GDB_TK)
3138
3139 # Build module lists & subconfigure args.
3140 AC_SUBST(build_configargs)
3141 AC_SUBST(build_configdirs)
3142
3143 # Host module lists & subconfigure args.
3144 AC_SUBST(host_configargs)
3145 AC_SUBST(configdirs)
3146 AC_SUBST(target_configdirs)
3147
3148 # Target module lists & subconfigure args.
3149 AC_SUBST(target_configargs)
3150
3151
3152 # Build tools.
3153 AC_SUBST(AR_FOR_BUILD)
3154 AC_SUBST(AS_FOR_BUILD)
3155 AC_SUBST(CC_FOR_BUILD)
3156 AC_SUBST(CFLAGS_FOR_BUILD)
3157 AC_SUBST(CXXFLAGS_FOR_BUILD)
3158 AC_SUBST(CXX_FOR_BUILD)
3159 AC_SUBST(DLLTOOL_FOR_BUILD)
3160 AC_SUBST(GCJ_FOR_BUILD)
3161 AC_SUBST(GFORTRAN_FOR_BUILD)
3162 AC_SUBST(GOC_FOR_BUILD)
3163 AC_SUBST(LDFLAGS_FOR_BUILD)
3164 AC_SUBST(LD_FOR_BUILD)
3165 AC_SUBST(NM_FOR_BUILD)
3166 AC_SUBST(RANLIB_FOR_BUILD)
3167 AC_SUBST(WINDMC_FOR_BUILD)
3168 AC_SUBST(WINDRES_FOR_BUILD)
3169
3170 # Generate default definitions for YACC, M4, LEX and other programs that run
3171 # on the build machine.  These are used if the Makefile can't locate these
3172 # programs in objdir.
3173 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3174
3175 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3176 case " $build_configdirs " in
3177   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3178 esac
3179
3180 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3181 case " $build_configdirs " in
3182   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3183 esac
3184
3185 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3186 case " $build_configdirs " in
3187   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3188 esac
3189
3190 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3191 case " $build_configdirs " in
3192   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3193   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3194 esac
3195
3196 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3197 case " $build_configdirs " in
3198   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3199 esac
3200
3201 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3202 case " $build_configdirs " in
3203   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3204   *)
3205 changequote(,)
3206     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3207     # higher, else we use the "missing" dummy.
3208     if ${MAKEINFO} --version \
3209        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3210       :
3211     else
3212       MAKEINFO="$MISSING makeinfo"
3213     fi
3214     ;;
3215 changequote([,])
3216 esac
3217
3218 # FIXME: expect and dejagnu may become build tools?
3219
3220 AC_CHECK_PROGS(EXPECT, expect, expect)
3221 case " $configdirs " in
3222   *" expect "*)
3223     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3224     ;;
3225 esac
3226
3227 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3228 case " $configdirs " in
3229   *" dejagnu "*)
3230     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3231     ;;
3232 esac
3233
3234
3235 # Host tools.
3236 NCN_STRICT_CHECK_TOOLS(AR, ar)
3237 NCN_STRICT_CHECK_TOOLS(AS, as)
3238 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3239 NCN_STRICT_CHECK_TOOLS(LD, ld)
3240 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3241 NCN_STRICT_CHECK_TOOLS(NM, nm)
3242 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3243 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3244 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3245 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3246 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3247 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3248 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3249 AC_SUBST(CC)
3250 AC_SUBST(CXX)
3251 AC_SUBST(CFLAGS)
3252 AC_SUBST(CXXFLAGS)
3253
3254 # Target tools.
3255 AC_ARG_WITH([build-time-tools],
3256   [AS_HELP_STRING([--with-build-time-tools=PATH],
3257                   [use given path to find target tools during the build])],
3258   [case x"$withval" in
3259      x/*) ;;
3260      *)
3261        with_build_time_tools=
3262        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3263        ;;
3264    esac],
3265   [with_build_time_tools=])
3266
3267 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3268 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3269 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3270 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3271 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3272 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3273
3274 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3275 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3276 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3277 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3278 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3279 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3280 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3281 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3282 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3283 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3284 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3285 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3286 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3287
3288 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3289
3290 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3291 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3292 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3293 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3294 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3295                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3296                 c++)
3297 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3298                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3299                 c++)
3300 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3301 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3302 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3303                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3304 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3305                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3306 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3307 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3308 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3309 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3310 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3311 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3312 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3313 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3314 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3315 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3316
3317 AC_SUBST(FLAGS_FOR_TARGET)
3318 AC_SUBST(RAW_CXX_FOR_TARGET)
3319
3320 # Certain tools may need extra flags.
3321 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3322 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3323 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3324
3325 # When building target libraries, except in a Canadian cross, we use
3326 # the same toolchain as the compiler we just built.
3327 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3328 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3329 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3330 if test $host = $build; then
3331   case " $configdirs " in
3332     *" gcc "*)
3333       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3334       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3335       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3336       ;;
3337   esac
3338 fi
3339
3340 AC_SUBST(COMPILER_AS_FOR_TARGET)
3341 AC_SUBST(COMPILER_LD_FOR_TARGET)
3342 AC_SUBST(COMPILER_NM_FOR_TARGET)
3343
3344 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3345 AC_ARG_ENABLE(maintainer-mode,
3346 [AS_HELP_STRING([--enable-maintainer-mode],
3347                 [enable make rules and dependencies not useful
3348                  (and sometimes confusing) to the casual installer])],
3349       USE_MAINTAINER_MODE=$enableval,
3350       USE_MAINTAINER_MODE=no)
3351 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3352 AC_SUBST(MAINTAINER_MODE_TRUE)
3353 AC_SUBST(MAINTAINER_MODE_FALSE)
3354 if test "$USE_MAINTAINER_MODE" = yes; then
3355   MAINTAINER_MODE_TRUE=
3356   MAINTAINER_MODE_FALSE='#'
3357 else
3358   MAINTAINER_MODE_TRUE='#'
3359   MAINTAINER_MODE_FALSE=
3360 fi
3361 MAINT=$MAINTAINER_MODE_TRUE
3362 AC_SUBST(MAINT)dnl
3363
3364 # ---------------------
3365 # GCC bootstrap support
3366 # ---------------------
3367
3368 # Stage specific cflags for build.
3369 stage1_cflags="-g"
3370 case $build in
3371   vax-*-*)
3372     case ${GCC} in
3373       yes) stage1_cflags="-g -Wa,-J" ;;
3374       *) stage1_cflags="-g -J" ;;
3375     esac ;;
3376 esac
3377
3378 AC_SUBST(stage1_cflags)
3379
3380 # Enable --enable-checking in stage1 of the compiler.
3381 AC_ARG_ENABLE(stage1-checking,
3382 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3383                 [choose additional checking for stage1 of the compiler])],
3384 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3385 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3386   # For --disable-checking or implicit --enable-checking=release, avoid
3387   # setting --enable-checking=gc in the default stage1 checking for LTO
3388   # bootstraps.  See PR62077.
3389   case $BUILD_CONFIG in
3390     *lto*)
3391       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3392     *)
3393       stage1_checking=--enable-checking=yes,types;;
3394   esac
3395   if test "x$enable_checking" = x && \
3396      test -d ${srcdir}/gcc && \
3397      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3398     stage1_checking=--enable-checking=yes,types,extra
3399   fi
3400 else
3401   stage1_checking=--enable-checking=$enable_checking,types
3402 fi])
3403 AC_SUBST(stage1_checking)
3404
3405 # Enable -Werror in bootstrap stage2 and later.
3406 AC_ARG_ENABLE(werror,
3407 [AS_HELP_STRING([--enable-werror],
3408                 [enable -Werror in bootstrap stage2 and later])], [],
3409 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3410   enable_werror=yes
3411 else
3412   enable_werror=no
3413 fi])
3414 case ${enable_werror} in
3415   yes) stage2_werror_flag="--enable-werror-always" ;;
3416   *) stage2_werror_flag="" ;;
3417 esac
3418 AC_SUBST(stage2_werror_flag)
3419
3420 # Enable --enable-host-shared.
3421 AC_ARG_ENABLE(host-shared,
3422 [AS_HELP_STRING([--enable-host-shared],
3423                 [build host code as shared libraries])],
3424 [host_shared=$enableval], [host_shared=no])
3425 AC_SUBST(host_shared)
3426
3427 # PR jit/64780: Require the user to explicitly specify
3428 # --enable-host-shared if the jit is enabled, hinting
3429 # that they might want to do a separate configure/build of
3430 # the jit, to avoid users from slowing down the rest of the
3431 # compiler by enabling the jit.
3432 if test ${host_shared} = "no" ; then
3433   case "${enable_languages}" in
3434     *jit*)
3435       AC_MSG_ERROR([
3436 Enabling language "jit" requires --enable-host-shared.
3437
3438 --enable-host-shared typically slows the rest of the compiler down by
3439 a few %, so you must explicitly enable it.
3440
3441 If you want to build both the jit and the regular compiler, it is often
3442 best to do this via two separate configure/builds, in separate
3443 directories, to avoid imposing the performance cost of
3444 --enable-host-shared on the regular compiler.])
3445       ;;
3446     *)
3447       ;;
3448   esac
3449 fi
3450
3451 # Specify what files to not compare during bootstrap.
3452
3453 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3454 case "$target" in
3455   hppa*64*-*-hpux*) ;;
3456   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3457   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3458 esac
3459 AC_SUBST(compare_exclusions)
3460
3461 AC_CONFIG_FILES([Makefile],
3462   [sed "$extrasub_build" Makefile |
3463    sed "$extrasub_host" |
3464    sed "$extrasub_target" > mf$$
3465    mv -f mf$$ Makefile],
3466   [extrasub_build="$extrasub_build"
3467    extrasub_host="$extrasub_host"
3468    extrasub_target="$extrasub_target"])
3469 AC_OUTPUT