configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/gcc-plugin.m4)
  27 m4_include(config/ax_cxx_compile_stdcxx.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT(move-if-change)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty build-libcpp"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #f
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 145
 146 # these libraries are built for the target environment, and are built after
 147 # the host libraries and the host tools (which may be a cross compiler)
 148 # Note that libiberty is not a target library.
 149 target_libraries="target-libgcc \
 150                 target-libbacktrace \
 151                 target-libgloss \
 152                 target-newlib \
 153                 target-libgomp \
 154                 target-liboffloadmic \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 252 # is provided.
 253 if test x$with_system_readline = xyes ; then
 254   noconfigdirs="$noconfigdirs readline"
 255 fi
 256
 257 AC_ARG_WITH(zstd,
 258 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 259
 260 # some tools are so dependent upon X11 that if we're not building with X,
 261 # it's not even worth trying to configure, much less build, that tool.
 262
 263 case ${with_x} in
 264   yes | "") ;; # the default value for this tree is that X11 is available
 265   no)
 266     skipdirs="${skipdirs} tk itcl libgui"
 267     # We won't be able to build gdbtk without X.
 268     enable_gdbtk=no
 269     ;;
 270   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 271 esac
 272
 273 # Some are only suitable for cross toolchains.
 274 # Remove these if host=target.
 275 cross_only="target-libgloss target-newlib target-opcodes"
 276
 277 case $is_cross_compiler in
 278   no) skipdirs="${skipdirs} ${cross_only}" ;;
 279 esac
 280
 281 # If both --with-headers and --with-libs are specified, default to
 282 # --without-newlib.
 283 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 284    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 285   if test x"${with_newlib}" = x ; then
 286     with_newlib=no
 287   fi
 288 fi
 289
 290 # Recognize --with-newlib/--without-newlib.
 291 case ${with_newlib} in
 292   no) skipdirs="${skipdirs} target-newlib" ;;
 293   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 294 esac
 295
 296 AC_ARG_ENABLE(as-accelerator-for,
 297 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 298                 [build as offload target compiler.
 299                 Specify offload host triple by ARG])])
 300
 301 AC_ARG_ENABLE(offload-targets,
 302 [AS_HELP_STRING([--enable-offload-targets=LIST],
 303                 [enable offloading to devices from comma-separated LIST of
 304                 TARGET[=DIR]. Use optional path to find offload target compiler
 305                 during the build])],
 306 [
 307   if test x"$enable_offload_targets" = x; then
 308     AC_MSG_ERROR([no offload targets specified])
 309   fi
 310 ], [enable_offload_targets=])
 311
 312 AC_ARG_ENABLE(offload-defaulted,
 313 [AS_HELP_STRING([--enable-offload-defaulted]
 314                 [If enabled, configured but not installed offload compilers and
 315                 libgomp plugins are silently ignored.  Useful for distribution
 316                 compilers where those are in separate optional packages.])],
 317 [enable_offload_defaulted=$enableval],
 318 [enable_offload_defaulted=])
 319
 320 # Handle --enable-gold, --enable-ld.
 321 # --disable-gold [--enable-ld]
 322 #     Build only ld.  Default option.
 323 # --enable-gold [--enable-ld]
 324 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 325 #     as "ld.bfd" and "ld".
 326 # --enable-gold=default [--enable-ld]
 327 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 328 #     install ld as "ld.bfd".
 329 # --enable-gold[=default] --disable-ld
 330 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 331 # --enable-gold --enable-ld=default
 332 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 333 #     and ld.bfd).
 334 #     In other words, ld is default
 335 # --enable-gold=default --enable-ld=default
 336 #     Error.
 337
 338 default_ld=
 339 AC_ARG_ENABLE(gold,
 340 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 341                 [build gold @<:@ARG={default,yes,no}@:>@])],
 342 ENABLE_GOLD=$enableval,
 343 ENABLE_GOLD=no)
 344 case "${ENABLE_GOLD}" in
 345   yes|default)
 346     # Check for ELF target.
 347     is_elf=no
 348     case "${target}" in
 349       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 350       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 351       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 352       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 353         case "${target}" in
 354           *-*-linux*aout* | *-*-linux*oldld*)
 355             ;;
 356           *)
 357             is_elf=yes
 358             ;;
 359         esac
 360     esac
 361
 362     if test "$is_elf" = "yes"; then
 363       # Check for target supported by gold.
 364       case "${target}" in
 365         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 366         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 367           configdirs="$configdirs gold"
 368           if test x${ENABLE_GOLD} = xdefault; then
 369             default_ld=gold
 370           fi
 371           ENABLE_GOLD=yes
 372           ;;
 373       esac
 374     fi
 375     ;;
 376   no)
 377     ;;
 378   *)
 379     AC_MSG_ERROR([invalid --enable-gold argument])
 380     ;;
 381 esac
 382
 383 AC_ARG_ENABLE(ld,
 384 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 385                 [build ld @<:@ARG={default,yes,no}@:>@])],
 386 ENABLE_LD=$enableval,
 387 ENABLE_LD=yes)
 388
 389 case "${ENABLE_LD}" in
 390   default)
 391     if test x${default_ld} != x; then
 392       AC_MSG_ERROR([either gold or ld can be the default ld])
 393     fi
 394     ;;
 395   yes)
 396     ;;
 397   no)
 398     if test x${ENABLE_GOLD} != xyes; then
 399       AC_MSG_WARN([neither ld nor gold are enabled])
 400     fi
 401     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 402     ;;
 403   *)
 404     AC_MSG_ERROR([invalid --enable-ld argument])
 405     ;;
 406 esac
 407
 408 AC_ARG_ENABLE(gprofng,
 409 [AS_HELP_STRING([[--enable-gprofng[=ARG]]],
 410                 [build gprofng @<:@ARG={yes,no}@:>@])],
 411 enable_gprofng=$enableval,
 412 enable_gprofng=yes)
 413 if test "$enable_gprofng" = "yes"; then
 414   case "${target}" in
 415     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux*)
 416     configdirs="$configdirs gprofng"
 417     ;;
 418   esac
 419 fi
 420
 421
 422 # PR gas/19109
 423 # Decide the default method for compressing debug sections.
 424 # Provide a configure time option to override our default.
 425 AC_ARG_ENABLE(compressed_debug_sections,
 426 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 427                 [Enable compressed debug sections for gas, gold or ld by
 428                  default])],
 429 [
 430   if test x"$enable_compressed_debug_sections" = xyes; then
 431     AC_MSG_ERROR([no program with compressed debug sections specified])
 432   fi
 433 ], [enable_compressed_debug_sections=])
 434
 435 # Select default compression algorithm.
 436 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 437 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 438                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 439 [], [default_compressed_debug_sections_algorithm=])
 440
 441 # Configure extra directories which are host specific
 442
 443 case "${host}" in
 444   *-cygwin*)
 445     configdirs="$configdirs libtermcap" ;;
 446 esac
 447
 448 # A target can indicate whether a language isn't supported for some reason.
 449 # Only spaces may be used in this macro; not newlines or tabs.
 450 unsupported_languages=
 451
 452 # Remove more programs from consideration, based on the host or
 453 # target this usually means that a port of the program doesn't
 454 # exist yet.
 455
 456 case "${host}" in
 457   i[[3456789]]86-*-msdosdjgpp*)
 458     noconfigdirs="$noconfigdirs tcl tk itcl"
 459     ;;
 460 esac
 461
 462 # Default to --disable-year2038 until we can handle differences between
 463 # projects that use gnulib (which understands year 2038) and projects that
 464 # do not (like BFD).
 465 AC_ARG_ENABLE(year2038,
 466 AS_HELP_STRING([--enable-year2038],
 467   [enable support for timestamps past the year 2038]),
 468 ENABLE_YEAR2038=$enableval,
 469 ENABLE_YEAR2038=no)
 470 enable_year2038=
 471 if test "${ENABLE_YEAR2038}" = "no" ; then
 472   enable_year2038=no
 473 fi
 474
 475 AC_ARG_ENABLE(libquadmath,
 476 AS_HELP_STRING([--disable-libquadmath],
 477   [do not build libquadmath directory]),
 478 ENABLE_LIBQUADMATH=$enableval,
 479 ENABLE_LIBQUADMATH=yes)
 480 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 481   noconfigdirs="$noconfigdirs target-libquadmath"
 482 fi
 483
 484
 485 AC_ARG_ENABLE(libquadmath-support,
 486 AS_HELP_STRING([--disable-libquadmath-support],
 487   [disable libquadmath support for Fortran]),
 488 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 489 ENABLE_LIBQUADMATH_SUPPORT=yes)
 490 enable_libquadmath_support=
 491 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 492   enable_libquadmath_support=no
 493 fi
 494
 495
 496 AC_ARG_ENABLE(libada,
 497 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 498 ENABLE_LIBADA=$enableval,
 499 ENABLE_LIBADA=yes)
 500 if test "${ENABLE_LIBADA}" != "yes" ; then
 501   noconfigdirs="$noconfigdirs gnattools"
 502 fi
 503
 504 AC_ARG_ENABLE(libssp,
 505 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 506 ENABLE_LIBSSP=$enableval,
 507 ENABLE_LIBSSP=yes)
 508
 509 AC_ARG_ENABLE(libstdcxx,
 510 AS_HELP_STRING([--disable-libstdcxx],
 511   [do not build libstdc++-v3 directory]),
 512 ENABLE_LIBSTDCXX=$enableval,
 513 ENABLE_LIBSTDCXX=default)
 514 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 515   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 516 fi]
 517
 518 # If this is accelerator compiler and its target is intelmic we enable
 519 # target liboffloadmic by default.  If this is compiler with offloading
 520 # for intelmic we enable host liboffloadmic by default.  Otherwise
 521 # liboffloadmic is disabled by default.
 522 AC_ARG_ENABLE([liboffloadmic],
 523 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 524                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 525 [case "$enableval" in
 526   no | host | target)
 527     enable_liboffloadmic=$enableval ;;
 528   *)
 529     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 530 esac],
 531 [if test x"$enable_as_accelerator_for" != x; then
 532   case "${target}" in
 533     *-intelmic-* | *-intelmicemul-*)
 534       enable_liboffloadmic=target
 535       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 536       ;;
 537     *)
 538       enable_liboffloadmic=no
 539       ;;
 540   esac
 541 else
 542   case "${enable_offload_targets}" in
 543     *-intelmic-* | *-intelmicemul-*)
 544       enable_liboffloadmic=host
 545       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 546       ;;
 547     *)
 548       enable_liboffloadmic=no
 549       ;;
 550     esac
 551 fi])
 552 AC_SUBST(extra_liboffloadmic_configure_flags)
 553
 554 # Enable libgomp by default on hosted POSIX systems, and a few others.
 555 if test x$enable_libgomp = x ; then
 556     case "${target}" in
 557     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 558         ;;
 559     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 560         ;;
 561     *-*-solaris2* | *-*-hpux11*)
 562         ;;
 563     *-*-darwin* | *-*-aix*)
 564         ;;
 565     nvptx*-*-* | amdgcn*-*-*)
 566         ;;
 567     *)
 568         noconfigdirs="$noconfigdirs target-libgomp"
 569         ;;
 570     esac
 571 fi
 572
 573 # Disable libatomic on unsupported systems.
 574 if test -d ${srcdir}/libatomic; then
 575     if test x$enable_libatomic = x; then
 576         AC_MSG_CHECKING([for libatomic support])
 577         if (srcdir=${srcdir}/libatomic; \
 578                 . ${srcdir}/configure.tgt; \
 579                 test -n "$UNSUPPORTED")
 580         then
 581             AC_MSG_RESULT([no])
 582             noconfigdirs="$noconfigdirs target-libatomic"
 583         else
 584             AC_MSG_RESULT([yes])
 585         fi
 586     fi
 587 fi
 588
 589 # Disable liboffloadmic on unsupported systems.
 590 if test -d ${srcdir}/liboffloadmic; then
 591     if test x$enable_liboffloadmic != xno; then
 592         AC_MSG_CHECKING([for liboffloadmic support])
 593         if (srcdir=${srcdir}/liboffloadmic; \
 594                 . ${srcdir}/configure.tgt; \
 595                 test -n "$UNSUPPORTED")
 596         then
 597             AC_MSG_RESULT([no])
 598             noconfigdirs="$noconfigdirs target-liboffloadmic"
 599         else
 600             AC_MSG_RESULT([yes])
 601         fi
 602     fi
 603 fi
 604
 605 # Disable libitm on unsupported systems.
 606 if test -d ${srcdir}/libitm; then
 607     if test x$enable_libitm = x; then
 608         AC_MSG_CHECKING([for libitm support])
 609         if (srcdir=${srcdir}/libitm; \
 610                 . ${srcdir}/configure.tgt; \
 611                 test -n "$UNSUPPORTED")
 612         then
 613             AC_MSG_RESULT([no])
 614             noconfigdirs="$noconfigdirs target-libitm"
 615         else
 616             AC_MSG_RESULT([yes])
 617         fi
 618     fi
 619 fi
 620
 621 # Disable libsanitizer on unsupported systems.
 622 if test -d ${srcdir}/libsanitizer; then
 623     if test x$enable_libsanitizer = x; then
 624         AC_MSG_CHECKING([for libsanitizer support])
 625         if (srcdir=${srcdir}/libsanitizer; \
 626                 . ${srcdir}/configure.tgt; \
 627                 test -n "$UNSUPPORTED")
 628         then
 629             AC_MSG_RESULT([no])
 630             noconfigdirs="$noconfigdirs target-libsanitizer"
 631         else
 632             AC_MSG_RESULT([yes])
 633         fi
 634     fi
 635 fi
 636
 637 # Disable libvtv on unsupported systems.
 638 if test -d ${srcdir}/libvtv; then
 639     if test x$enable_libvtv = x; then
 640         AC_MSG_CHECKING([for libvtv support])
 641         if (srcdir=${srcdir}/libvtv; \
 642                 . ${srcdir}/configure.tgt; \
 643                 test "$VTV_SUPPORTED" != "yes")
 644         then
 645             AC_MSG_RESULT([no])
 646             noconfigdirs="$noconfigdirs target-libvtv"
 647         else
 648             AC_MSG_RESULT([yes])
 649         fi
 650     fi
 651 fi
 652
 653 # Disable libquadmath for some systems.
 654 case "${target}" in
 655   avr-*-*)
 656     noconfigdirs="$noconfigdirs target-libquadmath"
 657     ;;
 658   # libquadmath is unused on AIX and libquadmath build process use of
 659   # LD_LIBRARY_PATH can break AIX bootstrap.
 660   powerpc-*-aix* | rs6000-*-aix*)
 661     noconfigdirs="$noconfigdirs target-libquadmath"
 662     ;;
 663 esac
 664
 665 # Disable libssp for some systems.
 666 case "${target}" in
 667   avr-*-*)
 668     # No hosted I/O support.
 669     noconfigdirs="$noconfigdirs target-libssp"
 670     ;;
 671   bpf-*-*)
 672     noconfigdirs="$noconfigdirs target-libssp"
 673     ;;
 674   powerpc-*-aix* | rs6000-*-aix*)
 675     noconfigdirs="$noconfigdirs target-libssp"
 676     ;;
 677   pru-*-*)
 678     # No hosted I/O support.
 679     noconfigdirs="$noconfigdirs target-libssp"
 680     ;;
 681   rl78-*-*)
 682     # libssp uses a misaligned load to trigger a fault, but the RL78
 683     # doesn't fault for those - instead, it gives a build-time error
 684     # for explicit misaligned loads.
 685     noconfigdirs="$noconfigdirs target-libssp"
 686     ;;
 687   visium-*-*)
 688     # No hosted I/O support.
 689     noconfigdirs="$noconfigdirs target-libssp"
 690     ;;
 691 esac
 692
 693 # Disable libstdc++-v3 for some systems.
 694 # Allow user to override this if they pass --enable-libstdcxx
 695 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 696   case "${target}" in
 697     *-*-vxworks*)
 698       # VxWorks uses the Dinkumware C++ library.
 699       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 700       ;;
 701     amdgcn*-*-*)
 702       # Not ported/fails to build when using newlib.
 703       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 704       ;;
 705     arm*-wince-pe*)
 706       # the C++ libraries don't build on top of CE's C libraries
 707       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 708       ;;
 709     avr-*-*)
 710       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 711       ;;
 712     bpf-*-*)
 713       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 714       ;;
 715     ft32-*-*)
 716       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 717       ;;
 718   esac
 719 fi
 720
 721 # Disable C++ on systems where it is known to not work.
 722 # For testing, you can override this with --enable-languages=c++.
 723 case ,${enable_languages}, in
 724   *,c++,*)
 725     ;;
 726   *)
 727       case "${target}" in
 728         bpf-*-*)
 729           unsupported_languages="$unsupported_languages c++"
 730           ;;
 731       esac
 732       ;;
 733 esac
 734
 735 # Disable Objc on systems where it is known to not work.
 736 # For testing, you can override this with --enable-languages=objc.
 737 case ,${enable_languages}, in
 738   *,objc,*)
 739     ;;
 740   *)
 741       case "${target}" in
 742         bpf-*-*)
 743           unsupported_languages="$unsupported_languages objc"
 744           ;;
 745       esac
 746       ;;
 747 esac
 748
 749 # Disable D on systems where it is known to not work.
 750 # For testing, you can override this with --enable-languages=d.
 751 case ,${enable_languages}, in
 752   *,d,*)
 753     ;;
 754   *)
 755     case "${target}" in
 756       bpf-*-*)
 757         unsupported_languages="$unsupported_languages d"
 758         ;;
 759     esac
 760     ;;
 761 esac
 762
 763 # Disable libphobos on unsupported systems.
 764 # For testing, you can override this with --enable-libphobos.
 765 if test -d ${srcdir}/libphobos; then
 766     if test x$enable_libphobos = x; then
 767         AC_MSG_CHECKING([for libphobos support])
 768         if (srcdir=${srcdir}/libphobos; \
 769                 . ${srcdir}/configure.tgt; \
 770                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 771         then
 772             AC_MSG_RESULT([no])
 773             noconfigdirs="$noconfigdirs target-libphobos"
 774         else
 775             AC_MSG_RESULT([yes])
 776         fi
 777     fi
 778 fi
 779
 780 # Disable Fortran for some systems.
 781 case "${target}" in
 782   mmix-*-*)
 783     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 784     unsupported_languages="$unsupported_languages fortran"
 785     ;;
 786   bpf-*-*)
 787     unsupported_languages="$unsupported_languages fortran"
 788     ;;
 789 esac
 790
 791 # Disable libffi for some systems.
 792 case "${target}" in
 793   powerpc-*-darwin*)
 794     ;;
 795   i[[3456789]]86-*-darwin*)
 796     ;;
 797   x86_64-*-darwin[[912]]*)
 798     ;;
 799   *-*-darwin*)
 800     noconfigdirs="$noconfigdirs target-libffi"
 801     ;;
 802   *-*-netware*)
 803     noconfigdirs="$noconfigdirs target-libffi"
 804     ;;
 805   *-*-phoenix*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   *-*-rtems*)
 809     noconfigdirs="$noconfigdirs target-libffi"
 810     ;;
 811   *-*-tpf*)
 812     noconfigdirs="$noconfigdirs target-libffi"
 813     ;;
 814   *-*-uclinux*)
 815     noconfigdirs="$noconfigdirs target-libffi"
 816     ;;
 817   *-*-vxworks*)
 818     noconfigdirs="$noconfigdirs target-libffi"
 819     ;;
 820   aarch64*-*-freebsd*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   alpha*-*-*vms*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826   arm*-*-freebsd*)
 827     noconfigdirs="$noconfigdirs target-libffi"
 828     ;;
 829   arm-wince-pe)
 830     noconfigdirs="$noconfigdirs target-libffi"
 831     ;;
 832   arm*-*-symbianelf*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   bpf-*-*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838   cris-*-* | crisv32-*-*)
 839     case "${target}" in
 840       *-*-linux*)
 841         ;;
 842       *) # See PR46792 regarding target-libffi.
 843         noconfigdirs="$noconfigdirs target-libffi";;
 844     esac
 845     ;;
 846   hppa*64*-*-hpux*)
 847     noconfigdirs="$noconfigdirs target-libffi"
 848     ;;
 849   hppa*-hp-hpux11*)
 850     ;;
 851   hppa*-*-hpux*)
 852     noconfigdirs="$noconfigdirs target-libffi"
 853     ;;
 854   ia64*-*-*vms*)
 855     noconfigdirs="$noconfigdirs target-libffi"
 856     ;;
 857   i[[3456789]]86-w64-mingw*)
 858     noconfigdirs="$noconfigdirs target-libffi"
 859     ;;
 860   i[[3456789]]86-*-mingw*)
 861     noconfigdirs="$noconfigdirs target-libffi"
 862     ;;
 863   x86_64-*-mingw*)
 864     noconfigdirs="$noconfigdirs target-libffi"
 865     ;;
 866   mmix-*-*)
 867     noconfigdirs="$noconfigdirs target-libffi"
 868     ;;
 869   powerpc-*-aix*)
 870     ;;
 871   rs6000-*-aix*)
 872     ;;
 873   ft32-*-*)
 874     noconfigdirs="$noconfigdirs target-libffi"
 875     ;;
 876   *-*-lynxos*)
 877     noconfigdirs="$noconfigdirs target-libffi"
 878     ;;
 879 esac
 880
 881 # Disable the go frontend on systems where it is known to not work. Please keep
 882 # this in sync with contrib/config-list.mk.
 883 case "${target}" in
 884 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 885     unsupported_languages="$unsupported_languages go"
 886     ;;
 887 esac
 888
 889 # Only allow gdbserver on some systems.
 890 if test -d ${srcdir}/gdbserver; then
 891     if test x$enable_gdbserver = x; then
 892         AC_MSG_CHECKING([for gdbserver support])
 893         if (srcdir=${srcdir}/gdbserver; \
 894                 . ${srcdir}/configure.srv; \
 895                 test -n "$UNSUPPORTED")
 896         then
 897             AC_MSG_RESULT([no])
 898             noconfigdirs="$noconfigdirs gdbserver"
 899         else
 900             AC_MSG_RESULT([yes])
 901         fi
 902     fi
 903 fi
 904
 905 # Disable libgo for some systems where it is known to not work.
 906 # For testing, you can easily override this with --enable-libgo.
 907 if test x$enable_libgo = x; then
 908     case "${target}" in
 909     *-*-darwin*)
 910         # PR 46986
 911         noconfigdirs="$noconfigdirs target-libgo"
 912         ;;
 913     *-*-cygwin* | *-*-mingw*)
 914         noconfigdirs="$noconfigdirs target-libgo"
 915         ;;
 916     bpf-*-*)
 917         noconfigdirs="$noconfigdirs target-libgo"
 918         ;;
 919     esac
 920 fi
 921
 922 # Default libgloss CPU subdirectory.
 923 libgloss_dir="$target_cpu"
 924
 925 case "${target}" in
 926   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 927     libgloss_dir=wince
 928     ;;
 929   aarch64*-*-* )
 930     libgloss_dir=aarch64
 931     ;;
 932   arm*-*-*)
 933     libgloss_dir=arm
 934     ;;
 935   cris-*-* | crisv32-*-*)
 936     libgloss_dir=cris
 937     ;;
 938   hppa*-*-*)
 939     libgloss_dir=pa
 940     ;;
 941   i[[3456789]]86-*-*)
 942     libgloss_dir=i386
 943     ;;
 944   loongarch*-*-*)
 945     libgloss_dir=loongarch
 946     ;;
 947   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 948     libgloss_dir=m68hc11
 949     ;;
 950   m68*-*-* | fido-*-*)
 951     libgloss_dir=m68k
 952     ;;
 953   mips*-*-*)
 954     libgloss_dir=mips
 955     ;;
 956   powerpc*-*-*)
 957     libgloss_dir=rs6000
 958     ;;
 959   pru-*-*)
 960     libgloss_dir=pru
 961     ;;
 962   sparc*-*-*)
 963     libgloss_dir=sparc
 964     ;;
 965 esac
 966
 967 # Disable newlib and libgloss for various target OSes.
 968 case "${target}" in
 969   alpha*-dec-osf*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   i[[3456789]]86-*-linux*)
 973     # This section makes it possible to build newlib natively on linux.
 974     # If we are using a cross compiler then don't configure newlib.
 975     if test x${is_cross_compiler} != xno ; then
 976       noconfigdirs="$noconfigdirs target-newlib"
 977     fi
 978     noconfigdirs="$noconfigdirs target-libgloss"
 979     # If we are not using a cross compiler, do configure newlib.
 980     # Note however, that newlib will only be configured in this situation
 981     # if the --with-newlib option has been given, because otherwise
 982     # 'target-newlib' will appear in skipdirs.
 983     ;;
 984   i[[3456789]]86-*-rdos*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990   sparc-*-sunos4*)
 991     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 992     ;;
 993   bpf-*-*)
 994     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 995     ;;
 996   *-*-aix*)
 997     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 998     ;;
 999   *-*-beos*)
