configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_DISABLE_OPTION_CHECKING
  35
  36 progname=$0
  37 # if PWD already has a value, it is probably wrong.
  38 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  39
  40 # Export original configure arguments for use by sub-configures.
  41 # Quote arguments with shell meta charatcers.
  42 TOPLEVEL_CONFIGURE_ARGUMENTS=
  43 set -- "$progname" "$@"
  44 for ac_arg
  45 do
  46   case "$ac_arg" in
  47   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  48     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  49     # if the argument is of the form -foo=baz, quote the baz part only
  50     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  51   *) ;;
  52   esac
  53   # Add the quoted argument to the list.
  54   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  55 done
  56 if test "$silent" = yes; then
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  58 fi
  59 # Remove the initial space we just introduced and, as these will be
  60 # expanded by make, quote '$'.
  61 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  62 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  63
  64 # Find the build, host, and target systems.
  65 ACX_NONCANONICAL_BUILD
  66 ACX_NONCANONICAL_HOST
  67 ACX_NONCANONICAL_TARGET
  68
  69 dnl Autoconf 2.5x and later will set a default program prefix if
  70 dnl --target was used, even if it was the same as --host.  Disable
  71 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  72 dnl to take effect.
  73 test "$host_noncanonical" = "$target_noncanonical" &&
  74   test "$program_prefix$program_suffix$program_transform_name" = \
  75     NONENONEs,x,x, &&
  76   program_transform_name=s,y,y,
  77
  78 AC_CANONICAL_SYSTEM
  79 AC_ARG_PROGRAM
  80
  81 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  82 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  83
  84 # Get 'install' or 'install-sh' and its variants.
  85 AC_PROG_INSTALL
  86 ACX_PROG_LN
  87 AC_PROG_LN_S
  88 AC_PROG_SED
  89 AC_PROG_AWK
  90
  91 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  92
  93 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  94 # a relative path.
  95 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  96   INSTALL="${srcpwd}/install-sh -c"
  97 fi
  98
  99 # Set srcdir to "." if that's what it is.
 100 # This is important for multilib support.
 101 pwd=`${PWDCMD-pwd}`
 102 if test "${pwd}" = "${srcpwd}" ; then
 103   srcdir=.
 104 fi
 105
 106 topsrcdir=$srcpwd
 107
 108 extra_host_args=
 109
 110 ### To add a new directory to the tree, first choose whether it is a target
 111 ### or a host dependent tool.  Then put it into the appropriate list
 112 ### (library or tools, host or target), doing a dependency sort.
 113
 114 # Subdirs will be configured in the order listed in build_configdirs,
 115 # configdirs, or target_configdirs; see the serialization section below.
 116
 117 # Dependency sorting is only needed when *configuration* must be done in
 118 # a particular order.  In all cases a dependency should be specified in
 119 # the Makefile, whether or not it's implicitly specified here.
 120
 121 # Double entries in build_configdirs, configdirs, or target_configdirs may
 122 # cause circular dependencies and break everything horribly.
 123
 124 # these library is used by various programs built for the build
 125 # environment
 126 #
 127 build_libs="build-libiberty build-libcpp"
 128
 129 # these tools are built for the build environment
 130 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 131
 132 # these libraries are used by various programs built for the host environment
 133 #f
 134 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 135
 136 # these tools are built for the host environment
 137 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 138 # know that we are building the simulator.
 139 # binutils, gas and ld appear in that order because it makes sense to run
 140 # "make check" in that particular order.
 141 # If --enable-gold is used, "gold" may replace "ld".
 142 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 143
 144 # these libraries are built for the target environment, and are built after
 145 # the host libraries and the host tools (which may be a cross compiler)
 146 # Note that libiberty is not a target library.
 147 target_libraries="target-libgcc \
 148                 target-libbacktrace \
 149                 target-libgloss \
 150                 target-newlib \
 151                 target-libgomp \
 152                 target-liboffloadmic \
 153                 target-libhsail-rt \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-* | amdgcn*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable liboffloadmic on unsupported systems.
 540 if test -d ${srcdir}/liboffloadmic; then
 541     if test x$enable_liboffloadmic != xno; then
 542         AC_MSG_CHECKING([for liboffloadmic support])
 543         if (srcdir=${srcdir}/liboffloadmic; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-liboffloadmic"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable libitm on unsupported systems.
 556 if test -d ${srcdir}/libitm; then
 557     if test x$enable_libitm = x; then
 558         AC_MSG_CHECKING([for libitm support])
 559         if (srcdir=${srcdir}/libitm; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-libitm"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libsanitizer on unsupported systems.
 572 if test -d ${srcdir}/libsanitizer; then
 573     if test x$enable_libsanitizer = x; then
 574         AC_MSG_CHECKING([for libsanitizer support])
 575         if (srcdir=${srcdir}/libsanitizer; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libsanitizer"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libvtv on unsupported systems.
 588 if test -d ${srcdir}/libvtv; then
 589     if test x$enable_libvtv = x; then
 590         AC_MSG_CHECKING([for libvtv support])
 591         if (srcdir=${srcdir}/libvtv; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test "$VTV_SUPPORTED" != "yes")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libvtv"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603
 604 # Disable libhsail-rt on unsupported systems.
 605 if test -d ${srcdir}/libhsail-rt; then
 606     if test x$enable_libhsail_rt = x; then
 607         AC_MSG_CHECKING([for libhsail-rt support])
 608         if (srcdir=${srcdir}/libhsail-rt; \
 609                 . ${srcdir}/configure.tgt; \
 610                 test -n "$UNSUPPORTED")
 611         then
 612             AC_MSG_RESULT([no])
 613             unsupported_languages="$unsupported_languages brig"
 614             # This implicitly disables also target-libhsail-rt as it won't
 615             # get added to the build without BRIG FE.
 616         else
 617             AC_MSG_RESULT([yes])
 618         fi
 619     fi
 620 fi
 621
 622
 623 # Disable libquadmath for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     noconfigdirs="$noconfigdirs target-libquadmath"
 627     ;;
 628   # libquadmath is unused on AIX and libquadmath build process use of
 629   # LD_LIBRARY_PATH can break AIX bootstrap.
 630   powerpc-*-aix* | rs6000-*-aix*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633 esac
 634
 635 # Disable libssp for some systems.
 636 case "${target}" in
 637   avr-*-*)
 638     # No hosted I/O support.
 639     noconfigdirs="$noconfigdirs target-libssp"
 640     ;;
 641   bpf-*-*)
 642     noconfigdirs="$noconfigdirs target-libssp"
 643     ;;
 644   powerpc-*-aix* | rs6000-*-aix*)
 645     noconfigdirs="$noconfigdirs target-libssp"
 646     ;;
 647   pru-*-*)
 648     # No hosted I/O support.
 649     noconfigdirs="$noconfigdirs target-libssp"
 650     ;;
 651   rl78-*-*)
 652     # libssp uses a misaligned load to trigger a fault, but the RL78
 653     # doesn't fault for those - instead, it gives a build-time error
 654     # for explicit misaligned loads.
 655     noconfigdirs="$noconfigdirs target-libssp"
 656     ;;
 657   visium-*-*)
 658     # No hosted I/O support.
 659     noconfigdirs="$noconfigdirs target-libssp"
 660     ;;
 661 esac
 662
 663 # Disable libstdc++-v3 for some systems.
 664 # Allow user to override this if they pass --enable-libstdc++-v3
 665 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 666   case "${target}" in
 667     *-*-vxworks*)
 668       # VxWorks uses the Dinkumware C++ library.
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     arm*-wince-pe*)
 672       # the C++ libraries don't build on top of CE's C libraries
 673       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 674       ;;
 675     avr-*-*)
 676       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 677       ;;
 678     bpf-*-*)
 679       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 680       ;;
 681     ft32-*-*)
 682       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 683       ;;
 684   esac
 685 fi
 686
 687 # Disable C++ on systems where it is known to not work.
 688 # For testing, you can override this with --enable-languages=c++.
 689 case ,${enable_languages}, in
 690   *,c++,*)
 691     ;;
 692   *)
 693       case "${target}" in
 694         bpf-*-*)
 695           unsupported_languages="$unsupported_languages c++"
 696           ;;
 697       esac
 698       ;;
 699 esac
 700
 701 # Disable Objc on systems where it is known to not work.
 702 # For testing, you can override this with --enable-languages=objc.
 703 case ,${enable_languages}, in
 704   *,objc,*)
 705     ;;
 706   *)
 707       case "${target}" in
 708         bpf-*-*)
 709           unsupported_languages="$unsupported_languages objc"
 710           ;;
 711       esac
 712       ;;
 713 esac
 714
 715 # Disable D on systems where it is known to not work.
 716 # For testing, you can override this with --enable-languages=d.
 717 case ,${enable_languages}, in
 718   *,d,*)
 719     ;;
 720   *)
 721     case "${target}" in
 722       *-*-darwin*)
 723         unsupported_languages="$unsupported_languages d"
 724         ;;
 725       bpf-*-*)
 726         unsupported_languages="$unsupported_languages d"
 727         ;;
 728     esac
 729     ;;
 730 esac
 731
 732 # Disable libphobos on unsupported systems.
 733 # For testing, you can override this with --enable-libphobos.
 734 if test -d ${srcdir}/libphobos; then
 735     if test x$enable_libphobos = x; then
 736         AC_MSG_CHECKING([for libphobos support])
 737         if (srcdir=${srcdir}/libphobos; \
 738                 . ${srcdir}/configure.tgt; \
 739                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 740         then
 741             AC_MSG_RESULT([no])
 742             noconfigdirs="$noconfigdirs target-libphobos"
 743         else
 744             AC_MSG_RESULT([yes])
 745         fi
 746     fi
 747 fi
 748
 749 # Disable Fortran for some systems.
 750 case "${target}" in
 751   mmix-*-*)
 752     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 753     unsupported_languages="$unsupported_languages fortran"
 754     ;;
 755   bpf-*-*)
 756     unsupported_languages="$unsupported_languages fortran"
 757     ;;
 758 esac
 759
 760 # Disable libffi for some systems.
 761 case "${target}" in
 762   powerpc-*-darwin*)
 763     ;;
 764   i[[3456789]]86-*-darwin*)
 765     ;;
 766   x86_64-*-darwin[[912]]*)
 767     ;;
 768   *-*-darwin*)
 769     noconfigdirs="$noconfigdirs target-libffi"
 770     ;;
 771   *-*-netware*)
 772     noconfigdirs="$noconfigdirs target-libffi"
 773     ;;
 774   *-*-phoenix*)
 775     noconfigdirs="$noconfigdirs target-libffi"
 776     ;;
 777   *-*-rtems*)
 778     noconfigdirs="$noconfigdirs target-libffi"
 779     ;;
 780   *-*-tpf*)
 781     noconfigdirs="$noconfigdirs target-libffi"
 782     ;;
 783   *-*-uclinux*)
 784     noconfigdirs="$noconfigdirs target-libffi"
 785     ;;
 786   *-*-vxworks*)
 787     noconfigdirs="$noconfigdirs target-libffi"
 788     ;;
 789   aarch64*-*-freebsd*)
 790     noconfigdirs="$noconfigdirs target-libffi"
 791     ;;
 792   alpha*-*-*vms*)
 793     noconfigdirs="$noconfigdirs target-libffi"
 794     ;;
 795   arm*-*-freebsd*)
 796     noconfigdirs="$noconfigdirs target-libffi"
 797     ;;
 798   arm-wince-pe)
 799     noconfigdirs="$noconfigdirs target-libffi"
 800     ;;
 801   arm*-*-symbianelf*)
 802     noconfigdirs="$noconfigdirs target-libffi"
 803     ;;
 804   bpf-*-*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   cris-*-* | crisv32-*-*)
 808     case "${target}" in
 809       *-*-linux*)
 810         ;;
 811       *) # See PR46792 regarding target-libffi.
 812         noconfigdirs="$noconfigdirs target-libffi";;
 813     esac
 814     ;;
 815   hppa*64*-*-hpux*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   hppa*-hp-hpux11*)
 819     ;;
 820   hppa*-*-hpux*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   ia64*-*-*vms*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826   i[[3456789]]86-w64-mingw*)
 827     noconfigdirs="$noconfigdirs target-libffi"
 828     ;;
 829   i[[3456789]]86-*-mingw*)
 830     noconfigdirs="$noconfigdirs target-libffi"
 831     ;;
 832   x86_64-*-mingw*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   mmix-*-*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838   powerpc-*-aix*)
 839     ;;
 840   rs6000-*-aix*)
 841     ;;
 842   ft32-*-*)
 843     noconfigdirs="$noconfigdirs target-libffi"
 844     ;;
 845   *-*-lynxos*)
 846     noconfigdirs="$noconfigdirs target-libffi"
 847     ;;
 848 esac
 849
 850 # Disable the go frontend on systems where it is known to not work. Please keep
 851 # this in sync with contrib/config-list.mk.
 852 case "${target}" in
 853 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 854     unsupported_languages="$unsupported_languages go"
 855     ;;
 856 esac
 857
 858 # Only allow gdbserver on some systems.
 859 if test -d ${srcdir}/gdbserver; then
 860     if test x$enable_gdbserver = x; then
 861         AC_MSG_CHECKING([for gdbserver support])
 862         if (srcdir=${srcdir}/gdbserver; \
 863                 . ${srcdir}/configure.srv; \
 864                 test -n "$UNSUPPORTED")
 865         then
 866             AC_MSG_RESULT([no])
 867             noconfigdirs="$noconfigdirs gdbserver"
 868         else
 869             AC_MSG_RESULT([yes])
 870         fi
 871     fi
 872 fi
 873
 874 # Disable libgo for some systems where it is known to not work.
 875 # For testing, you can easily override this with --enable-libgo.
 876 if test x$enable_libgo = x; then
 877     case "${target}" in
 878     *-*-darwin*)
 879         # PR 46986
 880         noconfigdirs="$noconfigdirs target-libgo"
 881         ;;
 882     *-*-cygwin* | *-*-mingw*)
 883         noconfigdirs="$noconfigdirs target-libgo"
 884         ;;
 885     bpf-*-*)
 886         noconfigdirs="$noconfigdirs target-libgo"
 887         ;;
 888     esac
 889 fi
 890
 891 # Default libgloss CPU subdirectory.
 892 libgloss_dir="$target_cpu"
 893
 894 case "${target}" in
 895   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 896     libgloss_dir=wince
 897     ;;
 898   aarch64*-*-* )
 899     libgloss_dir=aarch64
 900     ;;
 901   arm*-*-*)
 902     libgloss_dir=arm
 903     ;;
 904   cris-*-* | crisv32-*-*)
 905     libgloss_dir=cris
 906     ;;
 907   hppa*-*-*)
 908     libgloss_dir=pa
 909     ;;
 910   i[[3456789]]86-*-*)
 911     libgloss_dir=i386
 912     ;;
 913   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 914     libgloss_dir=m68hc11
 915     ;;
 916   m68*-*-* | fido-*-*)
 917     libgloss_dir=m68k
 918     ;;
 919   mips*-*-*)
 920     libgloss_dir=mips
 921     ;;
 922   powerpc*-*-*)
 923     libgloss_dir=rs6000
 924     ;;
 925   pru-*-*)
 926     libgloss_dir=pru
 927     ;;
 928   sparc*-*-*)
 929     libgloss_dir=sparc
 930     ;;
 931 esac
 932
 933 # Disable newlib and libgloss for various target OSes.
 934 case "${target}" in
 935   alpha*-dec-osf*)
 936     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 937     ;;
 938   i[[3456789]]86-*-linux*)
 939     # This section makes it possible to build newlib natively on linux.
 940     # If we are using a cross compiler then don't configure newlib.
 941     if test x${is_cross_compiler} != xno ; then
 942       noconfigdirs="$noconfigdirs target-newlib"
 943     fi
 944     noconfigdirs="$noconfigdirs target-libgloss"
 945     # If we are not using a cross compiler, do configure newlib.
 946     # Note however, that newlib will only be configured in this situation
 947     # if the --with-newlib option has been given, because otherwise
 948     # 'target-newlib' will appear in skipdirs.
 949     ;;
 950   i[[3456789]]86-*-rdos*)
 951     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 952     ;;
 953   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 954     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 955     ;;
 956   sparc-*-sunos4*)
 957     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 958     ;;
 959   bpf-*-*)
 960     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 961     ;;
 962   *-*-aix*)
 963     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 964     ;;
 965   *-*-beos*)
 966     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 967     ;;
 968   *-*-chorusos)
 969     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 970     ;;
 971   *-*-dragonfly*)
 972     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 973     ;;
 974   *-*-freebsd*)
 975     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 976     ;;
 977   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 978     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 979     ;;
 980   *-*-lynxos*)
 981     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 982     ;;
 983   *-*-mingw*)
 984     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 985     ;;
 986   *-*-netbsd*)
 987     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 988     ;;
 989   *-*-netware*)
 990     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 991     ;;
 992   *-*-tpf*)
 993     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 994     ;;
 995   *-*-uclinux*)
 996     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 997     ;;
 998   *-*-vxworks*)
 999     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1000     ;;