1000     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     ;;
1002   *-*-chorusos)
1003     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1004     ;;
1005   *-*-dragonfly*)
1006     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1007     ;;
1008   *-*-freebsd*)
1009     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1010     ;;
1011   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1012     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1013     ;;
1014   *-*-lynxos*)
1015     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1016     ;;
1017   *-*-mingw*)
1018     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1019     ;;
1020   *-*-netbsd*)
1021     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1022     ;;
1023   *-*-netware*)
1024     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1025     ;;
1026   *-*-tpf*)
1027     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1028     ;;
1029   *-*-uclinux*)
1030     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1031     ;;
1032   *-*-vxworks*)
1033     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1034     ;;
1035 esac
1036
1037 case "${target}" in
1038   *-*-chorusos)
1039     ;;
1040   aarch64-*-darwin*)
1041     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1042     noconfigdirs="$noconfigdirs sim target-rda"
1043     ;;
1044   amdgcn*-*-*)
1045     ;;
1046   arm-*-darwin*)
1047     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1048     noconfigdirs="$noconfigdirs sim target-rda"
1049     ;;
1050   powerpc-*-darwin*)
1051     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1052     noconfigdirs="$noconfigdirs sim target-rda"
1053     ;;
1054   i[[3456789]]86-*-darwin*)
1055     noconfigdirs="$noconfigdirs ld gprof"
1056     noconfigdirs="$noconfigdirs sim target-rda"
1057     ;;
1058   x86_64-*-darwin[[912]]*)
1059     noconfigdirs="$noconfigdirs ld gas gprof"
1060     noconfigdirs="$noconfigdirs sim target-rda"
1061     ;;
1062   *-*-darwin*)
1063     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1064     noconfigdirs="$noconfigdirs sim target-rda"
1065     ;;
1066   *-*-dragonfly*)
1067     ;;
1068   *-*-freebsd*)
1069     if test "x$with_gmp" = x \
1070         && ! test -d ${srcdir}/gmp \
1071         && test -f /usr/local/include/gmp.h; then
1072       with_gmp=/usr/local
1073     fi
1074     ;;
1075   *-*-kaos*)
1076     # Remove unsupported stuff on all kaOS configurations.
1077     noconfigdirs="$noconfigdirs target-libgloss"
1078     ;;
1079   *-*-netbsd*)
1080     ;;
1081   *-*-netware*)
1082     ;;
1083   *-*-phoenix*)
1084     noconfigdirs="$noconfigdirs target-libgloss"
1085     ;;
1086   *-*-rtems*)
1087     noconfigdirs="$noconfigdirs target-libgloss"
1088     ;;
1089     # The tpf target doesn't support gdb yet.
1090   *-*-tpf*)
1091     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1092     ;;
1093   *-*-uclinux*)
1094     noconfigdirs="$noconfigdirs target-rda"
1095     ;;
1096   *-*-vxworks*)
1097     ;;
1098   alpha*-dec-osf*)
1099     # ld works, but does not support shared libraries.
1100     # gas doesn't generate exception information.
1101     noconfigdirs="$noconfigdirs gas ld"
1102     ;;
1103   alpha*-*-*vms*)
1104     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1105     ;;
1106   alpha*-*-*)
1107     # newlib is not 64 bit ready
1108     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1109     ;;
1110   bpf-*-*)
1111     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1112     ;;
1113   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1114     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1115     ;;
1116   arc*-*-*)
1117     noconfigdirs="$noconfigdirs sim"
1118     ;;
1119   arm-*-pe*)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   arm-*-riscix*)
1123     noconfigdirs="$noconfigdirs ld target-libgloss"
1124     ;;
1125   avr-*-*)
1126     if test x${with_avrlibc} != xno; then
1127       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1128     fi
1129     ;;
1130   c4x-*-* | tic4x-*-*)
1131     noconfigdirs="$noconfigdirs target-libgloss"
1132     ;;
1133   tic54x-*-*)
1134     noconfigdirs="$noconfigdirs target-libgloss gdb"
1135     ;;
1136   d10v-*-*)
1137     noconfigdirs="$noconfigdirs target-libgloss"
1138     ;;
1139   d30v-*-*)
1140     noconfigdirs="$noconfigdirs gdb"
1141     ;;
1142   fr30-*-elf*)
1143     noconfigdirs="$noconfigdirs gdb"
1144     ;;
1145   ft32-*-*)
1146     noconfigdirs="$noconfigdirs target-rda gprof"
1147     ;;
1148   moxie-*-*)
1149     noconfigdirs="$noconfigdirs"
1150     ;;
1151   h8300*-*-*)
1152     noconfigdirs="$noconfigdirs target-libgloss"
1153     ;;
1154   h8500-*-*)
1155     noconfigdirs="$noconfigdirs target-libgloss"
1156     ;;
1157   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1158     ;;
1159   hppa*64*-*-hpux*)
1160     noconfigdirs="$noconfigdirs gdb"
1161     ;;
1162   hppa*-*-hpux11*)
1163     noconfigdirs="$noconfigdirs gdb ld"
1164     ;;
1165   hppa*64*-*-linux*)
1166     ;;
1167   hppa*-*-linux*)
1168     ;;
1169   hppa*-*-*elf* | \
1170   hppa*-*-lites* | \
1171   hppa*-*-openbsd* | \
1172   hppa*64*-*-*)
1173     ;;
1174   hppa*-*-pro*)
1175     ;;
1176   hppa*-*-*)
1177     noconfigdirs="$noconfigdirs ld"
1178     ;;
1179   i960-*-*)
1180     noconfigdirs="$noconfigdirs gdb"
1181     ;;
1182   ia64*-*-elf*)
1183     # No gdb support yet.
1184     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1185     ;;
1186   ia64*-**-hpux*)
1187     # No ld support yet.
1188     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1189     ;;
1190   ia64*-*-*vms*)
1191     # No ld support yet.
1192     noconfigdirs="$noconfigdirs libgui itcl ld"
1193     ;;
1194   i[[3456789]]86-w64-mingw*)
1195     ;;
1196   i[[3456789]]86-*-mingw*)
1197     target_configdirs="$target_configdirs target-winsup"
1198     ;;
1199   *-*-cygwin*)
1200     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1201     noconfigdirs="$noconfigdirs target-libgloss"
1202     # always build newlib if winsup directory is present.
1203     if test -d "$srcdir/winsup/cygwin"; then
1204       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1205     elif test -d "$srcdir/newlib"; then
1206       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1207     fi
1208     ;;
1209   i[[3456789]]86-*-pe)
1210     noconfigdirs="$noconfigdirs target-libgloss"
1211     ;;
1212   i[[3456789]]86-*-sco3.2v5*)
1213     # The linker does not yet know about weak symbols in COFF,
1214     # and is not configured to handle mixed ELF and COFF.
1215     noconfigdirs="$noconfigdirs ld target-libgloss"
1216     ;;
1217   i[[3456789]]86-*-sco*)
1218     noconfigdirs="$noconfigdirs gprof target-libgloss"
1219     ;;
1220   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1221     noconfigdirs="$noconfigdirs target-libgloss"
1222     ;;
1223   i[[3456789]]86-*-sysv4*)
1224     noconfigdirs="$noconfigdirs target-libgloss"
1225     ;;
1226   i[[3456789]]86-*-beos*)
1227     noconfigdirs="$noconfigdirs gdb"
1228     ;;
1229   i[[3456789]]86-*-rdos*)
1230     noconfigdirs="$noconfigdirs gdb"
1231     ;;
1232   mmix-*-*)
1233     noconfigdirs="$noconfigdirs gdb"
1234     ;;
1235   mt-*-*)
1236     noconfigdirs="$noconfigdirs sim"
1237     ;;
1238   nfp-*-*)
1239     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1240     noconfigdirs="$noconfigdirs $target_libraries"
1241     ;;
1242   pdp11-*-*)
1243     noconfigdirs="$noconfigdirs gdb gprof"
1244     ;;
1245   powerpc-*-aix*)
1246     # copied from rs6000-*-* entry
1247     noconfigdirs="$noconfigdirs gprof"
1248     ;;
1249   powerpc*-*-winnt* | powerpc*-*-pe*)
1250     target_configdirs="$target_configdirs target-winsup"
1251     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1252     # always build newlib.
1253     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1254     ;;
1255     # This is temporary until we can link against shared libraries
1256   powerpcle-*-solaris*)
1257     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1258     ;;
1259   powerpc-*-beos*)
1260     noconfigdirs="$noconfigdirs gdb"
1261     ;;
1262   rs6000-*-lynxos*)
1263     noconfigdirs="$noconfigdirs gprof"
1264     ;;
1265   rs6000-*-aix*)
1266     noconfigdirs="$noconfigdirs gprof"
1267     ;;
1268   rs6000-*-*)
1269     noconfigdirs="$noconfigdirs gprof"
1270     ;;
1271   m68k-apollo-*)
1272     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1273     ;;
1274   microblaze*)
1275     noconfigdirs="$noconfigdirs gprof"
1276     ;;
1277   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1278     if test x$with_newlib = xyes; then
1279       noconfigdirs="$noconfigdirs gprof"
1280     fi
1281     ;;
1282   mips*-*-irix5*)
1283     noconfigdirs="$noconfigdirs gprof target-libgloss"
1284     ;;
1285   mips*-*-irix6*)
1286     noconfigdirs="$noconfigdirs gprof target-libgloss"
1287     ;;
1288   mips*-*-bsd*)
1289     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1290     ;;
1291   mips*-*-linux*)
1292     ;;
1293   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1294   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1295     noconfigdirs="$noconfigdirs ld gas gprof"
1296     ;;
1297   mips*-*-*)
1298     noconfigdirs="$noconfigdirs gprof"
1299     ;;
1300   nvptx*-*-*)
1301     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1302     ;;
1303   sh-*-*)
1304     case "${target}" in
1305       sh*-*-elf)
1306          ;;
1307       *)
1308          noconfigdirs="$noconfigdirs target-libgloss" ;;
1309     esac
1310     ;;
1311   sparc-*-sunos4*)
1312     if test x${is_cross_compiler} = xno ; then
1313            use_gnu_ld=no
1314     fi
1315     ;;
1316   tic6x-*-*)
1317     noconfigdirs="$noconfigdirs sim"
1318     ;;
1319   tilepro*-*-* | tilegx*-*-*)
1320     noconfigdirs="$noconfigdirs sim"
1321     ;;
1322   v810-*-*)
1323     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1324     ;;
1325   vax-*-*)
1326     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1327     ;;
1328   wasm32-*-*)
1329     noconfigdirs="$noconfigdirs ld"
1330     ;;
1331   loongarch*-*-linux*)
1332     ;;
1333   loongarch*-*-*)
1334     noconfigdirs="$noconfigdirs gprof"
1335     ;;
1336 esac
1337
1338 # If we aren't building newlib, then don't build libgloss, since libgloss
1339 # depends upon some newlib header files.
1340 case "${noconfigdirs}" in
1341   *target-libgloss*) ;;
1342   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1343 esac
1344
1345 # Work in distributions that contain no compiler tools, like Autoconf.
1346 host_makefile_frag=/dev/null
1347 if test -d ${srcdir}/config ; then
1348 case "${host}" in
1349   i[[3456789]]86-*-msdosdjgpp*)
1350     host_makefile_frag="config/mh-djgpp"
1351     ;;
1352   *-cygwin*)
1353     ACX_CHECK_CYGWIN_CAT_WORKS
1354     host_makefile_frag="config/mh-cygwin"
1355     ;;
1356   *-mingw*)
1357     host_makefile_frag="config/mh-mingw"
1358     ;;
1359   alpha*-linux*)
1360     host_makefile_frag="config/mh-alpha-linux"
1361     ;;
1362   hppa*-hp-hpux10*)
1363     host_makefile_frag="config/mh-pa-hpux10"
1364     ;;
1365   hppa*-hp-hpux*)
1366     host_makefile_frag="config/mh-pa"
1367     ;;
1368   hppa*-*)
1369     host_makefile_frag="config/mh-pa"
1370     ;;
1371   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1372     host_makefile_frag="config/mh-darwin"
1373     ;;
1374   powerpc-*-aix*)
1375     host_makefile_frag="config/mh-ppc-aix"
1376     ;;
1377   rs6000-*-aix*)
1378     host_makefile_frag="config/mh-ppc-aix"
1379     ;;
1380 esac
1381 fi
1382
1383 if test "${build}" != "${host}" ; then
1384   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1385   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1386   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1387   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1388   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1389   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1390   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1391   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1392   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1393   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1394   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1395   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1396   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1397   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1398   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1399 else
1400   AR_FOR_BUILD="\$(AR)"
1401   AS_FOR_BUILD="\$(AS)"
1402   CC_FOR_BUILD="\$(CC)"
1403   CXX_FOR_BUILD="\$(CXX)"
1404   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1405   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1406   GOC_FOR_BUILD="\$(GOC)"
1407   GDC_FOR_BUILD="\$(GDC)"
1408   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1409   LD_FOR_BUILD="\$(LD)"
1410   NM_FOR_BUILD="\$(NM)"
1411   RANLIB_FOR_BUILD="\$(RANLIB)"
1412   WINDRES_FOR_BUILD="\$(WINDRES)"
1413   WINDMC_FOR_BUILD="\$(WINDMC)"
1414 fi
1415
1416 AC_PROG_CC_C99
1417 AC_PROG_CXX
1418
1419 # We must set the default linker to the linker used by gcc for the correct
1420 # operation of libtool.  If LD is not defined and we are using gcc, try to
1421 # set the LD default to the ld used by gcc.
1422 if test -z "$LD"; then
1423   if test "$GCC" = yes; then
1424     case $build in
1425     *-*-mingw*)
1426       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1427     *)
1428       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1429     esac
1430     case $gcc_prog_ld in
1431     # Accept absolute paths.
1432     [[\\/]* | [A-Za-z]:[\\/]*)]
1433       LD="$gcc_prog_ld" ;;
1434     esac
1435   fi
1436 fi
1437
1438 # Check whether -static-libstdc++ -static-libgcc is supported.
1439 have_static_libs=no
1440 if test "$GCC" = yes; then
1441   saved_LDFLAGS="$LDFLAGS"
1442
1443   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1444   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1445   AC_LANG_PUSH(C++)
1446   AC_LINK_IFELSE([AC_LANG_SOURCE([
1447 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1448 #error -static-libstdc++ not implemented
1449 #endif
1450 int main() {}])],
1451     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1452     [AC_MSG_RESULT([no])])
1453   AC_LANG_POP(C++)
1454
1455   LDFLAGS="$saved_LDFLAGS"
1456 fi
1457
1458 ACX_PROG_GNAT
1459 ACX_PROG_GDC
1460 ACX_PROG_CMP_IGNORE_INITIAL
1461
1462 AC_ARG_ENABLE([bootstrap],
1463 [AS_HELP_STRING([--enable-bootstrap],
1464                 [enable bootstrapping @<:@yes if native build@:>@])],,
1465 enable_bootstrap=default)
1466
1467 # Issue errors and warnings for invalid/strange bootstrap combinations.
1468 if test -r $srcdir/gcc/configure; then
1469   have_compiler=yes
1470 else
1471   have_compiler=no
1472 fi
1473
1474 case "$have_compiler:$host:$target:$enable_bootstrap" in
1475   *:*:*:no) ;;
1476
1477   # Default behavior.  Enable bootstrap if we have a compiler
1478   # and we are in a native configuration.
1479   yes:$build:$build:default)
1480     enable_bootstrap=yes ;;
1481
1482   *:*:*:default)
1483     enable_bootstrap=no ;;
1484
1485   # We have a compiler and we are in a native configuration, bootstrap is ok
1486   yes:$build:$build:yes)
1487     ;;
1488
1489   # Other configurations, but we have a compiler.  Assume the user knows
1490   # what he's doing.
1491   yes:*:*:yes)
1492     AC_MSG_WARN([trying to bootstrap a cross compiler])
1493     ;;
1494
1495   # No compiler: if they passed --enable-bootstrap explicitly, fail
1496   no:*:*:yes)
1497     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1498
1499   # Fail if wrong command line
1500   *)
1501     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1502     ;;
1503 esac
1504
1505 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1506 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1507 # require C++11 (or higher).
1508 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1509   CXX="$CXX -std=c++11"
1510 elif test "$have_compiler" = yes; then
1511   AX_CXX_COMPILE_STDCXX(11)
1512
1513   if test "${build}" != "${host}"; then
1514     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1515   fi
1516 fi
1517
1518 AC_ARG_ENABLE([pgo-build],
1519 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1520                 [enable the PGO build])],
1521 [enable_pgo_build=$enableval],
1522 [enable_pgo_build=no])
1523
1524 # Issue errors and warnings for invalid/strange PGO build combinations.
1525 case "$have_compiler:$host:$target:$enable_pgo_build" in
1526   *:*:*:no) ;;
1527
1528   # Allow the PGO build only if we aren't building a compiler and
1529   # we are in a native configuration.
1530   no:$build:$build:yes | no:$build:$build:lto) ;;
1531
1532   # Disallow the PGO bootstrap if we are building a compiler.
1533   yes:*:*:yes | yes:*:*:lto)
1534     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1535
1536   *)
1537     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1538     ;;
1539 esac
1540
1541 if test "$enable_pgo_build" != "no"; then
1542   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1543   old_CFLAGS="$CFLAGS"
1544   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1545   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1546   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1547                     [PGO_BUILD_GEN_CFLAGS=])
1548   CFLAGS="$old_CFLAGS"
1549   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1550     AC_MSG_RESULT([yes])
1551     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1552   else
1553     AC_MSG_RESULT([no])
1554     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1555   fi
1556
1557   if test "$enable_pgo_build" = "lto"; then
1558     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1559     old_CFLAGS="$CFLAGS"
1560     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1561     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1562     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1563                       [PGO_BUILD_LTO_CFLAGS=])
1564     CFLAGS="$old_CFLAGS"
1565     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1566       AC_MSG_RESULT([yes])
1567     else
1568       AC_MSG_RESULT([no])
1569       AC_MSG_WARN([LTO is disabled for the PGO build])
1570     fi
1571   fi
1572 fi
1573 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1574 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1575 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1576
1577 # Used for setting $lt_cv_objdir
1578 _LT_CHECK_OBJDIR
1579
1580 # Check for GMP, MPFR and MPC
1581 require_gmp=no
1582 require_mpc=no
1583 if test -d ${srcdir}/gcc ; then
1584   require_gmp=yes
1585   require_mpc=yes
1586 fi
1587 if test -d ${srcdir}/gdb ; then
1588   if test "x$enable_gdb" != xno; then
1589    require_gmp=yes
1590   fi
1591 fi
1592
1593 gmplibs="-lmpfr -lgmp"
1594 if test x"$require_mpc" = "xyes" ; then
1595   gmplibs="-lmpc $gmplibs"
1596 fi
1597 gmpinc=
1598 have_gmp=no
1599
1600 # Specify a location for mpc
1601 # check for this first so it ends up on the link line before mpfr.
1602 AC_ARG_WITH(mpc,
1603 [AS_HELP_STRING([--with-mpc=PATH],
1604                 [specify prefix directory for installed MPC package.
1605                  Equivalent to --with-mpc-include=PATH/include
1606                  plus --with-mpc-lib=PATH/lib])])
1607 AC_ARG_WITH(mpc-include,
1608 [AS_HELP_STRING([--with-mpc-include=PATH],
1609                 [specify directory for installed MPC include files])])
1610 AC_ARG_WITH(mpc-lib,
1611 [AS_HELP_STRING([--with-mpc-lib=PATH],
1612                 [specify directory for the installed MPC library])])
1613
1614 if test "x$with_mpc" != x; then
1615   gmplibs="-L$with_mpc/lib $gmplibs"
1616   gmpinc="-I$with_mpc/include $gmpinc"
1617 fi
1618 if test "x$with_mpc_include" != x; then
1619   gmpinc="-I$with_mpc_include $gmpinc"
1620 fi
1621 if test "x$with_mpc_lib" != x; then
1622   gmplibs="-L$with_mpc_lib $gmplibs"
1623 fi
1624 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1625   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1626   gmpinc='-I$$s/mpc/src '"$gmpinc"
1627   # Do not test the mpc version.  Assume that it is sufficient, since
1628   # it is in the source tree, and the library has not been built yet
1629   # but it would be included on the link line in the version check below
1630   # hence making the test fail.
1631   have_gmp=yes
1632 fi
1633
1634 # Specify a location for mpfr
1635 # check for this first so it ends up on the link line before gmp.
1636 AC_ARG_WITH(mpfr,
1637 [AS_HELP_STRING([--with-mpfr=PATH],
1638                 [specify prefix directory for installed MPFR package.
1639                  Equivalent to --with-mpfr-include=PATH/include
1640                  plus --with-mpfr-lib=PATH/lib])])
1641 AC_ARG_WITH(mpfr-include,
1642 [AS_HELP_STRING([--with-mpfr-include=PATH],
1643                 [specify directory for installed MPFR include files])])
1644 AC_ARG_WITH(mpfr-lib,
1645 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1646                 [specify directory for the installed MPFR library])])
1647
1648 if test "x$with_mpfr" != x; then
1649   gmplibs="-L$with_mpfr/lib $gmplibs"
1650   gmpinc="-I$with_mpfr/include $gmpinc"
1651 fi
1652 if test "x$with_mpfr_include" != x; then
1653   gmpinc="-I$with_mpfr_include $gmpinc"
1654 fi
1655 if test "x$with_mpfr_lib" != x; then
1656   gmplibs="-L$with_mpfr_lib $gmplibs"
1657 fi
1658 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1659   # MPFR v3.1.0 moved the sources into a src sub-directory.
1660   if ! test -d ${srcdir}/mpfr/src; then
1661     AC_MSG_ERROR([dnl
1662 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1663   fi
1664   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1665   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1666   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1667   # Do not test the mpfr version.  Assume that it is sufficient, since
1668   # it is in the source tree, and the library has not been built yet
1669   # but it would be included on the link line in the version check below
1670   # hence making the test fail.
1671   have_gmp=yes
1672 fi
1673
1674 # Specify a location for gmp
1675 AC_ARG_WITH(gmp,
1676 [AS_HELP_STRING([--with-gmp=PATH],
1677                 [specify prefix directory for the installed GMP package.
1678                  Equivalent to --with-gmp-include=PATH/include
1679                  plus --with-gmp-lib=PATH/lib])])
1680 AC_ARG_WITH(gmp-include,
1681 [AS_HELP_STRING([--with-gmp-include=PATH],
1682                 [specify directory for installed GMP include files])])
1683 AC_ARG_WITH(gmp-lib,
1684 [AS_HELP_STRING([--with-gmp-lib=PATH],
1685                 [specify directory for the installed GMP library])])
1686
1687
1688 if test "x$with_gmp" != x; then
1689   gmplibs="-L$with_gmp/lib $gmplibs"
1690   gmpinc="-I$with_gmp/include $gmpinc"
1691 fi
1692 if test "x$with_gmp_include" != x; then
1693   gmpinc="-I$with_gmp_include $gmpinc"
1694 fi
1695 if test "x$with_gmp_lib" != x; then
1696   gmplibs="-L$with_gmp_lib $gmplibs"
1697 fi
1698 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1699   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1700   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1701   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1702   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1703   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1704   # Do not test the gmp version.  Assume that it is sufficient, since
1705   # it is in the source tree, and the library has not been built yet
1706   # but it would be included on the link line in the version check below
1707   # hence making the test fail.
1708   have_gmp=yes
1709 fi
1710
1711 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1712   have_gmp=yes
1713   saved_CFLAGS="$CFLAGS"
1714   CFLAGS="$CFLAGS $gmpinc"
1715   # Check for the recommended and required versions of GMP.
1716   AC_MSG_CHECKING([for the correct version of gmp.h])
1717   AC_TRY_COMPILE([#include "gmp.h"],[
1718   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1719   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1720   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1721   choke me
1722   #endif
1723   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1724   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1725   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1726   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1727   choke me
1728   #endif
1729   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1730    [AC_MSG_RESULT([no]); have_gmp=no])
1731
1732   # If we have GMP, check the MPFR version.
1733   if test x"$have_gmp" = xyes; then
1734     # Check for the recommended and required versions of MPFR.
1735     AC_MSG_CHECKING([for the correct version of mpfr.h])
1736     AC_TRY_COMPILE([#include <gmp.h>
1737     #include <mpfr.h>],[
1738     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1739     choke me
1740     #endif
1741     ], [AC_TRY_COMPILE([#include <gmp.h>
1742     #include <mpfr.h>],[
1743     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1744     choke me
1745     #endif
1746     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1747      [AC_MSG_RESULT([no]); have_gmp=no])
1748   fi
1749
1750   # Check for the MPC header version.
1751   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1752     # Check for the recommended and required versions of MPC.
1753     AC_MSG_CHECKING([for the correct version of mpc.h])
1754     AC_TRY_COMPILE([#include <mpc.h>],[
1755     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1756     choke me
1757     #endif
1758     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1759     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1760     choke me
1761     #endif
1762     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1763      [AC_MSG_RESULT([no]); have_gmp=no])
1764   fi
1765
1766   # Now check the MPFR library.
1767   if test x"$have_gmp" = xyes; then
1768     saved_LIBS="$LIBS"
1769     LIBS="$LIBS $gmplibs"
1770     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1771     AC_TRY_LINK([#include <mpfr.h>],[
1772     mpfr_t n;
1773     mpfr_t x;
1774     int t;
1775     mpfr_init (n);
1776     mpfr_init (x);
1777     mpfr_atan2 (n, n, x, MPFR_RNDN);
1778     mpfr_erfc (n, x, MPFR_RNDN);
1779     mpfr_subnormalize (x, t, MPFR_RNDN);
1780     mpfr_clear(n);
1781     mpfr_clear(x);
1782     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1783     LIBS="$saved_LIBS"
1784   fi
1785
1786   # Now check the MPC library
1787   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1788     saved_LIBS="$LIBS"
1789     LIBS="$LIBS $gmplibs"
1790     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1791     AC_TRY_LINK([#include <mpc.h>],[
1792     mpc_t c;
1793     mpc_init2 (c, 53);
1794     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1795     mpc_cosh (c, c, MPC_RNDNN);
1796     mpc_pow (c, c, c, MPC_RNDNN);
1797     mpc_acosh (c, c, MPC_RNDNN);
1798     mpc_clear (c);
1799     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1800     LIBS="$saved_LIBS"
1801   fi
1802
1803   CFLAGS="$saved_CFLAGS"
1804
1805 # The library versions listed in the error message below should match
1806 # the HARD-minimums enforced above.
1807   if test x$have_gmp != xyes; then
1808     if test -d ${srcdir}/gcc ; then
1809       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1810 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1811 their locations.  Source code for these libraries can be found at
1812 their respective hosting sites as well as at
1813 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1814 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1815 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1816 make sure that you have installed both the libraries and the header
1817 files.  They may be located in separate packages.])
1818     else
1819       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1820 Try the --with-gmp and/or --with-mpfr options to specify
1821 their locations.  If you obtained GMP and/or MPFR from a vendor
1822 distribution package, make sure that you have installed both the libraries
1823 and the header files.  They may be located in separate packages.])
1824     fi
1825   fi
1826 fi
1827
1828 # Flags needed for both GMP, MPFR and/or MPC.
1829 AC_SUBST(gmplibs)
1830 AC_SUBST(gmpinc)
1831 AC_SUBST(extra_mpfr_configure_flags)
1832 AC_SUBST(extra_mpc_gmp_configure_flags)
1833 AC_SUBST(extra_mpc_mpfr_configure_flags)
1834 AC_SUBST(extra_isl_gmp_configure_flags)
1835
1836 # Libraries to use for stage1 or when not bootstrapping.
1837 AC_ARG_WITH(stage1-libs,
1838 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1839 [if test "$withval" = "no" -o "$withval" = "yes"; then
1840    stage1_libs=
1841  else
1842    stage1_libs=$withval
1843  fi],
1844 [stage1_libs=])
1845 AC_SUBST(stage1_libs)
1846
1847 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1848 # default is yes if gcc is being built; no otherwise.  The reason for
1849 # this default is that gdb is sometimes linked against GNU Source
1850 # Highlight, which is a shared library that uses C++ exceptions.  In
1851 # this case, -static-libstdc++ will cause crashes.
1852 AC_ARG_WITH(static-standard-libraries,
1853 [AS_HELP_STRING([--with-static-standard-libraries],
1854                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1855 [], [with_static_standard_libraries=auto])
1856 if test "$with_static_standard_libraries" = auto; then
1857   with_static_standard_libraries=$have_compiler
1858 fi
1859
1860 # Linker flags to use for stage1 or when not bootstrapping.
1861 AC_ARG_WITH(stage1-ldflags,
1862 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1863 [if test "$withval" = "no" -o "$withval" = "yes"; then
1864    stage1_ldflags=
1865  else
1866    stage1_ldflags=$withval
1867  fi],
1868 [stage1_ldflags=
1869  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1870  # if supported.  But if the user explicitly specified the libraries to use,
1871  # trust that they are doing what they want.
1872  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1873      -a "$have_static_libs" = yes; then
1874    stage1_ldflags="-static-libstdc++ -static-libgcc"
1875  fi])
1876 AC_SUBST(stage1_ldflags)
1877
1878 # Libraries to use for stage2 and later builds.
1879 AC_ARG_WITH(boot-libs,
1880 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1881 [if test "$withval" = "no" -o "$withval" = "yes"; then
1882    poststage1_libs=
1883  else
1884    poststage1_libs=$withval
1885  fi],
1886 [poststage1_libs=])
1887 AC_SUBST(poststage1_libs)
1888
1889 # Linker flags to use for stage2 and later builds.
1890 AC_ARG_WITH(boot-ldflags,
1891 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1892                 [linker flags for stage2 and later])],
1893 [if test "$withval" = "no" -o "$withval" = "yes"; then
1894    poststage1_ldflags=
1895  else
1896    poststage1_ldflags=$withval
1897  fi],
1898 [poststage1_ldflags=
1899  # In stages 2 and 3, default to linking libstdc++ and libgcc
1900  # statically.  But if the user explicitly specified the libraries to
1901  # use, trust that they are doing what they want.
1902  if test "$poststage1_libs" = ""; then
1903    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1904  fi])
1905 AC_SUBST(poststage1_ldflags)
1906
1907 # GCC GRAPHITE dependency isl.
1908 # Basic setup is inlined here, actual checks are in config/isl.m4
1909
1910 AC_ARG_WITH(isl,
1911   [AS_HELP_STRING(
1912    [--with-isl=PATH],
1913    [Specify prefix directory for the installed isl package.
1914     Equivalent to --with-isl-include=PATH/include
1915     plus --with-isl-lib=PATH/lib])])
1916
1917 # Treat --without-isl as a request to disable
1918 # GRAPHITE support and skip all following checks.
1919 if test "x$with_isl" != "xno"; then
1920   # Check for isl
1921   dnl Provide configure switches and initialize islinc & isllibs
1922   dnl with user input.
1923   ISL_INIT_FLAGS
1924   dnl The versions of isl that work for Graphite
1925   ISL_CHECK_VERSION()
1926   dnl Only execute fail-action, if isl has been requested.
1927   ISL_IF_FAILED([
1928     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1929 fi
1930
1931 # If the isl check failed, disable builds of in-tree variant of isl
1932 if test "x$with_isl" = xno ||
1933    test "x$gcc_cv_isl" = xno; then
1934   noconfigdirs="$noconfigdirs isl"
1935   islinc=
1936 fi
1937
1938 AC_SUBST(isllibs)
1939 AC_SUBST(islinc)
1940
1941 # Check for LTO support.
1942 AC_ARG_ENABLE(lto,
1943 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1944 enable_lto=$enableval,
1945 enable_lto=yes; default_enable_lto=yes)
1946
1947 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1948   build_lto_plugin=yes
1949 ],[if test x"$default_enable_lto" = x"yes" ; then
1950     case $target in
1951       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1952       # On other non-ELF platforms, LTO has yet to be validated.
1953       *) enable_lto=no ;;
1954     esac
1955   else
1956   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1957   # It would also be nice to check the binutils support, but we don't
1958   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1959   # warn during gcc/ subconfigure; unless you're bootstrapping with
1960   # -flto it won't be needed until after installation anyway.
1961     case $target in
1962       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1963       *) if test x"$enable_lto" = x"yes"; then
1964         AC_MSG_ERROR([LTO support is not enabled for this target.])
1965         fi
1966       ;;
1967     esac
1968   fi
1969   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1970   # Build it unless LTO was explicitly disabled.
1971   case $target in
1972     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1973     *) ;;
1974   esac
1975 ])
1976
1977 AC_ARG_ENABLE(linker-plugin-configure-flags,
1978   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1979     [additional flags for configuring linker plugins @<:@none@:>@])],
1980   extra_linker_plugin_configure_flags=$enableval,
1981   extra_linker_plugin_configure_flags=)
1982 AC_SUBST(extra_linker_plugin_configure_flags)
1983 AC_ARG_ENABLE(linker-plugin-flags,
1984   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1985     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1986   extra_linker_plugin_flags=$enableval,
1987   extra_linker_plugin_flags=)
1988 AC_SUBST(extra_linker_plugin_flags)
1989
1990 # Handle --enable-host-pie
1991 # If host PIE executables are the default (or must be forced on) for some host,
1992 # we must pass that configuration to the gcc directory.
1993 gcc_host_pie=
1994 AC_ARG_ENABLE(host-pie,
1995 [AS_HELP_STRING([--enable-host-pie],
1996                 [build position independent host executables])],
1997 [host_pie=$enableval
1998  case $host in
1999    *-*-darwin2*)
2000      if test x$host_pie != xyes ; then
2001        # for Darwin20+ this is required.
2002        AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
2003        host_pie=yes
2004        gcc_host_pie=--enable-host-pie
2005      fi ;;
2006   *) ;;
2007  esac],
2008 [case $host in
2009   *-*-darwin2*)
2010     # Default to PIE (mandatory for aarch64).
2011     host_pie=yes
2012     gcc_host_pie=--enable-host-pie
2013     ;;
2014   *) host_pie=no ;;
2015  esac])
2016
2017 AC_SUBST(host_pie)
2018 AC_SUBST(gcc_host_pie)
2019
2020 # Enable --enable-host-shared.
2021 # Checked early to determine whether jit is an 'all' language
2022 AC_ARG_ENABLE(host-shared,
2023 [AS_HELP_STRING([--enable-host-shared],
2024                 [build host code as shared libraries])],
2025 [host_shared=$enableval
2026  case $host in
2027    x86_64-*-darwin* | aarch64-*-darwin*)
2028      if test x$host_shared != xyes ; then
2029        # PIC is the default, and actually cannot be switched off.
2030        AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
2031        host_shared=yes
2032      fi ;;
2033    *-*-darwin*)
2034      if test x$host_pie = xyes -a x$host_shared != xyes ; then
2035        AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
2036        host_shared=yes
2037      fi ;;
2038   *) ;;
2039  esac],
2040 [case $host in
2041   # 64B x86_64 and Aarch64 Darwin default to PIC.
2042   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2043   # 32B and powerpc64 Darwin must use PIC to link PIE exes.
2044   *-*-darwin*) host_shared=$host_pie ;;
2045   *) host_shared=no;;
2046  esac])
2047
2048 AC_SUBST(host_shared)
2049
2050 if test x$host_shared = xyes; then
2051   case $host in
2052     *-*-darwin*)
2053       # Since host shared is the default for 64b Darwin, and also enabled for
2054       # host_pie, ensure that we present the PIE flag when host_pie is active.
2055       if test x$host_pie = xyes; then
2056         PICFLAG=-fPIE
2057       fi
2058       ;;
2059     *)
2060       PICFLAG=-fPIC
2061       ;;
2062   esac
2063 elif test x$host_pie = xyes; then
2064   PICFLAG=-fPIE
2065 else
2066   PICFLAG=
2067 fi
2068
2069 AC_SUBST(PICFLAG)
2070
2071 # If we are building PIC/PIE host executables, and we are building dependent
2072 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2073 # code.
2074 host_libs_picflag=
2075 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2076 host_libs_picflag='--with-pic'
2077 fi
2078 AC_SUBST(host_libs_picflag)
2079
2080 # By default, C and C++ are the only stage 1 languages.
2081 stage1_languages=,c,
2082
2083 # Target libraries that we bootstrap.
2084 bootstrap_target_libs=,target-libgcc,
2085
2086 # Figure out what language subdirectories are present.
2087 # Look if the user specified --enable-languages="..."; if not, use
2088 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2089 # go away some day.
2090 # NB:  embedded tabs in this IF block -- do not untabify
2091 if test -d ${srcdir}/gcc; then
2092   if test x"${enable_languages+set}" != xset; then
2093     if test x"${LANGUAGES+set}" = xset; then
2094       enable_languages="${LANGUAGES}"
2095         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2096     else
2097       enable_languages=default
2098     fi
2099   else
2100     if test x"${enable_languages}" = x ||
2101        test x"${enable_languages}" = xyes;
2102        then
2103       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2104       exit 1
2105     fi
2106   fi
2107   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2108
2109   # 'f95' is the old name for the 'fortran' language. We issue a warning
2110   # and make the substitution.
2111   case ,${enable_languages}, in
2112     *,f95,*)
2113       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2114       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2115       ;;
2116   esac
2117
2118   # If bootstrapping, C++ must be enabled.
2119   case ",$enable_languages,:$enable_bootstrap" in
2120     *,c++,*:*) ;;
2121     *:yes)
2122       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2123         enable_languages="${enable_languages},c++"
2124       else
2125         AC_MSG_ERROR([bootstrapping requires c++ sources])
2126       fi
2127       ;;
2128   esac
2129
2130   # First scan to see if an enabled language requires some other language.
2131   # We assume that a given config-lang.in will list all the language
2132   # front ends it requires, even if some are required indirectly.
2133   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2134     case ${lang_frag} in
2135       ..) ;;
2136       # The odd quoting in the next line works around
2137       # an apparent bug in bash 1.12 on linux.
2138       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2139       *)
2140         # From the config-lang.in, get $language, $lang_requires, and
2141         # $lang_requires_boot_languages.
2142         language=
2143         lang_requires=
2144         lang_requires_boot_languages=
2145         # set srcdir during sourcing lang_frag to the gcc dir.
2146         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2147         # polutes this shell
2148         saved_srcdir=${srcdir}
2149         srcdir=${srcdir}/gcc . ${lang_frag}
2150         srcdir=${saved_srcdir}
2151         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2152           case ,${enable_languages}, in
2153             *,$other,*) ;;
2154             *,default,*) ;;
2155             *,all,*) ;;
2156             *,$language,*)
2157               echo " \`$other' language required by \`$language'; enabling" 1>&2
2158               enable_languages="${enable_languages},${other}"
2159               ;;
2160           esac
2161         done
2162         for other in ${lang_requires_boot_languages} ; do
2163           if test "$other" != "c"; then
2164             case ,${enable_stage1_languages}, in
2165               *,$other,*) ;;
2166               *,default,*) ;;
2167               *,all,*) ;;
2168               *)
2169                 case ,${enable_languages}, in
2170                   *,$language,*)
2171                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2172                     enable_stage1_languages="$enable_stage1_languages,${other}"
2173                     ;;
2174                 esac
2175                 ;;
2176             esac
2177           fi
2178         done
2179         ;;
2180     esac
2181   done
2182
2183   new_enable_languages=,c,
2184
2185   # If LTO is enabled, add the LTO front end.
2186   if test "$enable_lto" = "yes" ; then
2187     case ,${enable_languages}, in
2188       *,lto,*) ;;
2189       *) enable_languages="${enable_languages},lto" ;;
2190     esac
2191     if test "${build_lto_plugin}" = "yes" ; then
2192       configdirs="$configdirs lto-plugin"
2193     fi
2194   fi
2195
2196   # If we're building an offloading compiler, add the LTO front end.
2197   if test x"$enable_as_accelerator_for" != x ; then
2198     case ,${enable_languages}, in
2199       *,lto,*) ;;
2200       *) enable_languages="${enable_languages},lto" ;;
2201     esac
2202   fi
2203
2204   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2205   potential_languages=,c,
2206
2207   enabled_target_libs=
2208   disabled_target_libs=
2209
2210   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2211     case ${lang_frag} in
2212       ..) ;;
2213       # The odd quoting in the next line works around
2214       # an apparent bug in bash 1.12 on linux.
2215       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2216       *)
2217         # From the config-lang.in, get $language, $target_libs,
2218         # $lang_dirs, $boot_language, and $build_by_default
2219         language=
2220         target_libs=
2221         lang_dirs=
2222         subdir_requires=
2223         boot_language=no
2224         build_by_default=yes
2225         # set srcdir during sourcing.  See above about save & restore
2226         saved_srcdir=${srcdir}
2227         srcdir=${srcdir}/gcc . ${lang_frag}
2228         srcdir=${saved_srcdir}
2229         if test x${language} = x; then
2230           echo "${lang_frag} doesn't set \$language." 1>&2
2231           exit 1
2232         fi
2233
2234         if test "$language" = "c++"; then
2235           boot_language=yes
2236         fi
2237
2238         add_this_lang=no
2239         # C is always enabled, so no need to add it again
2240         if test "$language" != "c"; then
2241           case ,${enable_languages}, in
2242             *,${language},*)
2243               # Language was explicitly selected; include it
2244               add_this_lang=yes
2245               ;;
2246             *,all,*)
2247               # All languages are enabled
2248               add_this_lang=all
2249               ;;
2250             *,default,*)
2251               # 'default' was selected, select it if it is a default language
2252               add_this_lang=${build_by_default}
2253               ;;
2254           esac
2255         fi
2256
2257         # Disable languages that need other directories if these aren't available.
2258         for i in $subdir_requires; do
2259           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2260           case ${add_this_lang} in
2261             yes)
2262               # Specifically requested language; tell them.
2263               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2264               ;;
2265             all)
2266               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2267               add_this_lang=unsupported
2268               ;;
2269             *)
2270               # Silently disable.
2271               add_this_lang=unsupported
2272               ;;
2273           esac
2274         done
2275
2276         # Disable Ada if no preexisting GNAT is available.
2277         case ${add_this_lang}:${language}:${have_gnat} in
2278           yes:ada:no)
2279             # Specifically requested language; tell them.
2280             AC_MSG_ERROR([GNAT is required to build $language])
2281             ;;
2282           all:ada:no)
2283             AC_MSG_WARN([GNAT is required to build $language])
2284             add_this_lang=unsupported
2285             ;;
2286           *:ada:no)
2287             # Silently disable.
2288             add_this_lang=unsupported
2289             ;;
2290         esac
2291
2292         # Disable D if no preexisting GDC is available.
2293         case ${add_this_lang}:${language}:${have_gdc} in
2294           yes:d:no)
2295             # Specifically requested language; tell them.
2296             AC_MSG_ERROR([GDC is required to build $language])
2297            ;;
2298           all:d:no)
2299             AC_MSG_WARN([GDC is required to build $language])
2300             add_this_lang=unsupported
2301             ;;
2302           *:d:no)
2303             # Silently disable.
2304             add_this_lang=unsupported
2305             ;;
2306         esac
2307
2308         # Disable jit if -enable-host-shared not specified
2309         # but not if building for Mingw. All code in Windows
2310         # is position independent code (PIC).
2311         case $target in
2312           *mingw*) ;;
2313           *)
2314           case ${add_this_lang}:${language}:${host_shared} in
2315             yes:jit:no)
2316                    # PR jit/64780: explicitly specify --enable-host-shared
2317             AC_MSG_ERROR([
2318 Enabling language "jit" requires --enable-host-shared.
2319
2320 --enable-host-shared typically slows the rest of the compiler down by
2321 a few %, so you must explicitly enable it.
2322
2323 If you want to build both the jit and the regular compiler, it is often
2324 best to do this via two separate configure/builds, in separate
2325 directories, to avoid imposing the performance cost of
2326 --enable-host-shared on the regular compiler.])
2327                     ;;
2328             all:jit:no)
2329               AC_MSG_WARN([--enable-host-shared required to build $language])
2330               add_this_lang=unsupported
2331               ;;
2332             *:jit:no)
2333               # Silently disable.
2334               add_this_lang=unsupported
2335               ;;
2336                 esac
2337           ;;
2338         esac
2339
2340         # Disable a language that is unsupported by the target.
2341         case "${add_this_lang}: $unsupported_languages " in
2342           no:*) ;;
2343           unsupported:*) ;;
2344           *:*" $language "*)
2345             AC_MSG_WARN([${language} not supported for this target])
2346             add_this_lang=unsupported
2347             ;;
2348         esac
2349
2350         case $add_this_lang in
2351           unsupported)
2352             # Remove language-dependent dirs.
2353             disabled_target_libs="$disabled_target_libs $target_libs"
2354             noconfigdirs="$noconfigdirs $lang_dirs"
2355             ;;
2356           no)
2357             # Remove language-dependent dirs; still show language as supported.
2358             disabled_target_libs="$disabled_target_libs $target_libs"
2359             noconfigdirs="$noconfigdirs $lang_dirs"
2360             potential_languages="${potential_languages}${language},"
2361             ;;
2362           all|yes)
2363             new_enable_languages="${new_enable_languages}${language},"
2364             potential_languages="${potential_languages}${language},"
2365             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2366             enabled_target_libs="$enabled_target_libs $target_libs"
2367             case "${boot_language}:,$enable_stage1_languages," in
2368               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2369                 # Add to (comma-separated) list of stage 1 languages.
2370                 case ",$stage1_languages," in
2371                   *,$language,* | ,yes, | ,all,) ;;
2372                   *) stage1_languages="${stage1_languages}${language}," ;;
2373                 esac
2374                 # We need to bootstrap any supporting libraries.
2375                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2376                 ;;
2377             esac
2378             ;;
2379         esac
2380         ;;
2381     esac
2382   done
2383
2384   # Add target libraries which are only needed for disabled languages
2385   # to noconfigdirs.
2386   if test -n "$disabled_target_libs"; then
2387     for dir in $disabled_target_libs; do
2388       case " $enabled_target_libs " in
2389       *" ${dir} "*) ;;
2390       *) noconfigdirs="$noconfigdirs $dir" ;;
2391       esac
2392     done
2393   fi
2394
2395   AC_ARG_ENABLE(stage1-languages,
2396   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2397                   [choose additional languages to build during
2398                   stage1.  Mostly useful for compiler development])],
2399   [case ,${enable_stage1_languages}, in
2400     ,no,|,,)
2401       # Set it to something that will have no effect in the loop below
2402       enable_stage1_languages=c ;;
2403     ,yes,)
2404       enable_stage1_languages=`echo $new_enable_languages | \
2405         sed -e "s/^,//" -e "s/,$//" ` ;;
2406     *,all,*)
2407       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2408         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2409   esac
2410
2411   # Add "good" languages from enable_stage1_languages to stage1_languages,
2412   # while "bad" languages go in missing_languages.  Leave no duplicates.
2413   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2414     case $potential_languages in
2415       *,$i,*)
2416         case $stage1_languages in
2417           *,$i,*) ;;
2418           *) stage1_languages="$stage1_languages$i," ;;
2419         esac ;;
2420       *)
2421         case $missing_languages in
2422           *,$i,*) ;;
2423           *) missing_languages="$missing_languages$i," ;;
2424         esac ;;
2425      esac
2426   done])
2427
2428   # Remove leading/trailing commas that were added for simplicity
2429   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2430   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2431   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2432   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2433
2434   if test "x$missing_languages" != x; then
2435     AC_MSG_ERROR([
2436 The following requested languages could not be built: ${missing_languages}
2437 Supported languages are: ${potential_languages}])
2438   fi
2439   if test "x$new_enable_languages" != "x$enable_languages"; then
2440     echo The following languages will be built: ${new_enable_languages}
2441     enable_languages="$new_enable_languages"
2442   fi
2443
2444   AC_SUBST(stage1_languages)
2445   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2446 fi
2447
2448 # Handle --disable-<component> generically.
2449 for dir in $configdirs $build_configdirs $target_configdirs ; do
2450   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2451   varname=`echo $dirname | sed -e s/+/_/g`
2452   if eval test x\${enable_${varname}} "=" xno ; then
2453     noconfigdirs="$noconfigdirs $dir"
2454   fi
2455 done
2456
2457 # Check for Boehm's garbage collector
2458 AC_ARG_ENABLE(objc-gc,
2459 [AS_HELP_STRING([--enable-objc-gc],
2460                 [enable use of Boehm's garbage collector with the
2461                  GNU Objective-C runtime])])
2462 AC_ARG_WITH([target-bdw-gc],
2463 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2464                 [specify prefix directory for installed bdw-gc package.
2465                  Equivalent to --with-target-bdw-gc-include=PATH/include
2466                  plus --with-target-bdw-gc-lib=PATH/lib])])
2467 AC_ARG_WITH([target-bdw-gc-include],
2468 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2469                 [specify directories for installed bdw-gc include files])])
2470 AC_ARG_WITH([target-bdw-gc-lib],
2471 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2472                 [specify directories for installed bdw-gc library])])
2473
2474 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2475   AC_MSG_CHECKING([for bdw garbage collector])
2476   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2477     dnl no bdw-gw options, assume default locations
2478     AC_MSG_RESULT([using bdw-gc in default locations])
2479   else
2480     dnl bdw-gw options, first error checking, complete checking in libobjc
2481     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2482       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2483     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2484       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2485     else
2486       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2487     fi
2488   fi
2489 esac
2490
2491 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2492 case ,${enable_languages}, in
2493   *,c++,*)
2494     # Disable libitm, libsanitizer if we're not building libstdc++
2495     case "${noconfigdirs}" in
2496       *target-libstdc++-v3*)
2497         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2498         ;;
2499       *) ;;
2500     esac
2501     ;;
2502   *)
2503     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2504     ;;
2505 esac
2506
2507 # If gcc/ is not in the source tree then we'll not be building a
2508 # target compiler, assume in that case we don't want to build any
2509 # target libraries or tools.
2510 #
2511 # This was added primarily for the benefit for binutils-gdb who reuse
2512 # this configure script, but don't always have target tools available.
2513 if test ! -d ${srcdir}/gcc; then
2514    skipdirs="${skipdirs} ${target_configdirs}"
2515 fi
2516
2517 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2518 # $build_configdirs and $target_configdirs.
2519 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2520
2521 notsupp=""
2522 for dir in . $skipdirs $noconfigdirs ; do
2523   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2524   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2525     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2526     if test -r $srcdir/$dirname/configure ; then
2527       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2528         true
2529       else
2530         notsupp="$notsupp $dir"
2531       fi
2532     fi
2533   fi
2534   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2535     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2536     if test -r $srcdir/$dirname/configure ; then
2537       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2538         true
2539       else
2540         notsupp="$notsupp $dir"
2541       fi
2542     fi
2543   fi
2544   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2545     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2546     if test -r $srcdir/$dirname/configure ; then
2547       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2548         true
2549       else
2550         notsupp="$notsupp $dir"
2551       fi
2552     fi
2553   fi
2554 done
2555
2556 # Quietly strip out all directories which aren't configurable in this tree.
2557 # This relies on all configurable subdirectories being autoconfiscated, which
2558 # is now the case.
2559 build_configdirs_all="$build_configdirs"
2560 build_configdirs=
2561 for i in ${build_configdirs_all} ; do
2562   j=`echo $i | sed -e s/build-//g`
2563   if test -f ${srcdir}/$j/configure ; then
2564     build_configdirs="${build_configdirs} $i"
2565   fi
2566 done
2567
2568 configdirs_all="$configdirs"
2569 configdirs=
2570 for i in ${configdirs_all} ; do
2571   if test -f ${srcdir}/$i/configure ; then
2572     configdirs="${configdirs} $i"
2573   fi
2574 done
2575
2576 target_configdirs_all="$target_configdirs"
2577 target_configdirs=
2578 for i in ${target_configdirs_all} ; do
2579   j=`echo $i | sed -e s/target-//g`
2580   if test -f ${srcdir}/$j/configure ; then
2581     target_configdirs="${target_configdirs} $i"
2582   fi
2583 done
2584
2585 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2586 # so we have to add it after the preceding checks.
2587 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2588 then
2589   case " $configdirs " in
2590     *" libiberty "*)
2591       # If we can build libiberty, we can also build libiberty-linker-plugin.
2592       configdirs="$configdirs libiberty-linker-plugin"
2593       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2594         --with-libiberty=../libiberty-linker-plugin";;
2595     *)
2596       AC_MSG_ERROR([libiberty missing]);;
2597   esac
2598 fi
2599
2600 # Sometimes we have special requirements for the host libiberty.
2601 extra_host_libiberty_configure_flags=
2602 case " $configdirs " in
2603   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2604     # When these are to be built as shared libraries, the same applies to
2605     # libiberty.
2606     extra_host_libiberty_configure_flags=--enable-shared
2607     ;;
2608 esac
2609 AC_SUBST(extra_host_libiberty_configure_flags)
2610
2611 # Sometimes we have special requirements for the host zlib.
2612 extra_host_zlib_configure_flags=
2613 case " $configdirs " in
2614   *" bfd "*)
2615     # When bfd is to be built as a shared library, the same applies to
2616     # zlib.
2617     if test "$enable_shared" = "yes"; then
2618       extra_host_zlib_configure_flags=--enable-host-shared
2619     fi
2620     ;;
2621 esac
2622 AC_SUBST(extra_host_zlib_configure_flags)
2623
2624 # Produce a warning message for the subdirs we can't configure.
2625 # This isn't especially interesting in the Cygnus tree, but in the individual
2626 # FSF releases, it's important to let people know when their machine isn't
2627 # supported by the one or two programs in a package.
2628
2629 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2630   # If $appdirs is non-empty, at least one of those directories must still
2631   # be configured, or we error out.  (E.g., if the gas release supports a
2632   # specified target in some subdirs but not the gas subdir, we shouldn't
2633   # pretend that all is well.)
2634   if test -n "$appdirs" ; then
2635     for dir in $appdirs ; do
2636       if test -r $dir/Makefile.in ; then
2637         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2638           appdirs=""
2639           break
2640         fi
2641         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2642           appdirs=""
2643           break
2644         fi
2645       fi
2646     done
2647     if test -n "$appdirs" ; then
2648       echo "*** This configuration is not supported by this package." 1>&2
2649       exit 1
2650     fi
2651   fi
2652   # Okay, some application will build, or we don't care to check.  Still
2653   # notify of subdirs not getting built.
2654   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2655   echo "    ${notsupp}" 1>&2
2656   echo "    (Any other directories should still work fine.)" 1>&2
2657 fi
2658
2659 case "$host" in
2660   *msdosdjgpp*)
2661     enable_gdbtk=no ;;
2662 esac
2663
2664 # To find our prefix, in gcc_cv_tool_prefix.
2665 ACX_TOOL_DIRS
2666
2667 copy_dirs=
2668
2669 AC_ARG_WITH([build-sysroot],
2670   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2671                   [use sysroot as the system root during the build])],
2672   [if test x"$withval" != x ; then
2673      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2674    fi],
2675   [SYSROOT_CFLAGS_FOR_TARGET=])
2676 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2677
2678 AC_ARG_WITH([debug-prefix-map],
2679   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2680                   [map A to B, C to D ... in debug information])],
2681   [if test x"$withval" != x; then
2682      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2683      for debug_map in $withval; do
2684        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2685      done
2686    fi],
2687   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2688 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2689
2690 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2691 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2692 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2693 # We want to ensure that TARGET libraries (which we know are built with
2694 # gcc) are built with "-O2 -g", so include those options when setting
2695 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2696 if test "x$CFLAGS_FOR_TARGET" = x; then
2697   if test "x${is_cross_compiler}" = xyes; then
2698     CFLAGS_FOR_TARGET="-g -O2"
2699   else
2700     CFLAGS_FOR_TARGET=$CFLAGS
2701     case " $CFLAGS " in
2702       *" -O2 "*) ;;
2703       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2704     esac
2705     case " $CFLAGS " in
2706       *" -g "* | *" -g3 "*) ;;
2707       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2708     esac
2709   fi
2710 fi
2711 AC_SUBST(CFLAGS_FOR_TARGET)
2712
2713 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2714   if test "x${is_cross_compiler}" = xyes; then
2715     CXXFLAGS_FOR_TARGET="-g -O2"
2716   else
2717     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2718     case " $CXXFLAGS " in
2719       *" -O2 "*) ;;
2720       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2721     esac
2722     case " $CXXFLAGS " in
2723       *" -g "* | *" -g3 "*) ;;
2724       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2725     esac
2726   fi
2727 fi
2728 AC_SUBST(CXXFLAGS_FOR_TARGET)
2729
2730 AC_SUBST(LDFLAGS_FOR_TARGET)
2731
2732 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2733 # the named directory are copied to $(tooldir)/sys-include.
2734 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2735   if test x${is_cross_compiler} = xno ; then
2736     echo 1>&2 '***' --with-headers is only supported when cross compiling
2737     exit 1
2738   fi
2739   if test x"${with_headers}" != xyes ; then
2740     x=${gcc_cv_tool_prefix}
2741     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2742   fi
2743 fi
2744
2745 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2746 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2747 # are permitted.
2748 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2749   if test x${is_cross_compiler} = xno ; then
2750     echo 1>&2 '***' --with-libs is only supported when cross compiling
2751     exit 1
2752   fi
2753   if test x"${with_libs}" != xyes ; then
2754     # Copy the libraries in reverse order, so that files in the first named
2755     # library override files in subsequent libraries.
2756     x=${gcc_cv_tool_prefix}
2757     for l in ${with_libs}; do
2758       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2759     done
2760   fi
2761 fi
2762
2763 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2764 #
2765 # This is done by determining whether or not the appropriate directory
2766 # is available, and by checking whether or not specific configurations
2767 # have requested that this magic not happen.
2768 #
2769 # The command line options always override the explicit settings in
2770 # configure.ac, and the settings in configure.ac override this magic.
2771 #
2772 # If the default for a toolchain is to use GNU as and ld, and you don't
2773 # want to do that, then you should use the --without-gnu-as and
2774 # --without-gnu-ld options for the configure script.  Similarly, if
2775 # the default is to use the included zlib and you don't want to do that,
2776 # you should use the --with-system-zlib option for the configure script.
2777
2778 if test x${use_gnu_as} = x &&
2779    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2780   with_gnu_as=yes
2781   extra_host_args="$extra_host_args --with-gnu-as"
2782 fi
2783
2784 if test x${use_gnu_ld} = x &&
2785    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2786   with_gnu_ld=yes
2787   extra_host_args="$extra_host_args --with-gnu-ld"
2788 fi
2789
2790 if test x${use_included_zlib} = x &&
2791    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2792   :
2793 else
2794   with_system_zlib=yes
2795   extra_host_args="$extra_host_args --with-system-zlib"
2796 fi
2797
2798 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2799 # can detect this case.
2800
2801 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2802   with_newlib=yes
2803   extra_host_args="$extra_host_args --with-newlib"
2804 fi
2805
2806 # Handle ${copy_dirs}
2807 set fnord ${copy_dirs}
2808 shift
2809 while test $# != 0 ; do
2810   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2811     :
2812   else
2813     echo Copying $1 to $2
2814
2815     # Use the install script to create the directory and all required
2816     # parent directories.
2817     if test -d $2 ; then
2818       :
2819     else
2820       echo >config.temp
2821       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2822     fi
2823
2824     # Copy the directory, assuming we have tar.
2825     # FIXME: Should we use B in the second tar?  Not all systems support it.
2826     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2827
2828     # It is the responsibility of the user to correctly adjust all
2829     # symlinks.  If somebody can figure out how to handle them correctly
2830     # here, feel free to add the code.
2831
2832     echo $1 > $2/COPIED
2833   fi
2834   shift; shift
2835 done
2836
2837 # Determine a target-dependent exec_prefix that the installed
2838 # gcc will search in.  Keep this list sorted by triplet, with
2839 # the *-*-osname triplets last.
2840 md_exec_prefix=
2841 case "${target}" in
2842   i[[34567]]86-pc-msdosdjgpp*)
2843     md_exec_prefix=/dev/env/DJDIR/bin
2844     ;;
2845   *-*-hpux* | \
2846   *-*-nto-qnx* | \
2847   *-*-solaris2*)
2848     md_exec_prefix=/usr/ccs/bin
2849     ;;
2850 esac
2851
2852 extra_arflags_for_target=
2853 extra_nmflags_for_target=
2854 extra_ranlibflags_for_target=
2855 target_makefile_frag=/dev/null
2856 case "${target}" in
2857   spu-*-*)
2858     target_makefile_frag="config/mt-spu"
2859     ;;
2860   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2861     target_makefile_frag="config/mt-sde"
2862     ;;
2863   mipsisa*-*-elfoabi*)
2864     target_makefile_frag="config/mt-mips-elfoabi"
2865     ;;
2866   mips*-*-*linux* | mips*-*-gnu*)
2867     target_makefile_frag="config/mt-mips-gnu"
2868     ;;
2869   nios2-*-elf*)
2870     target_makefile_frag="config/mt-nios2-elf"
2871     ;;
2872   *-*-linux-android*)
2873     target_makefile_frag="config/mt-android"
2874     ;;
2875   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2876     target_makefile_frag="config/mt-gnu"
2877     ;;
2878   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2879     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2880     # commands to handle both 32-bit and 64-bit objects.  These flags are
2881     # harmless if we're using GNU nm or ar.
2882     extra_arflags_for_target=" -X32_64"
2883     extra_nmflags_for_target=" -B -X32_64"
2884     ;;
2885 esac
2886
2887 alphaieee_frag=/dev/null
2888 case $target in
2889   alpha*-*-*)
2890     # This just makes sure to use the -mieee option to build target libs.
2891     # This should probably be set individually by each library.
2892     alphaieee_frag="config/mt-alphaieee"
2893     ;;
2894 esac
2895
2896 # If --enable-target-optspace always use -Os instead of -O2 to build
2897 # the target libraries, similarly if it is not specified, use -Os
2898 # on selected platforms.
2899 ospace_frag=/dev/null
2900 case "${enable_target_optspace}:${target}" in
2901   yes:*)
2902     ospace_frag="config/mt-ospace"
2903     ;;
2904   :d30v-*)
2905     ospace_frag="config/mt-d30v"
2906     ;;
2907   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2908     ospace_frag="config/mt-ospace"
2909     ;;
2910   no:* | :*)
2911     ;;
2912   *)
2913     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2914     ;;
2915 esac
2916
2917 # Some systems (e.g., one of the i386-aix systems the gas testers are
2918 # using) don't handle "\$" correctly, so don't use it here.
2919 tooldir='${exec_prefix}'/${target_noncanonical}
2920 build_tooldir=${tooldir}
2921
2922 # Create a .gdbinit file which runs the one in srcdir
2923 # and tells GDB to look there for source files.
2924
2925 if test -r ${srcdir}/.gdbinit ; then
2926   case ${srcdir} in
2927     .) ;;
2928     *) cat > ./.gdbinit <<EOF
2929 # ${NO_EDIT}
2930 dir ${srcdir}
2931 dir .
2932 source ${srcdir}/.gdbinit
2933 EOF
2934     ;;
2935   esac
2936 fi
2937
2938 # Make sure that the compiler is able to generate an executable.  If it
2939 # can't, we are probably in trouble.  We don't care whether we can run the
2940 # executable--we might be using a cross compiler--we only care whether it
2941 # can be created.  At this point the main configure script has set CC.
2942 we_are_ok=no
2943 echo "int main () { return 0; }" > conftest.c
2944 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2945 if test $? = 0 ; then
2946   if test -s conftest || test -s conftest.exe ; then
2947     we_are_ok=yes
2948   fi
2949 fi
2950 case $we_are_ok in
2951   no)
2952     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2953     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2954     rm -f conftest*
2955     exit 1
2956     ;;
2957 esac
2958 rm -f conftest*
2959
2960 # Decide which environment variable is used to find dynamic libraries.
2961 case "${host}" in
2962   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2963   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2964   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2965   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2966 esac
2967
2968 # On systems where the dynamic library environment variable is PATH,
2969 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2970 # built executables to PATH.
2971 if test "$RPATH_ENVVAR" = PATH; then
2972   GCC_SHLIB_SUBDIR=/shlib
2973 else
2974   GCC_SHLIB_SUBDIR=
2975 fi
2976
2977 # Adjust the toplevel makefile according to whether bootstrap was selected.
2978 case $enable_bootstrap in
2979   yes)
2980     bootstrap_suffix=bootstrap
2981     BUILD_CONFIG=bootstrap-debug
2982     ;;
2983   no)
2984     bootstrap_suffix=no-bootstrap
2985     BUILD_CONFIG=
2986     ;;
2987 esac
2988
2989 AC_MSG_CHECKING(for default BUILD_CONFIG)
2990
2991 AC_ARG_WITH([build-config],
2992   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2993                   [use config/NAME.mk build configuration])],
2994   [case $with_build_config in
2995    yes) with_build_config= ;;
2996    no) with_build_config= BUILD_CONFIG= ;;
2997    esac])
2998
2999 if test "x${with_build_config}" != x; then
3000   BUILD_CONFIG=$with_build_config
3001 else
3002   case $BUILD_CONFIG in
3003   bootstrap-debug)
3004     if echo "int f (void) { return 0; }" > conftest.c &&
3005        ${CC} -c conftest.c &&
3006        mv conftest.o conftest.o.g0 &&
3007        ${CC} -c -g conftest.c &&
3008        mv conftest.o conftest.o.g &&
3009        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
3010       :
3011     else
3012       BUILD_CONFIG=
3013     fi
3014     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
3015     ;;
3016   esac
3017 fi
3018 AC_MSG_RESULT($BUILD_CONFIG)
3019 AC_SUBST(BUILD_CONFIG)
3020
3021 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
3022 AC_MSG_CHECKING([for --enable-vtable-verify])
3023 AC_ARG_ENABLE(vtable-verify,
3024 [AS_HELP_STRING([--enable-vtable-verify],
3025                 [Enable vtable verification feature])],
3026 [case "$enableval" in
3027  yes) enable_vtable_verify=yes ;;
3028  no)  enable_vtable_verify=no ;;
3029  *)   enable_vtable_verify=no;;
3030  esac],
3031 [enable_vtable_verify=no])
3032 AC_MSG_RESULT($enable_vtable_verify)
3033
3034 # Record target_configdirs and the configure arguments for target and
3035 # build configuration in Makefile.
3036 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
3037 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
3038 bootstrap_fixincludes=no
3039
3040 # If we are building libgomp, bootstrap it.
3041 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
3042   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
3043 fi
3044
3045 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
3046 # or bootstrap-ubsan, bootstrap it.
3047 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
3048   case "$BUILD_CONFIG" in
3049     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
3050       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
3051       bootstrap_fixincludes=yes
3052       ;;
3053   esac
3054 fi
3055
3056 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3057 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3058    test "$enable_vtable_verify" != no; then
3059   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3060 fi
3061
3062 # If we are building libatomic and the list of enabled languages includes the
3063 # D frontend, bootstrap it.
3064 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3065   case ,${enable_languages}, in
3066     *,d,*)
3067       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3068       ;;
3069   esac
3070 fi
3071
3072 # Determine whether gdb needs tk/tcl or not.
3073 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3074 # and in that case we want gdb to be built without tk.  Ugh!
3075 # In fact I believe gdb is the *only* package directly dependent on tk,
3076 # so we should be able to put the 'maybe's in unconditionally and
3077 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3078 # 100% sure that that's safe though.
3079
3080 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3081 case "$enable_gdbtk" in
3082   no)
3083     GDB_TK="" ;;
3084   yes)
3085     GDB_TK="${gdb_tk}" ;;
3086   *)
3087     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3088     # distro.  Eventually someone will fix this and move Insight, nee
3089     # gdbtk to a separate directory.
3090     if test -d ${srcdir}/gdb/gdbtk ; then
3091       GDB_TK="${gdb_tk}"
3092     else
3093       GDB_TK=""
3094     fi
3095     ;;
3096 esac
3097 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3098 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3099
3100 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3101 # else does, only include them if one of these is built.  The Makefile
3102 # provides the ordering, so it's enough here to add to the list.
3103 case " ${configdirs} " in
3104   *\ gdb\ *)
3105     configdirs="${configdirs} gnulib gdbsupport"
3106     ;;
3107   *\ gdbserver\ *)
3108     configdirs="${configdirs} gnulib gdbsupport"
3109     ;;
3110   *\ sim\ *)
3111     configdirs="${configdirs} gnulib"
3112     ;;
3113 esac
3114
3115 # Strip out unwanted targets.
3116
3117 # While at that, we remove Makefiles if we were started for recursive
3118 # configuration, so that the top-level Makefile reconfigures them,
3119 # like we used to do when configure itself was recursive.
3120
3121 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3122 # but now we're fixing up the Makefile ourselves with the additional
3123 # commands passed to AC_CONFIG_FILES.  Use separate variables
3124 # extrasub-{build,host,target} not because there is any reason to split
3125 # the substitutions up that way, but only to remain below the limit of
3126 # 99 commands in a script, for HP-UX sed.
3127
3128 # Do not nest @if/@endif or @unless/@endunless pairs, because
3129 # configure will not warn you at all.
3130
3131 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3132   yes:yes:*\ gold\ *:*,c++,*) ;;
3133   yes:yes:*\ gold\ *:*)
3134     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3135     ;;
3136 esac
3137
3138 extrasub_build=
3139 for module in ${build_configdirs} ; do
3140   if test -z "${no_recursion}" \
3141      && test -f ${build_subdir}/${module}/Makefile; then
3142     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3143     rm -f ${build_subdir}/${module}/Makefile
3144   fi
3145   extrasub_build="$extrasub_build
3146 /^@if build-$module\$/d
3147 /^@endif build-$module\$/d
3148 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3149 /^@if build-$module-$bootstrap_suffix\$/d
3150 /^@endif build-$module-$bootstrap_suffix\$/d
3151 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3152 done
3153 extrasub_host=
3154 for module in ${configdirs} ; do
3155   if test -z "${no_recursion}"; then
3156     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3157       if test -f ${file}; then
3158         echo 1>&2 "*** removing ${file} to force reconfigure"
3159         rm -f ${file}
3160       fi
3161     done
3162   fi
3163   case ${module},${bootstrap_fixincludes} in
3164     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3165     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3166   esac
3167   extrasub_host="$extrasub_host
3168 /^@if $module\$/d
3169 /^@endif $module\$/d
3170 /^@unless $module\$/,/^@endunless $module\$/d
3171 /^@if $module-$host_bootstrap_suffix\$/d
3172 /^@endif $module-$host_bootstrap_suffix\$/d
3173 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3174 done
3175 extrasub_target=
3176 for module in ${target_configdirs} ; do
3177   if test -z "${no_recursion}" \
3178      && test -f ${target_subdir}/${module}/Makefile; then
3179     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3180     rm -f ${target_subdir}/${module}/Makefile
3181   fi
3182
3183   # We only bootstrap target libraries listed in bootstrap_target_libs.
3184   case $bootstrap_target_libs in
3185     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3186     *) target_bootstrap_suffix=no-bootstrap ;;
3187   esac
3188
3189   extrasub_target="$extrasub_target
3190 /^@if target-$module\$/d
3191 /^@endif target-$module\$/d
3192 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3193 /^@if target-$module-$target_bootstrap_suffix\$/d
3194 /^@endif target-$module-$target_bootstrap_suffix\$/d
3195 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3196 done
3197
3198 # Do the final fixup along with target modules.
3199 extrasub_target="$extrasub_target
3200 /^@if /,/^@endif /d
3201 /^@unless /d
3202 /^@endunless /d"
3203
3204 if test "$enable_pgo_build" != "no"; then
3205   extrasub_build="$extrasub_build
3206 /^@if pgo-build\$/d
3207 /^@endif pgo-build\$/d"
3208 fi
3209
3210 # Create the serialization dependencies.  This uses a temporary file.
3211
3212 AC_ARG_ENABLE([serial-configure],
3213 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3214                 [force sequential configuration of
3215                  sub-packages for the host, target or build
3216                  machine, or all sub-packages])])
3217
3218 case ${enable_serial_configure} in
3219   yes)
3220     enable_serial_build_configure=yes
3221     enable_serial_host_configure=yes
3222     enable_serial_target_configure=yes
3223     ;;
3224 esac
3225
3226 # These force 'configure's to be done one at a time, to avoid problems
3227 # with contention over a shared config.cache.
3228 rm -f serdep.tmp
3229 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3230 echo '# serdep.tmp' > serdep.tmp
3231 fi
3232 olditem=
3233 test "x${enable_serial_build_configure}" = xyes &&
3234 for item in ${build_configdirs} ; do
3235   case ${olditem} in
3236     "") ;;
3237     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3238   esac
3239   olditem=${item}
3240 done
3241 olditem=
3242 test "x${enable_serial_host_configure}" = xyes &&
3243 for item in ${configdirs} ; do
3244   case ${olditem} in
3245     "") ;;
3246     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3247   esac
3248   olditem=${item}
3249 done
3250 olditem=
3251 test "x${enable_serial_target_configure}" = xyes &&
3252 for item in ${target_configdirs} ; do
3253   case ${olditem} in
3254     "") ;;
3255     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3256   esac
3257   olditem=${item}
3258 done
3259 serialization_dependencies=serdep.tmp
3260 AC_SUBST_FILE(serialization_dependencies)
3261
3262 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3263 # target, nonopt, and variable assignments.  These are the ones we
3264 # might not want to pass down to subconfigures.  The exception being
3265 # --cache-file=/dev/null, which is used to turn off the use of cache
3266 # files altogether, and which should be passed on to subconfigures.
3267 # Also strip program-prefix, program-suffix, and program-transform-name,
3268 # so that we can pass down a consistent program-transform-name.
3269 baseargs=
3270 tbaseargs=
3271 keep_next=no
3272 skip_next=no
3273 eval "set -- $ac_configure_args"
3274 for ac_arg
3275 do
3276   if test X"$skip_next" = X"yes"; then
3277     skip_next=no
3278     continue
3279   fi
3280   if test X"$keep_next" = X"yes"; then
3281     case $ac_arg in
3282       *\'*)
3283         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3284     esac
3285     baseargs="$baseargs '$ac_arg'"
3286     tbaseargs="$tbaseargs '$ac_arg'"
3287     keep_next=no
3288     continue
3289   fi
3290
3291   # Handle separated arguments.  Based on the logic generated by
3292   # autoconf 2.59.
3293   case $ac_arg in
3294     *=* | --config-cache | -C | -disable-* | --disable-* \
3295       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3296       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3297       | -with-* | --with-* | -without-* | --without-* | --x)
3298       separate_arg=no
3299       ;;
3300     -*)
3301       separate_arg=yes
3302       ;;
3303     *)
3304       separate_arg=no
3305       ;;
3306   esac
3307
3308   skip_targ=no
3309   case $ac_arg in
3310 changequote(,)
3311   --with-* | --without-*)
3312     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3313
3314     case $libopt in
3315     *[-_]include)
3316       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3317       ;;
3318     *[-_]lib)
3319       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3320       ;;
3321     *)
3322       lib=$libopt
3323       ;;
3324     esac
3325 changequote([,])
3326
3327     case $lib in
3328     mpc | mpfr | gmp | isl)
3329       # If we're processing --with-$lib, --with-$lib-include or
3330       # --with-$lib-lib, for one of the libs above, and target is
3331       # different from host, don't pass the current argument to any
3332       # target library's configure.
3333       if test x$is_cross_compiler = xyes; then
3334         skip_targ=yes
3335       fi
3336       ;;
3337     esac
3338     ;;
3339   esac
3340
3341   case "$ac_arg" in
3342     --cache-file=/dev/null | \
3343     -cache-file=/dev/null )
3344       # Handled here to avoid the test to skip args below.
3345       baseargs="$baseargs '$ac_arg'"
3346       tbaseargs="$tbaseargs '$ac_arg'"
3347       # Assert: $separate_arg should always be no.
3348       keep_next=$separate_arg
3349       ;;
3350     --no*)
3351       continue
3352       ;;
3353     --c* | \
3354     --sr* | \
3355     --ho* | \
3356     --bu* | \
3357     --t* | \
3358     --program-* | \
3359     -cache_file* | \
3360     -srcdir* | \
3361     -host* | \
3362     -build* | \
3363     -target* | \
3364     -program-prefix* | \
3365     -program-suffix* | \
3366     -program-transform-name* )
3367       skip_next=$separate_arg
3368       continue
3369       ;;
3370     -*)
3371       # An option.  Add it.
3372       case $ac_arg in
3373         *\'*)
3374           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3375       esac
3376       baseargs="$baseargs '$ac_arg'"
3377       if test X"$skip_targ" = Xno; then
3378         tbaseargs="$tbaseargs '$ac_arg'"
3379       fi
3380       keep_next=$separate_arg
3381       ;;
3382     *)
3383       # Either a variable assignment, or a nonopt (triplet).  Don't
3384       # pass it down; let the Makefile handle this.
3385       continue
3386       ;;
3387   esac
3388 done
3389 # Remove the initial space we just introduced and, as these will be
3390 # expanded by make, quote '$'.
3391 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3392
3393 # Add in --program-transform-name, after --program-prefix and
3394 # --program-suffix have been applied to it.  Autoconf has already
3395 # doubled dollar signs and backslashes in program_transform_name; we want
3396 # the backslashes un-doubled, and then the entire thing wrapped in single
3397 # quotes, because this will be expanded first by make and then by the shell.
3398 # Also, because we want to override the logic in subdir configure scripts to
3399 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3400 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3401 ${program_transform_name}
3402 EOF_SED
3403 gcc_transform_name=`cat conftestsed.out`
3404 rm -f conftestsed.out
3405 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3406 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3407 if test "$silent" = yes; then
3408   baseargs="$baseargs --silent"
3409   tbaseargs="$tbaseargs --silent"
3410 fi
3411
3412 baseargs="$baseargs --disable-option-checking"
3413 tbaseargs="$tbaseargs --disable-option-checking"
3414
3415 if test "$enable_year2038" = no; then
3416   baseargs="$baseargs --disable-year2038"
3417   tbaseargs="$tbaseargs --disable-year2038"
3418 fi
3419
3420 # Record and document user additions to sub configure arguments.
3421 AC_ARG_VAR([build_configargs],
3422            [additional configure arguments for build directories])
3423 AC_ARG_VAR([host_configargs],
3424            [additional configure arguments for host directories])
3425 AC_ARG_VAR([target_configargs],
3426            [additional configure arguments for target directories])
3427
3428 # For the build-side libraries, we just need to pretend we're native,
3429 # and not use the same cache file.  Multilibs are neither needed nor
3430 # desired.  We can't even use the same cache file for all build-side
3431 # libraries, as they're compiled differently; some with C, some with
3432 # C++ or with different feature-enabling options.
3433 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3434
3435 # For host modules, accept cache file option, or specification as blank.
3436 case "${cache_file}" in
3437 "") # empty
3438   cache_file_option="" ;;
3439 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3440   cache_file_option="--cache-file=${cache_file}" ;;
3441 *) # relative path
3442   cache_file_option="--cache-file=../${cache_file}" ;;
3443 esac
3444
3445 # Host dirs don't like to share a cache file either, horribly enough.
3446 # This seems to be due to autoconf 2.5x stupidity.
3447 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3448
3449 target_configargs="$target_configargs ${tbaseargs}"
3450
3451 # Passing a --with-cross-host argument lets the target libraries know
3452 # whether they are being built with a cross-compiler or being built
3453 # native.  However, it would be better to use other mechanisms to make the
3454 # sorts of decisions they want to make on this basis.  Please consider
3455 # this option to be deprecated.  FIXME.
3456 if test x${is_cross_compiler} = xyes ; then
3457   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3458 fi
3459
3460 # Special user-friendly check for native x86_64-linux build, if
3461 # multilib is not explicitly enabled.
3462 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3463   x86_64-*linux*:yes:$build:$build:)
3464     # Make sure we have a development environment that handles 32-bit
3465     dev64=no
3466     echo "int main () { return 0; }" > conftest.c
3467     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3468     if test $? = 0 ; then
3469       if test -s conftest || test -s conftest.exe ; then
3470         dev64=yes
3471       fi
3472     fi
3473     rm -f conftest*
3474     if test x${dev64} != xyes ; then
3475       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3476     fi
3477     ;;
3478 esac
3479
3480 # Default to --enable-multilib.
3481 if test x${enable_multilib} = x ; then
3482   target_configargs="--enable-multilib ${target_configargs}"
3483 fi
3484
3485 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3486 # changed from the earlier setting of with_newlib.
3487 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3488   target_configargs="--with-newlib ${target_configargs}"
3489 fi
3490
3491 # Different target subdirs use different values of certain variables
3492 # (notably CXX).  Worse, multilibs use *lots* of different values.
3493 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3494 # it doesn't automatically accept command-line overrides of them.
3495 # This means it's not safe for target subdirs to share a cache file,
3496 # which is disgusting, but there you have it.  Hopefully this can be
3497 # fixed in future.  It's still worthwhile to use a cache file for each
3498 # directory.  I think.
3499
3500 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3501 # We need to pass --target, as newer autoconf's requires consistency
3502 # for target_alias and gcc doesn't manage it consistently.
3503 target_configargs="--cache-file=./config.cache ${target_configargs}"
3504
3505 FLAGS_FOR_TARGET=
3506 case " $target_configdirs " in
3507  *" newlib "*)
3508   case " $target_configargs " in
3509   *" --with-newlib "*)
3510    case "$target" in
3511     *-cygwin*)
3512       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3513       ;;
3514    esac
3515
3516    # If we're not building GCC, don't discard standard headers.
3517    if test -d ${srcdir}/gcc; then
3518      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3519
3520      if test "${build}" != "${host}"; then
3521        # On Canadian crosses, CC_FOR_TARGET will have already been set
3522        # by `configure', so we won't have an opportunity to add -Bgcc/
3523        # to it.  This is right: we don't want to search that directory
3524        # for binaries, but we want the header files in there, so add
3525        # them explicitly.
3526        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3527
3528        # Someone might think of using the pre-installed headers on
3529        # Canadian crosses, in case the installed compiler is not fully
3530        # compatible with the compiler being built.  In this case, it
3531        # would be better to flag an error than risking having
3532        # incompatible object files being constructed.  We can't
3533        # guarantee that an error will be flagged, but let's hope the
3534        # compiler will do it, when presented with incompatible header
3535        # files.
3536      fi
3537    fi
3538
3539    case "${target}-${is_cross_compiler}" in
3540    i[[3456789]]86-*-linux*-no)
3541       # Here host == target, so we don't need to build gcc,
3542       # so we don't want to discard standard headers.
3543       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3544       ;;
3545    *)
3546       # If we're building newlib, use its generic headers last, but search
3547       # for any libc-related directories first (so make it the last -B
3548       # switch).
3549       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3550
3551       # If we're building libgloss, find the startup file, simulator library
3552       # and linker script.
3553       case " $target_configdirs " in
3554         *" libgloss "*)
3555         # Look for startup file, simulator library and maybe linker script.
3556         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3557         # Look for libnosys.a in case the target needs it.
3558         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3559         # Most targets have the linker script in the source directory.
3560         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3561         ;;
3562       esac
3563       ;;
3564    esac
3565    ;;
3566   esac
3567   ;;
3568 esac
3569
3570 case "$target" in
3571   x86_64-*mingw* | *-w64-mingw*)
3572   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3573   # however, use a symlink named 'mingw' in ${prefix} .
3574     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3575     ;;
3576   *-mingw*)
3577   # MinGW can't be handled as Cygwin above since it does not use newlib.
3578     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3579     ;;
3580 esac
3581
3582 # Allow the user to override the flags for
3583 # our build compiler if desired.
3584 if test x"${build}" = x"${host}" ; then
3585   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3586   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3587   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3588   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3589 fi
3590
3591 # On Canadian crosses, we'll be searching the right directories for
3592 # the previously-installed cross compiler, so don't bother to add
3593 # flags for directories within the install tree of the compiler
3594 # being built; programs in there won't even run.
3595 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3596   # Search for pre-installed headers if nothing else fits.
3597   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3598 fi
3599
3600 if test "x${use_gnu_ld}" = x &&
3601    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3602   # Arrange for us to find uninstalled linker scripts.
3603   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3604 fi
3605
3606 # Search for other target-specific linker scripts and such.
3607 case "${target}" in
3608   mep*)
3609     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3610     ;;
3611   # The VxWorks support for shared libraries is getting in
3612   # incrementally.  Make sure it doesn't get activated implicitly:
3613   *vxworks*)
3614     if test "${enable_shared-unset}" = unset ; then
3615       enable_shared=no
3616       # So the build of libraries knows ...
3617       target_configargs="${target_configargs} --disable-shared"
3618       # So gcc knows ...
3619       host_configargs="${host_configargs} --disable-shared"
3620     fi
3621     ;;
3622 esac
3623
3624 # Makefile fragments.
3625 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3626 do
3627   eval fragval=\$$frag
3628   if test $fragval != /dev/null; then
3629     eval $frag=${srcdir}/$fragval
3630   fi
3631 done
3632 AC_SUBST_FILE(host_makefile_frag)
3633 AC_SUBST_FILE(target_makefile_frag)
3634 AC_SUBST_FILE(alphaieee_frag)
3635 AC_SUBST_FILE(ospace_frag)
3636
3637 # Miscellanea: directories, flags, etc.
3638 AC_SUBST(RPATH_ENVVAR)
3639 AC_SUBST(GCC_SHLIB_SUBDIR)
3640 AC_SUBST(tooldir)
3641 AC_SUBST(build_tooldir)
3642 AC_SUBST(CONFIGURE_GDB_TK)
3643 AC_SUBST(GDB_TK)
3644 AC_SUBST(INSTALL_GDB_TK)
3645
3646 # Build module lists & subconfigure args.
3647 AC_SUBST(build_configargs)
3648 AC_SUBST(build_configdirs)
3649
3650 # Host module lists & subconfigure args.
3651 AC_SUBST(host_configargs)
3652 AC_SUBST(configdirs)
3653 AC_SUBST(target_configdirs)
3654
3655 # Target module lists & subconfigure args.
3656 AC_SUBST(target_configargs)
3657
3658
3659 # Build tools.
3660 AC_SUBST(AR_FOR_BUILD)
3661 AC_SUBST(AS_FOR_BUILD)
3662 AC_SUBST(CC_FOR_BUILD)
3663 AC_SUBST(CFLAGS_FOR_BUILD)
3664 AC_SUBST(CPP_FOR_BUILD)
3665 AC_SUBST(CPPFLAGS_FOR_BUILD)
3666 AC_SUBST(CXXFLAGS_FOR_BUILD)
3667 AC_SUBST(CXX_FOR_BUILD)
3668 AC_SUBST(DLLTOOL_FOR_BUILD)
3669 AC_SUBST(DSYMUTIL_FOR_BUILD)
3670 AC_SUBST(GFORTRAN_FOR_BUILD)
3671 AC_SUBST(GOC_FOR_BUILD)
3672 AC_SUBST(GDC_FOR_BUILD)
3673 AC_SUBST(LDFLAGS_FOR_BUILD)
3674 AC_SUBST(LD_FOR_BUILD)
3675 AC_SUBST(NM_FOR_BUILD)
3676 AC_SUBST(RANLIB_FOR_BUILD)
3677 AC_SUBST(WINDMC_FOR_BUILD)
3678 AC_SUBST(WINDRES_FOR_BUILD)
3679
3680 # Generate default definitions for YACC, M4, LEX and other programs that run
3681 # on the build machine.  These are used if the Makefile can't locate these
3682 # programs in objdir.
3683 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3684
3685 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3686 case " $build_configdirs " in
3687   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3688 esac
3689
3690 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3691 case " $build_configdirs " in
3692   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3693 esac
3694
3695 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3696 case " $build_configdirs " in
3697   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3698 esac
3699
3700 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3701 case " $build_configdirs " in
3702   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3703   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3704 esac
3705
3706 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3707 case " $build_configdirs " in
3708   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3709 esac
3710
3711 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3712 case " $build_configdirs " in
3713   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3714   *)
3715 changequote(,)
3716     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3717     # higher, else we use the "missing" dummy.
3718     if ${MAKEINFO} --version \
3719        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3720       :
3721     else
3722       MAKEINFO="$MISSING makeinfo"
3723     fi
3724     ;;
3725 changequote([,])
3726 esac
3727
3728 # FIXME: expect and dejagnu may become build tools?
3729
3730 AC_CHECK_PROGS(EXPECT, expect, expect)
3731 case " $configdirs " in
3732   *" expect "*)
3733     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3734     ;;
3735 esac
3736
3737 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3738 case " $configdirs " in
3739   *" dejagnu "*)
3740     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3741     ;;
3742 esac
3743
3744
3745 # Host tools.
3746 NCN_STRICT_CHECK_TOOLS(AR, ar)
3747 NCN_STRICT_CHECK_TOOLS(AS, as)
3748 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3749 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3750 NCN_STRICT_CHECK_TOOLS(LD, ld)
3751 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3752 NCN_STRICT_CHECK_TOOLS(NM, nm)
3753 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3754 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3755 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3756 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3757 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3758 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3759 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3760 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3761 AC_SUBST(CC)
3762 AC_SUBST(CXX)
3763 AC_SUBST(CFLAGS)
3764 AC_SUBST(CXXFLAGS)
3765 AC_SUBST(GDC)
3766 AC_SUBST(GDCFLAGS)
3767 AC_SUBST(PKG_CONFIG_PATH)
3768
3769 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3770 AR_PLUGIN_OPTION=
3771 RANLIB_PLUGIN_OPTION=
3772 if test -n "$PLUGIN_OPTION"; then
3773   if $AR --help 2>&1 | grep -q "\--plugin"; then
3774     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3775   fi
3776   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3777     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3778   fi
3779 fi
3780 AC_SUBST(AR_PLUGIN_OPTION)
3781 AC_SUBST(RANLIB_PLUGIN_OPTION)
3782
3783 # Target tools.
3784 AC_ARG_WITH([build-time-tools],
3785   [AS_HELP_STRING([--with-build-time-tools=PATH],
3786                   [use given path to find target tools during the build])],
3787   [case x"$withval" in
3788      x/*) ;;
3789      *)
3790        with_build_time_tools=
3791        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3792        ;;
3793    esac],
3794   [with_build_time_tools=])
3795
3796 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3797 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3798 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3799 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3800 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3801 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3802
3803 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3804 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3805 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3806 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3807 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3808 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3809 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3810 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3811 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3812 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3813 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3814 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3815 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3816 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3817 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3818
3819 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3820
3821 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3822 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3823 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3824 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3825 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3826                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3827                 c++)
3828 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3829                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3830                 c++)
3831 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3832 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3833 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3834 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3835                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3836 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3837                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3838 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3839                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3840 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3841 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3842 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3843 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3844 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3845 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3846 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3847 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3848 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3849 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3850 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3851
3852 AC_SUBST(FLAGS_FOR_TARGET)
3853 AC_SUBST(RAW_CXX_FOR_TARGET)
3854
3855 # Certain tools may need extra flags.
3856 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3857 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3858 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3859
3860 # When building target libraries, except in a Canadian cross, we use
3861 # the same toolchain as the compiler we just built.
3862 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3863 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3864 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3865 if test $host = $build; then
3866   case " $configdirs " in
3867     *" gcc "*)
3868       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3869       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3870       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3871       ;;
3872   esac
3873 fi
3874
3875 AC_SUBST(COMPILER_AS_FOR_TARGET)
3876 AC_SUBST(COMPILER_LD_FOR_TARGET)
3877 AC_SUBST(COMPILER_NM_FOR_TARGET)
3878
3879 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3880 AC_ARG_ENABLE(maintainer-mode,
3881 [AS_HELP_STRING([--enable-maintainer-mode],
3882                 [enable make rules and dependencies not useful
3883                  (and sometimes confusing) to the casual installer])],
3884       USE_MAINTAINER_MODE=$enableval,
3885       USE_MAINTAINER_MODE=no)
3886 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3887 AC_SUBST(MAINTAINER_MODE_TRUE)
3888 AC_SUBST(MAINTAINER_MODE_FALSE)
3889 if test "$USE_MAINTAINER_MODE" = yes; then
3890   MAINTAINER_MODE_TRUE=
3891   MAINTAINER_MODE_FALSE='#'
3892 else
3893   MAINTAINER_MODE_TRUE='#'
3894   MAINTAINER_MODE_FALSE=
3895 fi
3896 MAINT=$MAINTAINER_MODE_TRUE
3897 AC_SUBST(MAINT)dnl
3898
3899 # ---------------------
3900 # GCC bootstrap support
3901 # ---------------------
3902
3903 # Stage specific cflags for build.
3904 stage1_cflags="-g"
3905 case $build in
3906   vax-*-*)
3907     case ${GCC} in
3908       yes) stage1_cflags="-g -Wa,-J" ;;
3909       *) stage1_cflags="-g -J" ;;
3910     esac ;;
3911 esac
3912
3913 AC_SUBST(stage1_cflags)
3914
3915 # Enable --enable-checking in stage1 of the compiler.
3916 AC_ARG_ENABLE(stage1-checking,
3917 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3918                 [choose additional checking for stage1 of the compiler])],
3919 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3920 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3921   # For --disable-checking or implicit --enable-checking=release, avoid
3922   # setting --enable-checking=gc in the default stage1 checking for LTO
3923   # bootstraps.  See PR62077.
3924   case $BUILD_CONFIG in
3925     *lto*)
3926       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3927     *)
3928       stage1_checking=--enable-checking=yes,types;;
3929   esac
3930   if test "x$enable_checking" = x && \
3931      test -d ${srcdir}/gcc && \
3932      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3933     stage1_checking=--enable-checking=yes,types,extra
3934   fi
3935 else
3936   stage1_checking=--enable-checking=$enable_checking,types
3937 fi])
3938 AC_SUBST(stage1_checking)
3939
3940 # Enable -Werror in bootstrap stage2 and later.
3941 AC_ARG_ENABLE(werror,
3942 [AS_HELP_STRING([--enable-werror],
3943                 [enable -Werror in bootstrap stage2 and later])],
3944 [
3945 case ${enable_werror} in
3946   yes) stage2_werror_flag="--enable-werror-always" ;;
3947   *) stage2_werror_flag="" ;;
3948 esac
3949 ],
3950 [
3951 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3952   case $BUILD_CONFIG in
3953   bootstrap-debug)
3954       stage2_werror_flag="--enable-werror-always" ;;
3955   "")
3956       stage2_werror_flag="--enable-werror-always" ;;
3957   esac
3958 fi
3959 ])
3960
3961 AC_SUBST(stage2_werror_flag)
3962
3963 # Specify what files to not compare during bootstrap.
3964
3965 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3966 case "$target" in
3967   hppa*64*-*-hpux*) ;;
3968   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3969   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3970 esac
3971 AC_SUBST(compare_exclusions)
3972
3973 AC_CONFIG_FILES([Makefile],
3974   [sed "$extrasub_build" Makefile |
3975    sed "$extrasub_host" |
3976    sed "$extrasub_target" > mf$$
3977    mv -f mf$$ Makefile],
3978   [extrasub_build="$extrasub_build"
3979    extrasub_host="$extrasub_host"
3980    extrasub_target="$extrasub_target"])
3981 AC_OUTPUT