1001 esac
1002
1003 case "${target}" in
1004   *-*-chorusos)
1005     ;;
1006   aarch64-*-darwin*)
1007     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1008     noconfigdirs="$noconfigdirs sim target-rda"
1009     ;;
1010   amdgcn*-*-*)
1011     ;;
1012   arm-*-darwin*)
1013     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1014     noconfigdirs="$noconfigdirs sim target-rda"
1015     ;;
1016   powerpc-*-darwin*)
1017     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1018     noconfigdirs="$noconfigdirs sim target-rda"
1019     ;;
1020   i[[3456789]]86-*-darwin*)
1021     noconfigdirs="$noconfigdirs ld gprof"
1022     noconfigdirs="$noconfigdirs sim target-rda"
1023     ;;
1024   x86_64-*-darwin[[912]]*)
1025     noconfigdirs="$noconfigdirs ld gas gprof"
1026     noconfigdirs="$noconfigdirs sim target-rda"
1027     ;;
1028   *-*-darwin*)
1029     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1030     noconfigdirs="$noconfigdirs sim target-rda"
1031     ;;
1032   *-*-dragonfly*)
1033     ;;
1034   *-*-freebsd*)
1035     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1036         && test -f /usr/local/include/gmp.h; then
1037       with_gmp=/usr/local
1038     fi
1039     ;;
1040   *-*-kaos*)
1041     # Remove unsupported stuff on all kaOS configurations.
1042     noconfigdirs="$noconfigdirs target-libgloss"
1043     ;;
1044   *-*-netbsd*)
1045     ;;
1046   *-*-netware*)
1047     ;;
1048   *-*-phoenix*)
1049     noconfigdirs="$noconfigdirs target-libgloss"
1050     ;;
1051   *-*-rtems*)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054     # The tpf target doesn't support gdb yet.
1055   *-*-tpf*)
1056     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1057     ;;
1058   *-*-uclinux*)
1059     noconfigdirs="$noconfigdirs target-rda"
1060     ;;
1061   *-*-vxworks*)
1062     ;;
1063   alpha*-dec-osf*)
1064     # ld works, but does not support shared libraries.
1065     # gas doesn't generate exception information.
1066     noconfigdirs="$noconfigdirs gas ld"
1067     ;;
1068   alpha*-*-*vms*)
1069     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1070     ;;
1071   alpha*-*-*)
1072     # newlib is not 64 bit ready
1073     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1074     ;;
1075   bpf-*-*)
1076     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1077     ;;
1078   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1079     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1080     ;;
1081   arc*-*-*)
1082     noconfigdirs="$noconfigdirs sim"
1083     ;;
1084   arm-*-pe*)
1085     noconfigdirs="$noconfigdirs target-libgloss"
1086     ;;
1087   arm-*-riscix*)
1088     noconfigdirs="$noconfigdirs ld target-libgloss"
1089     ;;
1090   avr-*-*)
1091     if test x${with_avrlibc} != xno; then
1092       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1093     fi
1094     ;;
1095   c4x-*-* | tic4x-*-*)
1096     noconfigdirs="$noconfigdirs target-libgloss"
1097     ;;
1098   tic54x-*-*)
1099     noconfigdirs="$noconfigdirs target-libgloss gdb"
1100     ;;
1101   d10v-*-*)
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     ;;
1104   d30v-*-*)
1105     noconfigdirs="$noconfigdirs gdb"
1106     ;;
1107   fr30-*-elf*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   ft32-*-*)
1111     noconfigdirs="$noconfigdirs target-rda gprof"
1112     ;;
1113   moxie-*-*)
1114     noconfigdirs="$noconfigdirs"
1115     ;;
1116   h8300*-*-*)
1117     noconfigdirs="$noconfigdirs target-libgloss"
1118     ;;
1119   h8500-*-*)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1123     ;;
1124   hppa*64*-*-hpux*)
1125     noconfigdirs="$noconfigdirs gdb"
1126     ;;
1127   hppa*-*-hpux11*)
1128     noconfigdirs="$noconfigdirs gdb ld"
1129     ;;
1130   hppa*64*-*-linux*)
1131     ;;
1132   hppa*-*-linux*)
1133     ;;
1134   hppa*-*-*elf* | \
1135   hppa*-*-lites* | \
1136   hppa*-*-openbsd* | \
1137   hppa*64*-*-*)
1138     ;;
1139   hppa*-*-pro*)
1140     ;;
1141   hppa*-*-*)
1142     noconfigdirs="$noconfigdirs ld"
1143     ;;
1144   i960-*-*)
1145     noconfigdirs="$noconfigdirs gdb"
1146     ;;
1147   ia64*-*-elf*)
1148     # No gdb support yet.
1149     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1150     ;;
1151   ia64*-**-hpux*)
1152     # No ld support yet.
1153     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1154     ;;
1155   ia64*-*-*vms*)
1156     # No ld support yet.
1157     noconfigdirs="$noconfigdirs libgui itcl ld"
1158     ;;
1159   i[[3456789]]86-w64-mingw*)
1160     ;;
1161   i[[3456789]]86-*-mingw*)
1162     target_configdirs="$target_configdirs target-winsup"
1163     ;;
1164   *-*-cygwin*)
1165     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1166     noconfigdirs="$noconfigdirs target-libgloss"
1167     # always build newlib if winsup directory is present.
1168     if test -d "$srcdir/winsup/cygwin"; then
1169       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1170     elif test -d "$srcdir/newlib"; then
1171       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1172     fi
1173     ;;
1174   i[[3456789]]86-*-pe)
1175     noconfigdirs="$noconfigdirs target-libgloss"
1176     ;;
1177   i[[3456789]]86-*-sco3.2v5*)
1178     # The linker does not yet know about weak symbols in COFF,
1179     # and is not configured to handle mixed ELF and COFF.
1180     noconfigdirs="$noconfigdirs ld target-libgloss"
1181     ;;
1182   i[[3456789]]86-*-sco*)
1183     noconfigdirs="$noconfigdirs gprof target-libgloss"
1184     ;;
1185   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1186     noconfigdirs="$noconfigdirs target-libgloss"
1187     ;;
1188   i[[3456789]]86-*-sysv4*)
1189     noconfigdirs="$noconfigdirs target-libgloss"
1190     ;;
1191   i[[3456789]]86-*-beos*)
1192     noconfigdirs="$noconfigdirs gdb"
1193     ;;
1194   i[[3456789]]86-*-rdos*)
1195     noconfigdirs="$noconfigdirs gdb"
1196     ;;
1197   mmix-*-*)
1198     noconfigdirs="$noconfigdirs gdb"
1199     ;;
1200   mt-*-*)
1201     noconfigdirs="$noconfigdirs sim"
1202     ;;
1203   nfp-*-*)
1204     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1205     noconfigdirs="$noconfigdirs $target_libraries"
1206     ;;
1207   powerpc-*-aix*)
1208     # copied from rs6000-*-* entry
1209     noconfigdirs="$noconfigdirs gprof"
1210     ;;
1211   powerpc*-*-winnt* | powerpc*-*-pe*)
1212     target_configdirs="$target_configdirs target-winsup"
1213     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1214     # always build newlib.
1215     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1216     ;;
1217     # This is temporary until we can link against shared libraries
1218   powerpcle-*-solaris*)
1219     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1220     ;;
1221   powerpc-*-beos*)
1222     noconfigdirs="$noconfigdirs gdb"
1223     ;;
1224   rs6000-*-lynxos*)
1225     noconfigdirs="$noconfigdirs gprof"
1226     ;;
1227   rs6000-*-aix*)
1228     noconfigdirs="$noconfigdirs gprof"
1229     ;;
1230   rs6000-*-*)
1231     noconfigdirs="$noconfigdirs gprof"
1232     ;;
1233   m68k-apollo-*)
1234     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1235     ;;
1236   microblaze*)
1237     noconfigdirs="$noconfigdirs gprof"
1238     ;;
1239   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1240     if test x$with_newlib = xyes; then
1241       noconfigdirs="$noconfigdirs gprof"
1242     fi
1243     ;;
1244   mips*-*-irix5*)
1245     noconfigdirs="$noconfigdirs gprof target-libgloss"
1246     ;;
1247   mips*-*-irix6*)
1248     noconfigdirs="$noconfigdirs gprof target-libgloss"
1249     ;;
1250   mips*-*-bsd*)
1251     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1252     ;;
1253   mips*-*-linux*)
1254     ;;
1255   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1256   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1257     noconfigdirs="$noconfigdirs ld gas gprof"
1258     ;;
1259   mips*-*-*)
1260     noconfigdirs="$noconfigdirs gprof"
1261     ;;
1262   nvptx*-*-*)
1263     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1264     ;;
1265   sh-*-*)
1266     case "${target}" in
1267       sh*-*-elf)
1268          ;;
1269       *)
1270          noconfigdirs="$noconfigdirs target-libgloss" ;;
1271     esac
1272     ;;
1273   sparc-*-sunos4*)
1274     if test x${is_cross_compiler} = xno ; then
1275            use_gnu_ld=no
1276     fi
1277     ;;
1278   tic6x-*-*)
1279     noconfigdirs="$noconfigdirs sim"
1280     ;;
1281   tilepro*-*-* | tilegx*-*-*)
1282     noconfigdirs="$noconfigdirs sim"
1283     ;;
1284   v810-*-*)
1285     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1286     ;;
1287   vax-*-*)
1288     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1289     ;;
1290   wasm32-*-*)
1291     noconfigdirs="$noconfigdirs ld"
1292     ;;
1293 esac
1294
1295 # If we aren't building newlib, then don't build libgloss, since libgloss
1296 # depends upon some newlib header files.
1297 case "${noconfigdirs}" in
1298   *target-libgloss*) ;;
1299   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1300 esac
1301
1302 # Work in distributions that contain no compiler tools, like Autoconf.
1303 host_makefile_frag=/dev/null
1304 if test -d ${srcdir}/config ; then
1305 case "${host}" in
1306   i[[3456789]]86-*-msdosdjgpp*)
1307     host_makefile_frag="config/mh-djgpp"
1308     ;;
1309   *-cygwin*)
1310     ACX_CHECK_CYGWIN_CAT_WORKS
1311     host_makefile_frag="config/mh-cygwin"
1312     ;;
1313   *-mingw*)
1314     host_makefile_frag="config/mh-mingw"
1315     ;;
1316   alpha*-linux*)
1317     host_makefile_frag="config/mh-alpha-linux"
1318     ;;
1319   hppa*-hp-hpux10*)
1320     host_makefile_frag="config/mh-pa-hpux10"
1321     ;;
1322   hppa*-hp-hpux*)
1323     host_makefile_frag="config/mh-pa"
1324     ;;
1325   hppa*-*)
1326     host_makefile_frag="config/mh-pa"
1327     ;;
1328   *-*-darwin*)
1329     host_makefile_frag="config/mh-darwin"
1330     ;;
1331   powerpc-*-aix*)
1332     host_makefile_frag="config/mh-ppc-aix"
1333     ;;
1334   rs6000-*-aix*)
1335     host_makefile_frag="config/mh-ppc-aix"
1336     ;;
1337 esac
1338 fi
1339
1340 if test "${build}" != "${host}" ; then
1341   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1342   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1343   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1344   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1345   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1346   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1347   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1348   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1349   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1350   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1351   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1352   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1353   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1354 else
1355   AR_FOR_BUILD="\$(AR)"
1356   AS_FOR_BUILD="\$(AS)"
1357   CC_FOR_BUILD="\$(CC)"
1358   CXX_FOR_BUILD="\$(CXX)"
1359   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1360   GOC_FOR_BUILD="\$(GOC)"
1361   GDC_FOR_BUILD="\$(GDC)"
1362   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1363   LD_FOR_BUILD="\$(LD)"
1364   NM_FOR_BUILD="\$(NM)"
1365   RANLIB_FOR_BUILD="\$(RANLIB)"
1366   WINDRES_FOR_BUILD="\$(WINDRES)"
1367   WINDMC_FOR_BUILD="\$(WINDMC)"
1368 fi
1369
1370 AC_PROG_CC
1371 AC_PROG_CXX
1372
1373 # We must set the default linker to the linker used by gcc for the correct
1374 # operation of libtool.  If LD is not defined and we are using gcc, try to
1375 # set the LD default to the ld used by gcc.
1376 if test -z "$LD"; then
1377   if test "$GCC" = yes; then
1378     case $build in
1379     *-*-mingw*)
1380       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1381     *)
1382       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1383     esac
1384     case $gcc_prog_ld in
1385     # Accept absolute paths.
1386     [[\\/]* | [A-Za-z]:[\\/]*)]
1387       LD="$gcc_prog_ld" ;;
1388     esac
1389   fi
1390 fi
1391
1392 # Check whether -static-libstdc++ -static-libgcc is supported.
1393 have_static_libs=no
1394 if test "$GCC" = yes; then
1395   saved_LDFLAGS="$LDFLAGS"
1396
1397   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1398   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1399   AC_LANG_PUSH(C++)
1400   AC_LINK_IFELSE([AC_LANG_SOURCE([
1401 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1402 #error -static-libstdc++ not implemented
1403 #endif
1404 int main() {}])],
1405     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1406     [AC_MSG_RESULT([no])])
1407   AC_LANG_POP(C++)
1408
1409   LDFLAGS="$saved_LDFLAGS"
1410 fi
1411
1412 ACX_PROG_GNAT
1413 ACX_PROG_CMP_IGNORE_INITIAL
1414
1415 AC_ARG_ENABLE([bootstrap],
1416 [AS_HELP_STRING([--enable-bootstrap],
1417                 [enable bootstrapping @<:@yes if native build@:>@])],,
1418 enable_bootstrap=default)
1419
1420 # Issue errors and warnings for invalid/strange bootstrap combinations.
1421 if test -r $srcdir/gcc/configure; then
1422   have_compiler=yes
1423 else
1424   have_compiler=no
1425 fi
1426
1427 case "$have_compiler:$host:$target:$enable_bootstrap" in
1428   *:*:*:no) ;;
1429
1430   # Default behavior.  Enable bootstrap if we have a compiler
1431   # and we are in a native configuration.
1432   yes:$build:$build:default)
1433     enable_bootstrap=yes ;;
1434
1435   *:*:*:default)
1436     enable_bootstrap=no ;;
1437
1438   # We have a compiler and we are in a native configuration, bootstrap is ok
1439   yes:$build:$build:yes)
1440     ;;
1441
1442   # Other configurations, but we have a compiler.  Assume the user knows
1443   # what he's doing.
1444   yes:*:*:yes)
1445     AC_MSG_WARN([trying to bootstrap a cross compiler])
1446     ;;
1447
1448   # No compiler: if they passed --enable-bootstrap explicitly, fail
1449   no:*:*:yes)
1450     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1451
1452   # Fail if wrong command line
1453   *)
1454     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1455     ;;
1456 esac
1457
1458 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1459 # C++98 compiler can still start the bootstrap.
1460 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1461   CXX="$CXX -std=gnu++98"
1462 fi
1463
1464 # Used for setting $lt_cv_objdir
1465 _LT_CHECK_OBJDIR
1466
1467 # Check for GMP, MPFR and MPC
1468 gmplibs="-lmpc -lmpfr -lgmp"
1469 gmpinc=
1470 have_gmp=no
1471
1472 # Specify a location for mpc
1473 # check for this first so it ends up on the link line before mpfr.
1474 AC_ARG_WITH(mpc,
1475 [AS_HELP_STRING([--with-mpc=PATH],
1476                 [specify prefix directory for installed MPC package.
1477                  Equivalent to --with-mpc-include=PATH/include
1478                  plus --with-mpc-lib=PATH/lib])])
1479 AC_ARG_WITH(mpc-include,
1480 [AS_HELP_STRING([--with-mpc-include=PATH],
1481                 [specify directory for installed MPC include files])])
1482 AC_ARG_WITH(mpc-lib,
1483 [AS_HELP_STRING([--with-mpc-lib=PATH],
1484                 [specify directory for the installed MPC library])])
1485
1486 if test "x$with_mpc" != x; then
1487   gmplibs="-L$with_mpc/lib $gmplibs"
1488   gmpinc="-I$with_mpc/include $gmpinc"
1489 fi
1490 if test "x$with_mpc_include" != x; then
1491   gmpinc="-I$with_mpc_include $gmpinc"
1492 fi
1493 if test "x$with_mpc_lib" != x; then
1494   gmplibs="-L$with_mpc_lib $gmplibs"
1495 fi
1496 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1497   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1498   gmpinc='-I$$s/mpc/src '"$gmpinc"
1499   # Do not test the mpc version.  Assume that it is sufficient, since
1500   # it is in the source tree, and the library has not been built yet
1501   # but it would be included on the link line in the version check below
1502   # hence making the test fail.
1503   have_gmp=yes
1504 fi
1505
1506 # Specify a location for mpfr
1507 # check for this first so it ends up on the link line before gmp.
1508 AC_ARG_WITH(mpfr-dir,
1509 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1510 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1511 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1512
1513 AC_ARG_WITH(mpfr,
1514 [AS_HELP_STRING([--with-mpfr=PATH],
1515                 [specify prefix directory for installed MPFR package.
1516                  Equivalent to --with-mpfr-include=PATH/include
1517                  plus --with-mpfr-lib=PATH/lib])])
1518 AC_ARG_WITH(mpfr-include,
1519 [AS_HELP_STRING([--with-mpfr-include=PATH],
1520                 [specify directory for installed MPFR include files])])
1521 AC_ARG_WITH(mpfr-lib,
1522 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1523                 [specify directory for the installed MPFR library])])
1524
1525 if test "x$with_mpfr" != x; then
1526   gmplibs="-L$with_mpfr/lib $gmplibs"
1527   gmpinc="-I$with_mpfr/include $gmpinc"
1528 fi
1529 if test "x$with_mpfr_include" != x; then
1530   gmpinc="-I$with_mpfr_include $gmpinc"
1531 fi
1532 if test "x$with_mpfr_lib" != x; then
1533   gmplibs="-L$with_mpfr_lib $gmplibs"
1534 fi
1535 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1536   # MPFR v3.1.0 moved the sources into a src sub-directory.
1537   if ! test -d ${srcdir}/mpfr/src; then
1538     AC_MSG_ERROR([dnl
1539 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1540   fi
1541   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1542   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1543   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1544   # Do not test the mpfr version.  Assume that it is sufficient, since
1545   # it is in the source tree, and the library has not been built yet
1546   # but it would be included on the link line in the version check below
1547   # hence making the test fail.
1548   have_gmp=yes
1549 fi
1550
1551 # Specify a location for gmp
1552 AC_ARG_WITH(gmp-dir,
1553 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1554 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1555 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1556
1557 AC_ARG_WITH(gmp,
1558 [AS_HELP_STRING([--with-gmp=PATH],
1559                 [specify prefix directory for the installed GMP package.
1560                  Equivalent to --with-gmp-include=PATH/include
1561                  plus --with-gmp-lib=PATH/lib])])
1562 AC_ARG_WITH(gmp-include,
1563 [AS_HELP_STRING([--with-gmp-include=PATH],
1564                 [specify directory for installed GMP include files])])
1565 AC_ARG_WITH(gmp-lib,
1566 [AS_HELP_STRING([--with-gmp-lib=PATH],
1567                 [specify directory for the installed GMP library])])
1568
1569
1570 if test "x$with_gmp" != x; then
1571   gmplibs="-L$with_gmp/lib $gmplibs"
1572   gmpinc="-I$with_gmp/include $gmpinc"
1573 fi
1574 if test "x$with_gmp_include" != x; then
1575   gmpinc="-I$with_gmp_include $gmpinc"
1576 fi
1577 if test "x$with_gmp_lib" != x; then
1578   gmplibs="-L$with_gmp_lib $gmplibs"
1579 fi
1580 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1581   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1582   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1583   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1584   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1585   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1586   # Do not test the gmp version.  Assume that it is sufficient, since
1587   # it is in the source tree, and the library has not been built yet
1588   # but it would be included on the link line in the version check below
1589   # hence making the test fail.
1590   have_gmp=yes
1591 fi
1592
1593 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1594   have_gmp=yes
1595   saved_CFLAGS="$CFLAGS"
1596   CFLAGS="$CFLAGS $gmpinc"
1597   # Check for the recommended and required versions of GMP.
1598   AC_MSG_CHECKING([for the correct version of gmp.h])
1599   AC_TRY_COMPILE([#include "gmp.h"],[
1600   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1601   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1602   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1603   choke me
1604   #endif
1605   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1606   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1607   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1608   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1609   choke me
1610   #endif
1611   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1612    [AC_MSG_RESULT([no]); have_gmp=no])
1613
1614   # If we have GMP, check the MPFR version.
1615   if test x"$have_gmp" = xyes; then
1616     # Check for the recommended and required versions of MPFR.
1617     AC_MSG_CHECKING([for the correct version of mpfr.h])
1618     AC_TRY_COMPILE([#include <gmp.h>
1619     #include <mpfr.h>],[
1620     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1621     choke me
1622     #endif
1623     ], [AC_TRY_COMPILE([#include <gmp.h>
1624     #include <mpfr.h>],[
1625     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1626     choke me
1627     #endif
1628     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1629      [AC_MSG_RESULT([no]); have_gmp=no])
1630   fi
1631
1632   # Check for the MPC header version.
1633   if test x"$have_gmp" = xyes ; then
1634     # Check for the recommended and required versions of MPC.
1635     AC_MSG_CHECKING([for the correct version of mpc.h])
1636     AC_TRY_COMPILE([#include <mpc.h>],[
1637     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1638     choke me
1639     #endif
1640     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1641     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1642     choke me
1643     #endif
1644     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1645      [AC_MSG_RESULT([no]); have_gmp=no])
1646   fi
1647
1648   # Now check the MPFR library.
1649   if test x"$have_gmp" = xyes; then
1650     saved_LIBS="$LIBS"
1651     LIBS="$LIBS $gmplibs"
1652     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1653     AC_TRY_LINK([#include <mpc.h>],[
1654     mpfr_t n;
1655     mpfr_t x;
1656     mpc_t c;
1657     int t;
1658     mpfr_init (n);
1659     mpfr_init (x);
1660     mpfr_atan2 (n, n, x, MPFR_RNDN);
1661     mpfr_erfc (n, x, MPFR_RNDN);
1662     mpfr_subnormalize (x, t, MPFR_RNDN);
1663     mpfr_clear(n);
1664     mpfr_clear(x);
1665     mpc_init2 (c, 53);
1666     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1667     mpc_cosh (c, c, MPC_RNDNN);
1668     mpc_pow (c, c, c, MPC_RNDNN);
1669     mpc_acosh (c, c, MPC_RNDNN);
1670     mpc_clear (c);
1671     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1672     LIBS="$saved_LIBS"
1673   fi
1674
1675   CFLAGS="$saved_CFLAGS"
1676
1677 # The library versions listed in the error message below should match
1678 # the HARD-minimums enforced above.
1679   if test x$have_gmp != xyes; then
1680     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1681 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1682 their locations.  Source code for these libraries can be found at
1683 their respective hosting sites as well as at
1684 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1685 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1686 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1687 make sure that you have installed both the libraries and the header
1688 files.  They may be located in separate packages.])
1689   fi
1690 fi
1691
1692 # Flags needed for both GMP, MPFR and/or MPC.
1693 AC_SUBST(gmplibs)
1694 AC_SUBST(gmpinc)
1695 AC_SUBST(extra_mpfr_configure_flags)
1696 AC_SUBST(extra_mpc_gmp_configure_flags)
1697 AC_SUBST(extra_mpc_mpfr_configure_flags)
1698 AC_SUBST(extra_isl_gmp_configure_flags)
1699
1700 # Libraries to use for stage1 or when not bootstrapping.
1701 AC_ARG_WITH(stage1-libs,
1702 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1703 [if test "$withval" = "no" -o "$withval" = "yes"; then
1704    stage1_libs=
1705  else
1706    stage1_libs=$withval
1707  fi],
1708 [stage1_libs=])
1709 AC_SUBST(stage1_libs)
1710
1711 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1712 # default is yes if gcc is being built; no otherwise.  The reason for
1713 # this default is that gdb is sometimes linked against GNU Source
1714 # Highlight, which is a shared library that uses C++ exceptions.  In
1715 # this case, -static-libstdc++ will cause crashes.
1716 AC_ARG_WITH(static-standard-libraries,
1717 [AS_HELP_STRING([--with-static-standard-libraries],
1718                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1719 [], [with_static_standard_libraries=auto])
1720 if test "$with_static_standard_libraries" = auto; then
1721   with_static_standard_libraries=$have_compiler
1722 fi
1723
1724 # Linker flags to use for stage1 or when not bootstrapping.
1725 AC_ARG_WITH(stage1-ldflags,
1726 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1727 [if test "$withval" = "no" -o "$withval" = "yes"; then
1728    stage1_ldflags=
1729  else
1730    stage1_ldflags=$withval
1731  fi],
1732 [stage1_ldflags=
1733  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1734  # if supported.  But if the user explicitly specified the libraries to use,
1735  # trust that they are doing what they want.
1736  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1737      -a "$have_static_libs" = yes; then
1738    stage1_ldflags="-static-libstdc++ -static-libgcc"
1739  fi])
1740 AC_SUBST(stage1_ldflags)
1741
1742 # Libraries to use for stage2 and later builds.
1743 AC_ARG_WITH(boot-libs,
1744 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1745 [if test "$withval" = "no" -o "$withval" = "yes"; then
1746    poststage1_libs=
1747  else
1748    poststage1_libs=$withval
1749  fi],
1750 [poststage1_libs=])
1751 AC_SUBST(poststage1_libs)
1752
1753 # Linker flags to use for stage2 and later builds.
1754 AC_ARG_WITH(boot-ldflags,
1755 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1756                 [linker flags for stage2 and later])],
1757 [if test "$withval" = "no" -o "$withval" = "yes"; then
1758    poststage1_ldflags=
1759  else
1760    poststage1_ldflags=$withval
1761  fi],
1762 [poststage1_ldflags=
1763  # In stages 2 and 3, default to linking libstdc++ and libgcc
1764  # statically.  But if the user explicitly specified the libraries to
1765  # use, trust that they are doing what they want.
1766  if test "$poststage1_libs" = ""; then
1767    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1768  fi])
1769 AC_SUBST(poststage1_ldflags)
1770
1771 # GCC GRAPHITE dependency isl.
1772 # Basic setup is inlined here, actual checks are in config/isl.m4
1773
1774 AC_ARG_WITH(isl,
1775   [AS_HELP_STRING(
1776    [--with-isl=PATH],
1777    [Specify prefix directory for the installed isl package.
1778     Equivalent to --with-isl-include=PATH/include
1779     plus --with-isl-lib=PATH/lib])])
1780
1781 # Treat --without-isl as a request to disable
1782 # GRAPHITE support and skip all following checks.
1783 if test "x$with_isl" != "xno"; then
1784   # Check for isl
1785   dnl Provide configure switches and initialize islinc & isllibs
1786   dnl with user input.
1787   ISL_INIT_FLAGS
1788   dnl The versions of isl that work for Graphite
1789   ISL_CHECK_VERSION()
1790   dnl Only execute fail-action, if isl has been requested.
1791   ISL_IF_FAILED([
1792     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1793 fi
1794
1795 # If the isl check failed, disable builds of in-tree variant of isl
1796 if test "x$with_isl" = xno ||
1797    test "x$gcc_cv_isl" = xno; then
1798   noconfigdirs="$noconfigdirs isl"
1799   islinc=
1800 fi
1801
1802 AC_SUBST(isllibs)
1803 AC_SUBST(islinc)
1804
1805 # Check for LTO support.
1806 AC_ARG_ENABLE(lto,
1807 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1808 enable_lto=$enableval,
1809 enable_lto=yes; default_enable_lto=yes)
1810
1811 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1812   build_lto_plugin=yes
1813 ],[if test x"$default_enable_lto" = x"yes" ; then
1814     case $target in
1815       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1816       # On other non-ELF platforms, LTO has yet to be validated.
1817       *) enable_lto=no ;;
1818     esac
1819   else
1820   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1821   # It would also be nice to check the binutils support, but we don't
1822   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1823   # warn during gcc/ subconfigure; unless you're bootstrapping with
1824   # -flto it won't be needed until after installation anyway.
1825     case $target in
1826       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1827       *) if test x"$enable_lto" = x"yes"; then
1828         AC_MSG_ERROR([LTO support is not enabled for this target.])
1829         fi
1830       ;;
1831     esac
1832   fi
1833   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1834   # Build it unless LTO was explicitly disabled.
1835   case $target in
1836     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1837     *) ;;
1838   esac
1839 ])
1840
1841 AC_ARG_ENABLE(linker-plugin-configure-flags,
1842   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1843     [additional flags for configuring linker plugins @<:@none@:>@])],
1844   extra_linker_plugin_configure_flags=$enableval,
1845   extra_linker_plugin_configure_flags=)
1846 AC_SUBST(extra_linker_plugin_configure_flags)
1847 AC_ARG_ENABLE(linker-plugin-flags,
1848   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1849     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1850   extra_linker_plugin_flags=$enableval,
1851   extra_linker_plugin_flags=)
1852 AC_SUBST(extra_linker_plugin_flags)
1853
1854 # Enable --enable-host-shared.
1855 # Checked early to determine whether jit is an 'all' language
1856 AC_ARG_ENABLE(host-shared,
1857 [AS_HELP_STRING([--enable-host-shared],
1858                 [build host code as shared libraries])],
1859 [host_shared=$enableval], [host_shared=no])
1860 AC_SUBST(host_shared)
1861
1862 # By default, C and C++ are the only stage 1 languages.
1863 stage1_languages=,c,
1864
1865 # Target libraries that we bootstrap.
1866 bootstrap_target_libs=,target-libgcc,
1867
1868 # Figure out what language subdirectories are present.
1869 # Look if the user specified --enable-languages="..."; if not, use
1870 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1871 # go away some day.
1872 # NB:  embedded tabs in this IF block -- do not untabify
1873 if test -d ${srcdir}/gcc; then
1874   if test x"${enable_languages+set}" != xset; then
1875     if test x"${LANGUAGES+set}" = xset; then
1876       enable_languages="${LANGUAGES}"
1877         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1878     else
1879       enable_languages=default
1880     fi
1881   else
1882     if test x"${enable_languages}" = x ||
1883        test x"${enable_languages}" = xyes;
1884        then
1885       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1886       exit 1
1887     fi
1888   fi
1889   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1890
1891   # 'f95' is the old name for the 'fortran' language. We issue a warning
1892   # and make the substitution.
1893   case ,${enable_languages}, in
1894     *,f95,*)
1895       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1896       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1897       ;;
1898   esac
1899
1900   # If bootstrapping, C++ must be enabled.
1901   case ",$enable_languages,:$enable_bootstrap" in
1902     *,c++,*:*) ;;
1903     *:yes)
1904       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1905         enable_languages="${enable_languages},c++"
1906       else
1907         AC_MSG_ERROR([bootstrapping requires c++ sources])
1908       fi
1909       ;;
1910   esac
1911
1912   # First scan to see if an enabled language requires some other language.
1913   # We assume that a given config-lang.in will list all the language
1914   # front ends it requires, even if some are required indirectly.
1915   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1916     case ${lang_frag} in
1917       ..) ;;
1918       # The odd quoting in the next line works around
1919       # an apparent bug in bash 1.12 on linux.
1920       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1921       *)
1922         # From the config-lang.in, get $language, $lang_requires, and
1923         # $lang_requires_boot_languages.
1924         language=
1925         lang_requires=
1926         lang_requires_boot_languages=
1927         # set srcdir during sourcing lang_frag to the gcc dir.
1928         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1929         # polutes this shell
1930         saved_srcdir=${srcdir}
1931         srcdir=${srcdir}/gcc . ${lang_frag}
1932         srcdir=${saved_srcdir}
1933         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1934           case ,${enable_languages}, in
1935             *,$other,*) ;;
1936             *,default,*) ;;
1937             *,all,*) ;;
1938             *,$language,*)
1939               echo " \`$other' language required by \`$language'; enabling" 1>&2
1940               enable_languages="${enable_languages},${other}"
1941               ;;
1942           esac
1943         done
1944         for other in ${lang_requires_boot_languages} ; do
1945           if test "$other" != "c"; then
1946             case ,${enable_stage1_languages}, in
1947               *,$other,*) ;;
1948               *,default,*) ;;
1949               *,all,*) ;;
1950               *)
1951                 case ,${enable_languages}, in
1952                   *,$language,*)
1953                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1954                     enable_stage1_languages="$enable_stage1_languages,${other}"
1955                     ;;
1956                 esac
1957                 ;;
1958             esac
1959           fi
1960         done
1961         ;;
1962     esac
1963   done
1964
1965   new_enable_languages=,c,
1966
1967   # If LTO is enabled, add the LTO front end.
1968   if test "$enable_lto" = "yes" ; then
1969     case ,${enable_languages}, in
1970       *,lto,*) ;;
1971       *) enable_languages="${enable_languages},lto" ;;
1972     esac
1973     if test "${build_lto_plugin}" = "yes" ; then
1974       configdirs="$configdirs lto-plugin"
1975     fi
1976   fi
1977
1978   # If we're building an offloading compiler, add the LTO front end.
1979   if test x"$enable_as_accelerator_for" != x ; then
1980     case ,${enable_languages}, in
1981       *,lto,*) ;;
1982       *) enable_languages="${enable_languages},lto" ;;
1983     esac
1984   fi
1985
1986   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1987   potential_languages=,c,
1988
1989   enabled_target_libs=
1990   disabled_target_libs=
1991
1992   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1993     case ${lang_frag} in
1994       ..) ;;
1995       # The odd quoting in the next line works around
1996       # an apparent bug in bash 1.12 on linux.
1997       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1998       *)
1999         # From the config-lang.in, get $language, $target_libs,
2000         # $lang_dirs, $boot_language, and $build_by_default
2001         language=
2002         target_libs=
2003         lang_dirs=
2004         subdir_requires=
2005         boot_language=no
2006         build_by_default=yes
2007         # set srcdir during sourcing.  See above about save & restore
2008         saved_srcdir=${srcdir}
2009         srcdir=${srcdir}/gcc . ${lang_frag}
2010         srcdir=${saved_srcdir}
2011         if test x${language} = x; then
2012           echo "${lang_frag} doesn't set \$language." 1>&2
2013           exit 1
2014         fi
2015
2016         if test "$language" = "c++"; then
2017           boot_language=yes
2018         fi
2019
2020         add_this_lang=no
2021         # C is always enabled, so no need to add it again
2022         if test "$language" != "c"; then
2023           case ,${enable_languages}, in
2024             *,${language},*)
2025               # Language was explicitly selected; include it
2026               add_this_lang=yes
2027               ;;
2028             *,all,*)
2029               # All languages are enabled
2030               add_this_lang=all
2031               ;;
2032             *,default,*)
2033               # 'default' was selected, select it if it is a default language
2034               add_this_lang=${build_by_default}
2035               ;;
2036           esac
2037         fi
2038
2039         # Disable languages that need other directories if these aren't available.
2040         for i in $subdir_requires; do
2041           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2042           case ${add_this_lang} in
2043             yes)
2044               # Specifically requested language; tell them.
2045               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2046               ;;
2047             all)
2048               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2049               add_this_lang=unsupported
2050               ;;
2051             *)
2052               # Silently disable.
2053               add_this_lang=unsupported
2054               ;;
2055           esac
2056         done
2057
2058         # Disable Ada if no preexisting GNAT is available.
2059         case ${add_this_lang}:${language}:${have_gnat} in
2060           yes:ada:no)
2061             # Specifically requested language; tell them.
2062             AC_MSG_ERROR([GNAT is required to build $language])
2063             ;;
2064           all:ada:no)
2065             AC_MSG_WARN([GNAT is required to build $language])
2066             add_this_lang=unsupported
2067             ;;
2068           *:ada:no)
2069             # Silently disable.
2070             add_this_lang=unsupported
2071             ;;
2072         esac
2073
2074         # Disable jit if -enable-host-shared not specified
2075         case ${add_this_lang}:${language}:${host_shared} in
2076           yes:jit:no)
2077             # PR jit/64780: explicitly specify --enable-host-shared
2078             AC_MSG_ERROR([
2079 Enabling language "jit" requires --enable-host-shared.
2080
2081 --enable-host-shared typically slows the rest of the compiler down by
2082 a few %, so you must explicitly enable it.
2083
2084 If you want to build both the jit and the regular compiler, it is often
2085 best to do this via two separate configure/builds, in separate
2086 directories, to avoid imposing the performance cost of
2087 --enable-host-shared on the regular compiler.])
2088             ;;
2089           all:jit:no)
2090             AC_MSG_WARN([--enable-host-shared required to build $language])
2091             add_this_lang=unsupported
2092             ;;
2093           *:jit:no)
2094             # Silently disable.
2095             add_this_lang=unsupported
2096             ;;
2097         esac
2098
2099         # Disable a language that is unsupported by the target.
2100         case "${add_this_lang}: $unsupported_languages " in
2101           no:*) ;;
2102           unsupported:*) ;;
2103           *:*" $language "*)
2104             AC_MSG_WARN([${language} not supported for this target])
2105             add_this_lang=unsupported
2106             ;;
2107         esac
2108
2109         case $add_this_lang in
2110           unsupported)
2111             # Remove language-dependent dirs.
2112             disabled_target_libs="$disabled_target_libs $target_libs"
2113             noconfigdirs="$noconfigdirs $lang_dirs"
2114             ;;
2115           no)
2116             # Remove language-dependent dirs; still show language as supported.
2117             disabled_target_libs="$disabled_target_libs $target_libs"
2118             noconfigdirs="$noconfigdirs $lang_dirs"
2119             potential_languages="${potential_languages}${language},"
2120             ;;
2121           all|yes)
2122             new_enable_languages="${new_enable_languages}${language},"
2123             potential_languages="${potential_languages}${language},"
2124             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2125             enabled_target_libs="$enabled_target_libs $target_libs"
2126             case "${boot_language}:,$enable_stage1_languages," in
2127               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2128                 # Add to (comma-separated) list of stage 1 languages.
2129                 case ",$stage1_languages," in
2130                   *,$language,* | ,yes, | ,all,) ;;
2131                   *) stage1_languages="${stage1_languages}${language}," ;;
2132                 esac
2133                 # We need to bootstrap any supporting libraries.
2134                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2135                 ;;
2136             esac
2137             ;;
2138         esac
2139         ;;
2140     esac
2141   done
2142
2143   # Add target libraries which are only needed for disabled languages
2144   # to noconfigdirs.
2145   if test -n "$disabled_target_libs"; then
2146     for dir in $disabled_target_libs; do
2147       case " $enabled_target_libs " in
2148       *" ${dir} "*) ;;
2149       *) noconfigdirs="$noconfigdirs $dir" ;;
2150       esac
2151     done
2152   fi
2153
2154   AC_ARG_ENABLE(stage1-languages,
2155   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2156                   [choose additional languages to build during
2157                   stage1.  Mostly useful for compiler development])],
2158   [case ,${enable_stage1_languages}, in
2159     ,no,|,,)
2160       # Set it to something that will have no effect in the loop below
2161       enable_stage1_languages=c ;;
2162     ,yes,)
2163       enable_stage1_languages=`echo $new_enable_languages | \
2164         sed -e "s/^,//" -e "s/,$//" ` ;;
2165     *,all,*)
2166       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2167         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2168   esac
2169
2170   # Add "good" languages from enable_stage1_languages to stage1_languages,
2171   # while "bad" languages go in missing_languages.  Leave no duplicates.
2172   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2173     case $potential_languages in
2174       *,$i,*)
2175         case $stage1_languages in
2176           *,$i,*) ;;
2177           *) stage1_languages="$stage1_languages$i," ;;
2178         esac ;;
2179       *)
2180         case $missing_languages in
2181           *,$i,*) ;;
2182           *) missing_languages="$missing_languages$i," ;;
2183         esac ;;
2184      esac
2185   done])
2186
2187   # Remove leading/trailing commas that were added for simplicity
2188   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2189   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2190   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2191   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2192
2193   if test "x$missing_languages" != x; then
2194     AC_MSG_ERROR([
2195 The following requested languages could not be built: ${missing_languages}
2196 Supported languages are: ${potential_languages}])
2197   fi
2198   if test "x$new_enable_languages" != "x$enable_languages"; then
2199     echo The following languages will be built: ${new_enable_languages}
2200     enable_languages="$new_enable_languages"
2201   fi
2202
2203   AC_SUBST(stage1_languages)
2204   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2205 fi
2206
2207 # Handle --disable-<component> generically.
2208 for dir in $configdirs $build_configdirs $target_configdirs ; do
2209   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2210   varname=`echo $dirname | sed -e s/+/_/g`
2211   if eval test x\${enable_${varname}} "=" xno ; then
2212     noconfigdirs="$noconfigdirs $dir"
2213   fi
2214 done
2215
2216 # Check for Boehm's garbage collector
2217 AC_ARG_ENABLE(objc-gc,
2218 [AS_HELP_STRING([--enable-objc-gc],
2219                 [enable use of Boehm's garbage collector with the
2220                  GNU Objective-C runtime])])
2221 AC_ARG_WITH([target-bdw-gc],
2222 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2223                 [specify prefix directory for installed bdw-gc package.
2224                  Equivalent to --with-target-bdw-gc-include=PATH/include
2225                  plus --with-target-bdw-gc-lib=PATH/lib])])
2226 AC_ARG_WITH([target-bdw-gc-include],
2227 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2228                 [specify directories for installed bdw-gc include files])])
2229 AC_ARG_WITH([target-bdw-gc-lib],
2230 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2231                 [specify directories for installed bdw-gc library])])
2232
2233 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2234   AC_MSG_CHECKING([for bdw garbage collector])
2235   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2236     dnl no bdw-gw options, assume default locations
2237     AC_MSG_RESULT([using bdw-gc in default locations])
2238   else
2239     dnl bdw-gw options, first error checking, complete checking in libobjc
2240     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2241       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2242     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2243       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2244     else
2245       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2246     fi
2247   fi
2248 esac
2249
2250 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2251 case ,${enable_languages}, in
2252   *,c++,*)
2253     # Disable libitm, libsanitizer if we're not building libstdc++
2254     case "${noconfigdirs}" in
2255       *target-libstdc++-v3*)
2256         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2257         ;;
2258       *) ;;
2259     esac
2260     ;;
2261   *)
2262     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2263     ;;
2264 esac
2265
2266 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2267 # $build_configdirs and $target_configdirs.
2268 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2269
2270 notsupp=""
2271 for dir in . $skipdirs $noconfigdirs ; do
2272   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2273   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2274     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2275     if test -r $srcdir/$dirname/configure ; then
2276       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2277         true
2278       else
2279         notsupp="$notsupp $dir"
2280       fi
2281     fi
2282   fi
2283   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2284     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2285     if test -r $srcdir/$dirname/configure ; then
2286       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2287         true
2288       else
2289         notsupp="$notsupp $dir"
2290       fi
2291     fi
2292   fi
2293   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2294     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2295     if test -r $srcdir/$dirname/configure ; then
2296       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2297         true
2298       else
2299         notsupp="$notsupp $dir"
2300       fi
2301     fi
2302   fi
2303 done
2304
2305 # Quietly strip out all directories which aren't configurable in this tree.
2306 # This relies on all configurable subdirectories being autoconfiscated, which
2307 # is now the case.
2308 build_configdirs_all="$build_configdirs"
2309 build_configdirs=
2310 for i in ${build_configdirs_all} ; do
2311   j=`echo $i | sed -e s/build-//g`
2312   if test -f ${srcdir}/$j/configure ; then
2313     build_configdirs="${build_configdirs} $i"
2314   fi
2315 done
2316
2317 configdirs_all="$configdirs"
2318 configdirs=
2319 for i in ${configdirs_all} ; do
2320   if test -f ${srcdir}/$i/configure ; then
2321     configdirs="${configdirs} $i"
2322   fi
2323 done
2324
2325 target_configdirs_all="$target_configdirs"
2326 target_configdirs=
2327 for i in ${target_configdirs_all} ; do
2328   j=`echo $i | sed -e s/target-//g`
2329   if test -f ${srcdir}/$j/configure ; then
2330     target_configdirs="${target_configdirs} $i"
2331   fi
2332 done
2333
2334 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2335 # so we have to add it after the preceding checks.
2336 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2337 then
2338   case " $configdirs " in
2339     *" libiberty "*)
2340       # If we can build libiberty, we can also build libiberty-linker-plugin.
2341       configdirs="$configdirs libiberty-linker-plugin"
2342       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2343         --with-libiberty=../libiberty-linker-plugin";;
2344     *)
2345       AC_MSG_ERROR([libiberty missing]);;
2346   esac
2347 fi
2348
2349 # Sometimes we have special requirements for the host libiberty.
2350 extra_host_libiberty_configure_flags=
2351 extra_host_zlib_configure_flags=
2352 case " $configdirs " in
2353   *" lto-plugin "* | *" libcc1 "*)
2354     # When these are to be built as shared libraries, the same applies to
2355     # libiberty.
2356     extra_host_libiberty_configure_flags=--enable-shared
2357     ;;
2358   *" bfd "*)
2359     # When bfd is to be built as a shared library, the same applies to
2360     # zlib.
2361     if test "$enable_shared" = "yes"; then
2362       extra_host_zlib_configure_flags=--enable-host-shared
2363     fi
2364     ;;
2365 esac
2366 AC_SUBST(extra_host_libiberty_configure_flags)
2367 AC_SUBST(extra_host_zlib_configure_flags)
2368
2369 # Produce a warning message for the subdirs we can't configure.
2370 # This isn't especially interesting in the Cygnus tree, but in the individual
2371 # FSF releases, it's important to let people know when their machine isn't
2372 # supported by the one or two programs in a package.
2373
2374 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2375   # If $appdirs is non-empty, at least one of those directories must still
2376   # be configured, or we error out.  (E.g., if the gas release supports a
2377   # specified target in some subdirs but not the gas subdir, we shouldn't
2378   # pretend that all is well.)
2379   if test -n "$appdirs" ; then
2380     for dir in $appdirs ; do
2381       if test -r $dir/Makefile.in ; then
2382         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2383           appdirs=""
2384           break
2385         fi
2386         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2387           appdirs=""
2388           break
2389         fi
2390       fi
2391     done
2392     if test -n "$appdirs" ; then
2393       echo "*** This configuration is not supported by this package." 1>&2
2394       exit 1
2395     fi
2396   fi
2397   # Okay, some application will build, or we don't care to check.  Still
2398   # notify of subdirs not getting built.
2399   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2400   echo "    ${notsupp}" 1>&2
2401   echo "    (Any other directories should still work fine.)" 1>&2
2402 fi
2403
2404 case "$host" in
2405   *msdosdjgpp*)
2406     enable_gdbtk=no ;;
2407 esac
2408
2409 # To find our prefix, in gcc_cv_tool_prefix.
2410 ACX_TOOL_DIRS
2411
2412 copy_dirs=
2413
2414 AC_ARG_WITH([build-sysroot],
2415   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2416                   [use sysroot as the system root during the build])],
2417   [if test x"$withval" != x ; then
2418      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2419    fi],
2420   [SYSROOT_CFLAGS_FOR_TARGET=])
2421 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2422
2423 AC_ARG_WITH([debug-prefix-map],
2424   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2425                   [map A to B, C to D ... in debug information])],
2426   [if test x"$withval" != x; then
2427      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2428      for debug_map in $withval; do
2429        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2430      done
2431    fi],
2432   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2433 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2434
2435 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2436 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2437 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2438 # We want to ensure that TARGET libraries (which we know are built with
2439 # gcc) are built with "-O2 -g", so include those options when setting
2440 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2441 if test "x$CFLAGS_FOR_TARGET" = x; then
2442   if test "x${is_cross_compiler}" = xyes; then
2443     CFLAGS_FOR_TARGET="-g -O2"
2444   else
2445     CFLAGS_FOR_TARGET=$CFLAGS
2446     case " $CFLAGS " in
2447       *" -O2 "*) ;;
2448       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2449     esac
2450     case " $CFLAGS " in
2451       *" -g "* | *" -g3 "*) ;;
2452       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2453     esac
2454   fi
2455 fi
2456 AC_SUBST(CFLAGS_FOR_TARGET)
2457
2458 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2459   if test "x${is_cross_compiler}" = xyes; then
2460     CXXFLAGS_FOR_TARGET="-g -O2"
2461   else
2462     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2463     case " $CXXFLAGS " in
2464       *" -O2 "*) ;;
2465       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2466     esac
2467     case " $CXXFLAGS " in
2468       *" -g "* | *" -g3 "*) ;;
2469       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2470     esac
2471   fi
2472 fi
2473 AC_SUBST(CXXFLAGS_FOR_TARGET)
2474
2475 AC_SUBST(LDFLAGS_FOR_TARGET)
2476
2477 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2478 # the named directory are copied to $(tooldir)/sys-include.
2479 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2480   if test x${is_cross_compiler} = xno ; then
2481     echo 1>&2 '***' --with-headers is only supported when cross compiling
2482     exit 1
2483   fi
2484   if test x"${with_headers}" != xyes ; then
2485     x=${gcc_cv_tool_prefix}
2486     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2487   fi
2488 fi
2489
2490 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2491 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2492 # are permitted.
2493 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2494   if test x${is_cross_compiler} = xno ; then
2495     echo 1>&2 '***' --with-libs is only supported when cross compiling
2496     exit 1
2497   fi
2498   if test x"${with_libs}" != xyes ; then
2499     # Copy the libraries in reverse order, so that files in the first named
2500     # library override files in subsequent libraries.
2501     x=${gcc_cv_tool_prefix}
2502     for l in ${with_libs}; do
2503       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2504     done
2505   fi
2506 fi
2507
2508 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2509 #
2510 # This is done by determining whether or not the appropriate directory
2511 # is available, and by checking whether or not specific configurations
2512 # have requested that this magic not happen.
2513 #
2514 # The command line options always override the explicit settings in
2515 # configure.ac, and the settings in configure.ac override this magic.
2516 #
2517 # If the default for a toolchain is to use GNU as and ld, and you don't
2518 # want to do that, then you should use the --without-gnu-as and
2519 # --without-gnu-ld options for the configure script.  Similarly, if
2520 # the default is to use the included zlib and you don't want to do that,
2521 # you should use the --with-system-zlib option for the configure script.
2522
2523 if test x${use_gnu_as} = x &&
2524    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2525   with_gnu_as=yes
2526   extra_host_args="$extra_host_args --with-gnu-as"
2527 fi
2528
2529 if test x${use_gnu_ld} = x &&
2530    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2531   with_gnu_ld=yes
2532   extra_host_args="$extra_host_args --with-gnu-ld"
2533 fi
2534
2535 if test x${use_included_zlib} = x &&
2536    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2537   :
2538 else
2539   with_system_zlib=yes
2540   extra_host_args="$extra_host_args --with-system-zlib"
2541 fi
2542
2543 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2544 # can detect this case.
2545
2546 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2547   with_newlib=yes
2548   extra_host_args="$extra_host_args --with-newlib"
2549 fi
2550
2551 # Handle ${copy_dirs}
2552 set fnord ${copy_dirs}
2553 shift
2554 while test $# != 0 ; do
2555   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2556     :
2557   else
2558     echo Copying $1 to $2
2559
2560     # Use the install script to create the directory and all required
2561     # parent directories.
2562     if test -d $2 ; then
2563       :
2564     else
2565       echo >config.temp
2566       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2567     fi
2568
2569     # Copy the directory, assuming we have tar.
2570     # FIXME: Should we use B in the second tar?  Not all systems support it.
2571     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2572
2573     # It is the responsibility of the user to correctly adjust all
2574     # symlinks.  If somebody can figure out how to handle them correctly
2575     # here, feel free to add the code.
2576
2577     echo $1 > $2/COPIED
2578   fi
2579   shift; shift
2580 done
2581
2582 # Determine a target-dependent exec_prefix that the installed
2583 # gcc will search in.  Keep this list sorted by triplet, with
2584 # the *-*-osname triplets last.
2585 md_exec_prefix=
2586 case "${target}" in
2587   i[[34567]]86-pc-msdosdjgpp*)
2588     md_exec_prefix=/dev/env/DJDIR/bin
2589     ;;
2590   *-*-hpux* | \
2591   *-*-nto-qnx* | \
2592   *-*-solaris2*)
2593     md_exec_prefix=/usr/ccs/bin
2594     ;;
2595 esac
2596
2597 extra_arflags_for_target=
2598 extra_nmflags_for_target=
2599 extra_ranlibflags_for_target=
2600 target_makefile_frag=/dev/null
2601 case "${target}" in
2602   spu-*-*)
2603     target_makefile_frag="config/mt-spu"
2604     ;;
2605   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2606     target_makefile_frag="config/mt-sde"
2607     ;;
2608   mipsisa*-*-elfoabi*)
2609     target_makefile_frag="config/mt-mips-elfoabi"
2610     ;;
2611   mips*-*-*linux* | mips*-*-gnu*)
2612     target_makefile_frag="config/mt-mips-gnu"
2613     ;;
2614   nios2-*-elf*)
2615     target_makefile_frag="config/mt-nios2-elf"
2616     ;;
2617   *-*-linux-android*)
2618     target_makefile_frag="config/mt-android"
2619     ;;
2620   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2621     target_makefile_frag="config/mt-gnu"
2622     ;;
2623   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2624     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2625     # commands to handle both 32-bit and 64-bit objects.  These flags are
2626     # harmless if we're using GNU nm or ar.
2627     extra_arflags_for_target=" -X32_64"
2628     extra_nmflags_for_target=" -B -X32_64"
2629     ;;
2630 esac
2631
2632 alphaieee_frag=/dev/null
2633 case $target in
2634   alpha*-*-*)
2635     # This just makes sure to use the -mieee option to build target libs.
2636     # This should probably be set individually by each library.
2637     alphaieee_frag="config/mt-alphaieee"
2638     ;;
2639 esac
2640
2641 # If --enable-target-optspace always use -Os instead of -O2 to build
2642 # the target libraries, similarly if it is not specified, use -Os
2643 # on selected platforms.
2644 ospace_frag=/dev/null
2645 case "${enable_target_optspace}:${target}" in
2646   yes:*)
2647     ospace_frag="config/mt-ospace"
2648     ;;
2649   :d30v-*)
2650     ospace_frag="config/mt-d30v"
2651     ;;
2652   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2653     ospace_frag="config/mt-ospace"
2654     ;;
2655   no:* | :*)
2656     ;;
2657   *)
2658     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2659     ;;
2660 esac
2661
2662 # Some systems (e.g., one of the i386-aix systems the gas testers are
2663 # using) don't handle "\$" correctly, so don't use it here.
2664 tooldir='${exec_prefix}'/${target_noncanonical}
2665 build_tooldir=${tooldir}
2666
2667 # Create a .gdbinit file which runs the one in srcdir
2668 # and tells GDB to look there for source files.
2669
2670 if test -r ${srcdir}/.gdbinit ; then
2671   case ${srcdir} in
2672     .) ;;
2673     *) cat > ./.gdbinit <<EOF
2674 # ${NO_EDIT}
2675 dir ${srcdir}
2676 dir .
2677 source ${srcdir}/.gdbinit
2678 EOF
2679     ;;
2680   esac
2681 fi
2682
2683 # Make sure that the compiler is able to generate an executable.  If it
2684 # can't, we are probably in trouble.  We don't care whether we can run the
2685 # executable--we might be using a cross compiler--we only care whether it
2686 # can be created.  At this point the main configure script has set CC.
2687 we_are_ok=no
2688 echo "int main () { return 0; }" > conftest.c
2689 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2690 if test $? = 0 ; then
2691   if test -s conftest || test -s conftest.exe ; then
2692     we_are_ok=yes
2693   fi
2694 fi
2695 case $we_are_ok in
2696   no)
2697     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2698     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2699     rm -f conftest*
2700     exit 1
2701     ;;
2702 esac
2703 rm -f conftest*
2704
2705 # Decide which environment variable is used to find dynamic libraries.
2706 case "${host}" in
2707   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2708   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2709   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2710   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2711 esac
2712
2713 # On systems where the dynamic library environment variable is PATH,
2714 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2715 # built executables to PATH.
2716 if test "$RPATH_ENVVAR" = PATH; then
2717   GCC_SHLIB_SUBDIR=/shlib
2718 else
2719   GCC_SHLIB_SUBDIR=
2720 fi
2721
2722 # Adjust the toplevel makefile according to whether bootstrap was selected.
2723 case $enable_bootstrap in
2724   yes)
2725     bootstrap_suffix=bootstrap
2726     BUILD_CONFIG=bootstrap-debug
2727     ;;
2728   no)
2729     bootstrap_suffix=no-bootstrap
2730     BUILD_CONFIG=
2731     ;;
2732 esac
2733
2734 AC_MSG_CHECKING(for default BUILD_CONFIG)
2735
2736 AC_ARG_WITH([build-config],
2737   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2738                   [use config/NAME.mk build configuration])],
2739   [case $with_build_config in
2740    yes) with_build_config= ;;
2741    no) with_build_config= BUILD_CONFIG= ;;
2742    esac])
2743
2744 if test "x${with_build_config}" != x; then
2745   BUILD_CONFIG=$with_build_config
2746 else
2747   case $BUILD_CONFIG in
2748   bootstrap-debug)
2749     if echo "int f (void) { return 0; }" > conftest.c &&
2750        ${CC} -c conftest.c &&
2751        mv conftest.o conftest.o.g0 &&
2752        ${CC} -c -g conftest.c &&
2753        mv conftest.o conftest.o.g &&
2754        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2755       :
2756     else
2757       BUILD_CONFIG=
2758     fi
2759     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2760     ;;
2761   esac
2762 fi
2763 AC_MSG_RESULT($BUILD_CONFIG)
2764 AC_SUBST(BUILD_CONFIG)
2765
2766 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2767 AC_MSG_CHECKING([for --enable-vtable-verify])
2768 AC_ARG_ENABLE(vtable-verify,
2769 [AS_HELP_STRING([--enable-vtable-verify],
2770                 [Enable vtable verification feature])],
2771 [case "$enableval" in
2772  yes) enable_vtable_verify=yes ;;
2773  no)  enable_vtable_verify=no ;;
2774  *)   enable_vtable_verify=no;;
2775  esac],
2776 [enable_vtable_verify=no])
2777 AC_MSG_RESULT($enable_vtable_verify)
2778
2779 # Record target_configdirs and the configure arguments for target and
2780 # build configuration in Makefile.
2781 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2782 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2783 bootstrap_fixincludes=no
2784
2785 # If we are building libgomp, bootstrap it.
2786 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2787   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2788 fi
2789
2790 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2791 # or bootstrap-ubsan, bootstrap it.
2792 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2793   case "$BUILD_CONFIG" in
2794     *bootstrap-asan* | *bootstrap-ubsan* )
2795       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2796       bootstrap_fixincludes=yes
2797       ;;
2798   esac
2799 fi
2800
2801 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2802 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2803    test "$enable_vtable_verify" != no; then
2804   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2805 fi
2806
2807 # Determine whether gdb needs tk/tcl or not.
2808 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2809 # and in that case we want gdb to be built without tk.  Ugh!
2810 # In fact I believe gdb is the *only* package directly dependent on tk,
2811 # so we should be able to put the 'maybe's in unconditionally and
2812 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2813 # 100% sure that that's safe though.
2814
2815 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2816 case "$enable_gdbtk" in
2817   no)
2818     GDB_TK="" ;;
2819   yes)
2820     GDB_TK="${gdb_tk}" ;;
2821   *)
2822     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2823     # distro.  Eventually someone will fix this and move Insight, nee
2824     # gdbtk to a separate directory.
2825     if test -d ${srcdir}/gdb/gdbtk ; then
2826       GDB_TK="${gdb_tk}"
2827     else
2828       GDB_TK=""
2829     fi
2830     ;;
2831 esac
2832 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2833 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2834
2835 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2836 # else does, only include them if one of these is built.  The Makefile
2837 # provides the ordering, so it's enough here to add to the list.
2838 case " ${configdirs} " in
2839   *\ gdb\ *)
2840     configdirs="${configdirs} gnulib gdbsupport"
2841     ;;
2842   *\ gdbserver\ *)
2843     configdirs="${configdirs} gnulib gdbsupport"
2844     ;;
2845 esac
2846
2847 # Strip out unwanted targets.
2848
2849 # While at that, we remove Makefiles if we were started for recursive
2850 # configuration, so that the top-level Makefile reconfigures them,
2851 # like we used to do when configure itself was recursive.
2852
2853 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2854 # but now we're fixing up the Makefile ourselves with the additional
2855 # commands passed to AC_CONFIG_FILES.  Use separate variables
2856 # extrasub-{build,host,target} not because there is any reason to split
2857 # the substitutions up that way, but only to remain below the limit of
2858 # 99 commands in a script, for HP-UX sed.
2859
2860 # Do not nest @if/@endif or @unless/@endunless pairs, because
2861 # configure will not warn you at all.
2862
2863 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2864   yes:yes:*\ gold\ *:*,c++,*) ;;
2865   yes:yes:*\ gold\ *:*)
2866     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2867     ;;
2868 esac
2869
2870 extrasub_build=
2871 for module in ${build_configdirs} ; do
2872   if test -z "${no_recursion}" \
2873      && test -f ${build_subdir}/${module}/Makefile; then
2874     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2875     rm -f ${build_subdir}/${module}/Makefile
2876   fi
2877   extrasub_build="$extrasub_build
2878 /^@if build-$module\$/d
2879 /^@endif build-$module\$/d
2880 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2881 /^@if build-$module-$bootstrap_suffix\$/d
2882 /^@endif build-$module-$bootstrap_suffix\$/d
2883 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2884 done
2885 extrasub_host=
2886 for module in ${configdirs} ; do
2887   if test -z "${no_recursion}"; then
2888     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2889       if test -f ${file}; then
2890         echo 1>&2 "*** removing ${file} to force reconfigure"
2891         rm -f ${file}
2892       fi
2893     done
2894   fi
2895   case ${module},${bootstrap_fixincludes} in
2896     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2897     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2898   esac
2899   extrasub_host="$extrasub_host
2900 /^@if $module\$/d
2901 /^@endif $module\$/d
2902 /^@unless $module\$/,/^@endunless $module\$/d
2903 /^@if $module-$host_bootstrap_suffix\$/d
2904 /^@endif $module-$host_bootstrap_suffix\$/d
2905 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2906 done
2907 extrasub_target=
2908 for module in ${target_configdirs} ; do
2909   if test -z "${no_recursion}" \
2910      && test -f ${target_subdir}/${module}/Makefile; then
2911     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2912     rm -f ${target_subdir}/${module}/Makefile
2913   fi
2914
2915   # We only bootstrap target libraries listed in bootstrap_target_libs.
2916   case $bootstrap_target_libs in
2917     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2918     *) target_bootstrap_suffix=no-bootstrap ;;
2919   esac
2920
2921   extrasub_target="$extrasub_target
2922 /^@if target-$module\$/d
2923 /^@endif target-$module\$/d
2924 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2925 /^@if target-$module-$target_bootstrap_suffix\$/d
2926 /^@endif target-$module-$target_bootstrap_suffix\$/d
2927 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2928 done
2929
2930 # Do the final fixup along with target modules.
2931 extrasub_target="$extrasub_target
2932 /^@if /,/^@endif /d
2933 /^@unless /d
2934 /^@endunless /d"
2935
2936 # Create the serialization dependencies.  This uses a temporary file.
2937
2938 AC_ARG_ENABLE([serial-configure],
2939 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2940                 [force sequential configuration of
2941                  sub-packages for the host, target or build
2942                  machine, or all sub-packages])])
2943
2944 case ${enable_serial_configure} in
2945   yes)
2946     enable_serial_build_configure=yes
2947     enable_serial_host_configure=yes
2948     enable_serial_target_configure=yes
2949     ;;
2950 esac
2951
2952 # These force 'configure's to be done one at a time, to avoid problems
2953 # with contention over a shared config.cache.
2954 rm -f serdep.tmp
2955 echo '# serdep.tmp' > serdep.tmp
2956 olditem=
2957 test "x${enable_serial_build_configure}" = xyes &&
2958 for item in ${build_configdirs} ; do
2959   case ${olditem} in
2960     "") ;;
2961     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2962   esac
2963   olditem=${item}
2964 done
2965 olditem=
2966 test "x${enable_serial_host_configure}" = xyes &&
2967 for item in ${configdirs} ; do
2968   case ${olditem} in
2969     "") ;;
2970     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2971   esac
2972   olditem=${item}
2973 done
2974 olditem=
2975 test "x${enable_serial_target_configure}" = xyes &&
2976 for item in ${target_configdirs} ; do
2977   case ${olditem} in
2978     "") ;;
2979     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2980   esac
2981   olditem=${item}
2982 done
2983 serialization_dependencies=serdep.tmp
2984 AC_SUBST_FILE(serialization_dependencies)
2985
2986 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2987 # target, nonopt, and variable assignments.  These are the ones we
2988 # might not want to pass down to subconfigures.  The exception being
2989 # --cache-file=/dev/null, which is used to turn off the use of cache
2990 # files altogether, and which should be passed on to subconfigures.
2991 # Also strip program-prefix, program-suffix, and program-transform-name,
2992 # so that we can pass down a consistent program-transform-name.
2993 baseargs=
2994 tbaseargs=
2995 keep_next=no
2996 skip_next=no
2997 eval "set -- $ac_configure_args"
2998 for ac_arg
2999 do
3000   if test X"$skip_next" = X"yes"; then
3001     skip_next=no
3002     continue
3003   fi
3004   if test X"$keep_next" = X"yes"; then
3005     case $ac_arg in
3006       *\'*)
3007         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3008     esac
3009     baseargs="$baseargs '$ac_arg'"
3010     tbaseargs="$tbaseargs '$ac_arg'"
3011     keep_next=no
3012     continue
3013   fi
3014
3015   # Handle separated arguments.  Based on the logic generated by
3016   # autoconf 2.59.
3017   case $ac_arg in
3018     *=* | --config-cache | -C | -disable-* | --disable-* \
3019       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3020       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3021       | -with-* | --with-* | -without-* | --without-* | --x)
3022       separate_arg=no
3023       ;;
3024     -*)
3025       separate_arg=yes
3026       ;;
3027     *)
3028       separate_arg=no
3029       ;;
3030   esac
3031
3032   skip_targ=no
3033   case $ac_arg in
3034 changequote(,)
3035   --with-* | --without-*)
3036     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3037
3038     case $libopt in
3039     *[-_]include)
3040       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3041       ;;
3042     *[-_]lib)
3043       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3044       ;;
3045     *)
3046       lib=$libopt
3047       ;;
3048     esac
3049 changequote([,])
3050
3051     case $lib in
3052     mpc | mpfr | gmp | isl)
3053       # If we're processing --with-$lib, --with-$lib-include or
3054       # --with-$lib-lib, for one of the libs above, and target is
3055       # different from host, don't pass the current argument to any
3056       # target library's configure.
3057       if test x$is_cross_compiler = xyes; then
3058         skip_targ=yes
3059       fi
3060       ;;
3061     esac
3062     ;;
3063   esac
3064
3065   case "$ac_arg" in
3066     --cache-file=/dev/null | \
3067     -cache-file=/dev/null )
3068       # Handled here to avoid the test to skip args below.
3069       baseargs="$baseargs '$ac_arg'"
3070       tbaseargs="$tbaseargs '$ac_arg'"
3071       # Assert: $separate_arg should always be no.
3072       keep_next=$separate_arg
3073       ;;
3074     --no*)
3075       continue
3076       ;;
3077     --c* | \
3078     --sr* | \
3079     --ho* | \
3080     --bu* | \
3081     --t* | \
3082     --program-* | \
3083     -cache_file* | \
3084     -srcdir* | \
3085     -host* | \
3086     -build* | \
3087     -target* | \
3088     -program-prefix* | \
3089     -program-suffix* | \
3090     -program-transform-name* )
3091       skip_next=$separate_arg
3092       continue
3093       ;;
3094     -*)
3095       # An option.  Add it.
3096       case $ac_arg in
3097         *\'*)
3098           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3099       esac
3100       baseargs="$baseargs '$ac_arg'"
3101       if test X"$skip_targ" = Xno; then
3102         tbaseargs="$tbaseargs '$ac_arg'"
3103       fi
3104       keep_next=$separate_arg
3105       ;;
3106     *)
3107       # Either a variable assignment, or a nonopt (triplet).  Don't
3108       # pass it down; let the Makefile handle this.
3109       continue
3110       ;;
3111   esac
3112 done
3113 # Remove the initial space we just introduced and, as these will be
3114 # expanded by make, quote '$'.
3115 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3116
3117 # Add in --program-transform-name, after --program-prefix and
3118 # --program-suffix have been applied to it.  Autoconf has already
3119 # doubled dollar signs and backslashes in program_transform_name; we want
3120 # the backslashes un-doubled, and then the entire thing wrapped in single
3121 # quotes, because this will be expanded first by make and then by the shell.
3122 # Also, because we want to override the logic in subdir configure scripts to
3123 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3124 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3125 ${program_transform_name}
3126 EOF_SED
3127 gcc_transform_name=`cat conftestsed.out`
3128 rm -f conftestsed.out
3129 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3130 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3131 if test "$silent" = yes; then
3132   baseargs="$baseargs --silent"
3133   tbaseargs="$tbaseargs --silent"
3134 fi
3135 baseargs="$baseargs --disable-option-checking"
3136 tbaseargs="$tbaseargs --disable-option-checking"
3137
3138 # Record and document user additions to sub configure arguments.
3139 AC_ARG_VAR([build_configargs],
3140            [additional configure arguments for build directories])
3141 AC_ARG_VAR([host_configargs],
3142            [additional configure arguments for host directories])
3143 AC_ARG_VAR([target_configargs],
3144            [additional configure arguments for target directories])
3145
3146 # For the build-side libraries, we just need to pretend we're native,
3147 # and not use the same cache file.  Multilibs are neither needed nor
3148 # desired.  We can't even use the same cache file for all build-side
3149 # libraries, as they're compiled differently; some with C, some with
3150 # C++ or with different feature-enabling options.
3151 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3152
3153 # For host modules, accept cache file option, or specification as blank.
3154 case "${cache_file}" in
3155 "") # empty
3156   cache_file_option="" ;;
3157 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3158   cache_file_option="--cache-file=${cache_file}" ;;
3159 *) # relative path
3160   cache_file_option="--cache-file=../${cache_file}" ;;
3161 esac
3162
3163 # Host dirs don't like to share a cache file either, horribly enough.
3164 # This seems to be due to autoconf 2.5x stupidity.
3165 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3166
3167 target_configargs="$target_configargs ${tbaseargs}"
3168
3169 # Passing a --with-cross-host argument lets the target libraries know
3170 # whether they are being built with a cross-compiler or being built
3171 # native.  However, it would be better to use other mechanisms to make the
3172 # sorts of decisions they want to make on this basis.  Please consider
3173 # this option to be deprecated.  FIXME.
3174 if test x${is_cross_compiler} = xyes ; then
3175   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3176 fi
3177
3178 # Special user-friendly check for native x86_64-linux build, if
3179 # multilib is not explicitly enabled.
3180 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3181   x86_64-*linux*:yes:$build:$build:)
3182     # Make sure we have a development environment that handles 32-bit
3183     dev64=no
3184     echo "int main () { return 0; }" > conftest.c
3185     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3186     if test $? = 0 ; then
3187       if test -s conftest || test -s conftest.exe ; then
3188         dev64=yes
3189       fi
3190     fi
3191     rm -f conftest*
3192     if test x${dev64} != xyes ; then
3193       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3194     fi
3195     ;;
3196 esac
3197
3198 # Default to --enable-multilib.
3199 if test x${enable_multilib} = x ; then
3200   target_configargs="--enable-multilib ${target_configargs}"
3201 fi
3202
3203 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3204 # changed from the earlier setting of with_newlib.
3205 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3206   target_configargs="--with-newlib ${target_configargs}"
3207 fi
3208
3209 # Different target subdirs use different values of certain variables
3210 # (notably CXX).  Worse, multilibs use *lots* of different values.
3211 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3212 # it doesn't automatically accept command-line overrides of them.
3213 # This means it's not safe for target subdirs to share a cache file,
3214 # which is disgusting, but there you have it.  Hopefully this can be
3215 # fixed in future.  It's still worthwhile to use a cache file for each
3216 # directory.  I think.
3217
3218 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3219 # We need to pass --target, as newer autoconf's requires consistency
3220 # for target_alias and gcc doesn't manage it consistently.
3221 target_configargs="--cache-file=./config.cache ${target_configargs}"
3222
3223 FLAGS_FOR_TARGET=
3224 case " $target_configdirs " in
3225  *" newlib "*)
3226   case " $target_configargs " in
3227   *" --with-newlib "*)
3228    case "$target" in
3229     *-cygwin*)
3230       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3231       ;;
3232    esac
3233
3234    # If we're not building GCC, don't discard standard headers.
3235    if test -d ${srcdir}/gcc; then
3236      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3237
3238      if test "${build}" != "${host}"; then
3239        # On Canadian crosses, CC_FOR_TARGET will have already been set
3240        # by `configure', so we won't have an opportunity to add -Bgcc/
3241        # to it.  This is right: we don't want to search that directory
3242        # for binaries, but we want the header files in there, so add
3243        # them explicitly.
3244        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3245
3246        # Someone might think of using the pre-installed headers on
3247        # Canadian crosses, in case the installed compiler is not fully
3248        # compatible with the compiler being built.  In this case, it
3249        # would be better to flag an error than risking having
3250        # incompatible object files being constructed.  We can't
3251        # guarantee that an error will be flagged, but let's hope the
3252        # compiler will do it, when presented with incompatible header
3253        # files.
3254      fi
3255    fi
3256
3257    case "${target}-${is_cross_compiler}" in
3258    i[[3456789]]86-*-linux*-no)
3259       # Here host == target, so we don't need to build gcc,
3260       # so we don't want to discard standard headers.
3261       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3262       ;;
3263    *)
3264       # If we're building newlib, use its generic headers last, but search
3265       # for any libc-related directories first (so make it the last -B
3266       # switch).
3267       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3268
3269       # If we're building libgloss, find the startup file, simulator library
3270       # and linker script.
3271       case " $target_configdirs " in
3272         *" libgloss "*)
3273         # Look for startup file, simulator library and maybe linker script.
3274         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3275         # Look for libnosys.a in case the target needs it.
3276         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3277         # Most targets have the linker script in the source directory.
3278         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3279         ;;
3280       esac
3281       ;;
3282    esac
3283    ;;
3284   esac
3285   ;;
3286 esac
3287
3288 case "$target" in
3289   x86_64-*mingw* | *-w64-mingw*)
3290   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3291   # however, use a symlink named 'mingw' in ${prefix} .
3292     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3293     ;;
3294   *-mingw*)
3295   # MinGW can't be handled as Cygwin above since it does not use newlib.
3296     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3297     ;;
3298 esac
3299
3300 # Allow the user to override the flags for
3301 # our build compiler if desired.
3302 if test x"${build}" = x"${host}" ; then
3303   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3304   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3305   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3306 fi
3307
3308 # On Canadian crosses, we'll be searching the right directories for
3309 # the previously-installed cross compiler, so don't bother to add
3310 # flags for directories within the install tree of the compiler
3311 # being built; programs in there won't even run.
3312 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3313   # Search for pre-installed headers if nothing else fits.
3314   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3315 fi
3316
3317 if test "x${use_gnu_ld}" = x &&
3318    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3319   # Arrange for us to find uninstalled linker scripts.
3320   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3321 fi
3322
3323 # Search for other target-specific linker scripts and such.
3324 case "${target}" in
3325   mep*)
3326     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3327     ;;
3328 esac
3329
3330 # Makefile fragments.
3331 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3332 do
3333   eval fragval=\$$frag
3334   if test $fragval != /dev/null; then
3335     eval $frag=${srcdir}/$fragval
3336   fi
3337 done
3338 AC_SUBST_FILE(host_makefile_frag)
3339 AC_SUBST_FILE(target_makefile_frag)
3340 AC_SUBST_FILE(alphaieee_frag)
3341 AC_SUBST_FILE(ospace_frag)
3342
3343 # Miscellanea: directories, flags, etc.
3344 AC_SUBST(RPATH_ENVVAR)
3345 AC_SUBST(GCC_SHLIB_SUBDIR)
3346 AC_SUBST(tooldir)
3347 AC_SUBST(build_tooldir)
3348 AC_SUBST(CONFIGURE_GDB_TK)
3349 AC_SUBST(GDB_TK)
3350 AC_SUBST(INSTALL_GDB_TK)
3351
3352 # Build module lists & subconfigure args.
3353 AC_SUBST(build_configargs)
3354 AC_SUBST(build_configdirs)
3355
3356 # Host module lists & subconfigure args.
3357 AC_SUBST(host_configargs)
3358 AC_SUBST(configdirs)
3359 AC_SUBST(target_configdirs)
3360
3361 # Target module lists & subconfigure args.
3362 AC_SUBST(target_configargs)
3363
3364
3365 # Build tools.
3366 AC_SUBST(AR_FOR_BUILD)
3367 AC_SUBST(AS_FOR_BUILD)
3368 AC_SUBST(CC_FOR_BUILD)
3369 AC_SUBST(CFLAGS_FOR_BUILD)
3370 AC_SUBST(CXXFLAGS_FOR_BUILD)
3371 AC_SUBST(CXX_FOR_BUILD)
3372 AC_SUBST(DLLTOOL_FOR_BUILD)
3373 AC_SUBST(GFORTRAN_FOR_BUILD)
3374 AC_SUBST(GOC_FOR_BUILD)
3375 AC_SUBST(GDC_FOR_BUILD)
3376 AC_SUBST(LDFLAGS_FOR_BUILD)
3377 AC_SUBST(LD_FOR_BUILD)
3378 AC_SUBST(NM_FOR_BUILD)
3379 AC_SUBST(RANLIB_FOR_BUILD)
3380 AC_SUBST(WINDMC_FOR_BUILD)
3381 AC_SUBST(WINDRES_FOR_BUILD)
3382
3383 # Generate default definitions for YACC, M4, LEX and other programs that run
3384 # on the build machine.  These are used if the Makefile can't locate these
3385 # programs in objdir.
3386 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3387
3388 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3389 case " $build_configdirs " in
3390   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3391 esac
3392
3393 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3394 case " $build_configdirs " in
3395   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3396 esac
3397
3398 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3399 case " $build_configdirs " in
3400   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3401 esac
3402
3403 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3404 case " $build_configdirs " in
3405   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3406   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3407 esac
3408
3409 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3410 case " $build_configdirs " in
3411   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3412 esac
3413
3414 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3415 case " $build_configdirs " in
3416   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3417   *)
3418 changequote(,)
3419     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3420     # higher, else we use the "missing" dummy.
3421     if ${MAKEINFO} --version \
3422        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3423       :
3424     else
3425       MAKEINFO="$MISSING makeinfo"
3426     fi
3427     ;;
3428 changequote([,])
3429 esac
3430
3431 # FIXME: expect and dejagnu may become build tools?
3432
3433 AC_CHECK_PROGS(EXPECT, expect, expect)
3434 case " $configdirs " in
3435   *" expect "*)
3436     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3437     ;;
3438 esac
3439
3440 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3441 case " $configdirs " in
3442   *" dejagnu "*)
3443     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3444     ;;
3445 esac
3446
3447
3448 # Host tools.
3449 NCN_STRICT_CHECK_TOOLS(AR, ar)
3450 NCN_STRICT_CHECK_TOOLS(AS, as)
3451 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3452 NCN_STRICT_CHECK_TOOLS(LD, ld)
3453 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3454 NCN_STRICT_CHECK_TOOLS(NM, nm)
3455 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3456 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3457 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3458 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3459 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3460 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3461 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3462 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3463 AC_SUBST(CC)
3464 AC_SUBST(CXX)
3465 AC_SUBST(CFLAGS)
3466 AC_SUBST(CXXFLAGS)
3467
3468 # Target tools.
3469 AC_ARG_WITH([build-time-tools],
3470   [AS_HELP_STRING([--with-build-time-tools=PATH],
3471                   [use given path to find target tools during the build])],
3472   [case x"$withval" in
3473      x/*) ;;
3474      *)
3475        with_build_time_tools=
3476        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3477        ;;
3478    esac],
3479   [with_build_time_tools=])
3480
3481 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3482 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3483 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3484 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3485 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3486 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3487
3488 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3489 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3490 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3491 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3492 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3493 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3494 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3495 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3496 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3497 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3498 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3499 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3500 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3501 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3502
3503 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3504
3505 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3506 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3507 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3508 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3509 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3510                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3511                 c++)
3512 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3513                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3514                 c++)
3515 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3516 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3517 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3518                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3519 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3520                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3521 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3522                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3523 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3524 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3525 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3526 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3527 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3528 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3529 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3530 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3531 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3532 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3533 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3534
3535 AC_SUBST(FLAGS_FOR_TARGET)
3536 AC_SUBST(RAW_CXX_FOR_TARGET)
3537
3538 # Certain tools may need extra flags.
3539 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3540 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3541 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3542
3543 # When building target libraries, except in a Canadian cross, we use
3544 # the same toolchain as the compiler we just built.
3545 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3546 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3547 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3548 if test $host = $build; then
3549   case " $configdirs " in
3550     *" gcc "*)
3551       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3552       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3553       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3554       ;;
3555   esac
3556 fi
3557
3558 AC_SUBST(COMPILER_AS_FOR_TARGET)
3559 AC_SUBST(COMPILER_LD_FOR_TARGET)
3560 AC_SUBST(COMPILER_NM_FOR_TARGET)
3561
3562 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3563 AC_ARG_ENABLE(maintainer-mode,
3564 [AS_HELP_STRING([--enable-maintainer-mode],
3565                 [enable make rules and dependencies not useful
3566                  (and sometimes confusing) to the casual installer])],
3567       USE_MAINTAINER_MODE=$enableval,
3568       USE_MAINTAINER_MODE=no)
3569 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3570 AC_SUBST(MAINTAINER_MODE_TRUE)
3571 AC_SUBST(MAINTAINER_MODE_FALSE)
3572 if test "$USE_MAINTAINER_MODE" = yes; then
3573   MAINTAINER_MODE_TRUE=
3574   MAINTAINER_MODE_FALSE='#'
3575 else
3576   MAINTAINER_MODE_TRUE='#'
3577   MAINTAINER_MODE_FALSE=
3578 fi
3579 MAINT=$MAINTAINER_MODE_TRUE
3580 AC_SUBST(MAINT)dnl
3581
3582 # ---------------------
3583 # GCC bootstrap support
3584 # ---------------------
3585
3586 # Stage specific cflags for build.
3587 stage1_cflags="-g"
3588 case $build in
3589   vax-*-*)
3590     case ${GCC} in
3591       yes) stage1_cflags="-g -Wa,-J" ;;
3592       *) stage1_cflags="-g -J" ;;
3593     esac ;;
3594 esac
3595
3596 AC_SUBST(stage1_cflags)
3597
3598 # Enable --enable-checking in stage1 of the compiler.
3599 AC_ARG_ENABLE(stage1-checking,
3600 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3601                 [choose additional checking for stage1 of the compiler])],
3602 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3603 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3604   # For --disable-checking or implicit --enable-checking=release, avoid
3605   # setting --enable-checking=gc in the default stage1 checking for LTO
3606   # bootstraps.  See PR62077.
3607   case $BUILD_CONFIG in
3608     *lto*)
3609       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3610     *)
3611       stage1_checking=--enable-checking=yes,types;;
3612   esac
3613   if test "x$enable_checking" = x && \
3614      test -d ${srcdir}/gcc && \
3615      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3616     stage1_checking=--enable-checking=yes,types,extra
3617   fi
3618 else
3619   stage1_checking=--enable-checking=$enable_checking,types
3620 fi])
3621 AC_SUBST(stage1_checking)
3622
3623 # Enable -Werror in bootstrap stage2 and later.
3624 AC_ARG_ENABLE(werror,
3625 [AS_HELP_STRING([--enable-werror],
3626                 [enable -Werror in bootstrap stage2 and later])],
3627 [
3628 case ${enable_werror} in
3629   yes) stage2_werror_flag="--enable-werror-always" ;;
3630   *) stage2_werror_flag="" ;;
3631 esac
3632 ],
3633 [
3634 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3635   case $BUILD_CONFIG in
3636   bootstrap-debug)
3637       stage2_werror_flag="--enable-werror-always" ;;
3638   "")
3639       stage2_werror_flag="--enable-werror-always" ;;
3640   esac
3641 fi
3642 ])
3643
3644 AC_SUBST(stage2_werror_flag)
3645
3646 # Specify what files to not compare during bootstrap.
3647
3648 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3649 case "$target" in
3650   hppa*64*-*-hpux*) ;;
3651   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3652   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3653 esac
3654 AC_SUBST(compare_exclusions)
3655
3656 AC_CONFIG_FILES([Makefile],
3657   [sed "$extrasub_build" Makefile |
3658    sed "$extrasub_host" |
3659    sed "$extrasub_target" > mf$$
3660    mv -f mf$$ Makefile],
3661   [extrasub_build="$extrasub_build"
3662    extrasub_host="$extrasub_host"
3663    extrasub_target="$extrasub_target"])
3664 AC_OUTPUT