opcodes/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2023 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([opcodes], BFD_VERSION)
  22 AC_CONFIG_SRCDIR([z8k-dis.c])
  23
  24 AC_CANONICAL_TARGET
  25
  26 AM_INIT_AUTOMAKE
  27 AM_SILENT_RULES([yes])
  28
  29 AC_PROG_CC
  30 AC_GNU_SOURCE
  31 AC_USE_SYSTEM_EXTENSIONS
  32
  33 dnl These must be called before LT_INIT, because it may want
  34 dnl to call AC_CHECK_PROG.
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_CHECK_TOOL(RANLIB, ranlib, :)
  37
  38 dnl Default to a non shared library.  This may be overridden by the
  39 dnl configure option --enable-shared.
  40 AC_DISABLE_SHARED
  41
  42 LT_INIT
  43
  44 ac_checking=
  45 . ${srcdir}/../bfd/development.sh
  46 test "$development" = true && ac_checking=yes
  47 AC_ARG_ENABLE(checking,
  48 [  --enable-checking       enable run-time checks],
  49 [case "${enableval}" in
  50   no|none)  ac_checking= ;;
  51   *)        ac_checking=yes ;;
  52 esac])dnl
  53 if test x$ac_checking != x ; then
  54   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  55 fi
  56
  57 AC_ARG_ENABLE(targets,
  58 [  --enable-targets        alternative target configurations],
  59 [case "${enableval}" in
  60   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  61             ;;
  62   no)       enable_targets= ;;
  63   *)        enable_targets=$enableval ;;
  64 esac])dnl
  65
  66 AM_BINUTILS_WARNINGS
  67
  68 AC_CONFIG_HEADERS(config.h:config.in)
  69
  70 # PR 14072
  71 AH_VERBATIM([00_CONFIG_H_CHECK],
  72 [/* Check that config.h is #included before system headers
  73    (this works only for glibc, but that should be enough).  */
  74 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  75 #  error config.h must be #included before system headers
  76 #endif
  77 #define __CONFIG_H__ 1])
  78
  79 if test -z "$target" ; then
  80     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  81 fi
  82
  83 AM_MAINTAINER_MODE
  84 AM_INSTALL_LIBBFD
  85 AC_EXEEXT
  86
  87 # host-specific stuff:
  88
  89 ALL_LINGUAS="da de es fi fr ga id it nl pt_BR ro sr sv tr uk vi zh_CN"
  90 ZW_GNU_GETTEXT_SISTER_DIR
  91 AM_PO_SUBDIRS
  92
  93 . ${srcdir}/../bfd/configure.host
  94
  95 BFD_CC_FOR_BUILD
  96 BFD_64_BIT
  97
  98 AC_SUBST(HDEFINES)
  99 AC_PROG_INSTALL
 100
 101 AC_CHECK_DECLS([basename, stpcpy])
 102
 103 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 104 # since sigsetjmp might only be defined as a macro.
 105 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 106 [AC_TRY_COMPILE([
 107 #include <setjmp.h>
 108 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 109 bfd_cv_func_sigsetjmp=yes, bfd_cv_func_sigsetjmp=no)])
 110 if test $bfd_cv_func_sigsetjmp = yes; then
 111   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 112 fi
 113
 114 cgen_maint=no
 115 cgendir='$(srcdir)/../../cgen'
 116 if test -r ${srcdir}/../cgen/iformat.scm; then
 117     cgendir='$(srcdir)/../cgen'
 118 fi
 119
 120 AC_ARG_ENABLE(cgen-maint,
 121 [  --enable-cgen-maint[=dir]    build cgen generated files],
 122 [case "${enableval}" in
 123   yes)  cgen_maint=yes ;;
 124   no)   cgen_maint=no ;;
 125   *)
 126         # Argument is a directory where cgen can be found.  In some
 127         # future world cgen could be installable, but right now this
 128         # is not the case.  Instead we assume the directory is a path
 129         # to the cgen source tree.
 130         cgen_maint=yes
 131         if test -r ${enableval}/iformat.scm; then
 132           # This looks like a cgen source tree.
 133           cgendir=${enableval}
 134         else
 135           AC_MSG_ERROR(${enableval} doesn't look like a cgen source tree)
 136         fi
 137         ;;
 138 esac])dnl
 139 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 140 AC_SUBST(cgendir)
 141
 142 using_cgen=no
 143
 144 # Check if linker supports --as-needed and --no-as-needed options
 145 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 146         [bfd_cv_ld_as_needed=no
 147         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 148                 bfd_cv_ld_as_needed=yes
 149         fi
 150         ])
 151
 152 LT_LIB_M
 153
 154 #Libs for generator progs
 155 if test "x$cross_compiling" = "xno"; then
 156   BUILD_LIBS=../libiberty/libiberty.a
 157   BUILD_LIB_DEPS=$BUILD_LIBS
 158 else
 159   # if cross-compiling, assume that the system provides -liberty
 160   # and that the version is compatible with new headers.
 161   BUILD_LIBS=-liberty
 162   BUILD_LIB_DEPS=
 163 fi
 164 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 165 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 166
 167 AC_SUBST(BUILD_LIBS)
 168 AC_SUBST(BUILD_LIB_DEPS)
 169
 170 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 171 SHARED_LDFLAGS=
 172 SHARED_LIBADD=
 173 SHARED_DEPENDENCIES=
 174 if test "$enable_shared" = "yes"; then
 175 # When building a shared libopcodes, link against the pic version of libiberty
 176 # so that apps that use libopcodes won't need libiberty just to satisfy any
 177 # libopcodes references.
 178 # We can't do that if a pic libiberty is unavailable since including non-pic
 179 # code would insert text relocations into libopcodes.
 180 # Note that linking against libbfd as we do here, which is itself linked
 181 # against libiberty, may not satisfy all the libopcodes libiberty references
 182 # since libbfd may not pull in the entirety of libiberty.
 183 # Also, jam libintl into the right place in all of this: after libiberty,
 184 # which uses it, but before -lcygwin, which it uses.
 185 changequote(,)dnl
 186   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 187 changequote([,])dnl
 188   if test -n "$x"; then
 189     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 190   fi
 191 fi
 192
 193 SHARED_LIBADD="$SHARED_LIBADD $LIBINTL"
 194
 195 if test "$enable_shared" = "yes"; then
 196   case "${host}" in
 197     *-*-cygwin*)
 198       SHARED_LDFLAGS="-no-undefined"
 199       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty $SHARED_LIBADD"
 200       ;;
 201     *)
 202       SHARED_LIBADD="../bfd/libbfd.la ${SHARED_LIBADD}"
 203       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 204       ;;
 205   esac
 206
 207   if test -n "$SHARED_LIBADD"; then
 208     if test -n "$LIBM"; then
 209       if test x"$bfd_cv_ld_as_needed" = xyes; then
 210         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 211         # to stop libtool reordering these options.
 212         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 213       else
 214         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 215       fi
 216     fi
 217   fi
 218 fi
 219 AC_SUBST(SHARED_LDFLAGS)
 220 AC_SUBST(SHARED_LIBADD)
 221 AC_SUBST(SHARED_DEPENDENCIES)
 222
 223 # target-specific stuff:
 224
 225 # Canonicalize the secondary target names.
 226 if test -n "$enable_targets" ; then
 227     for targ in `echo $enable_targets | sed 's/,/ /g'`
 228     do
 229         result=`$ac_config_sub $targ 2>/dev/null`
 230         if test -n "$result" ; then
 231             canon_targets="$canon_targets $result"
 232         else
 233             # Allow targets that config.sub doesn't recognize, like "all".
 234             canon_targets="$canon_targets $targ"
 235         fi
 236     done
 237 fi
 238
 239 all_targets=false
 240 selarchs=
 241 for targ in $target $canon_targets
 242 do
 243     if test "x$targ" = "xall" ; then
 244         all_targets=true
 245     else
 246         . $srcdir/../bfd/config.bfd
 247         selarchs="$selarchs $targ_archs"
 248     fi
 249 done
 250
 251 # Utility var, documents generic cgen support files.
 252
 253 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 254
 255 # We don't do any links based on the target system, just makefile config.
 256
 257 if test x${all_targets} = xfalse ; then
 258
 259     # Target architecture .o files.
 260     ta=
 261
 262     for arch in $selarchs
 263     do
 264         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 265         archdefs="$archdefs -DARCH_$ad"
 266         case "$arch" in
 267         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 268         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 269         bfd_amdgcn_arch)        ;;
 270         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 271         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 272         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 273         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 274         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 275         bfd_cris_arch)          ta="$ta cris-desc.lo cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 276         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 277         bfd_csky_arch)          ta="$ta csky-dis.lo" ;;
 278         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 279         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 280         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 281         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 282         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 283         bfd_ft32_arch)          ta="$ta ft32-opc.lo ft32-dis.lo" ;;
 284         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 285         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 286         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 287         bfd_i386_arch|bfd_iamcu_arch)
 288                                 ta="$ta i386-dis.lo" ;;
 289         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 290         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 291         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 292         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 293         bfd_kvx_arch)           ta="$ta kvx-opc.lo kvx-dis.lo" ;;
 294         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 295         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 296         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 297         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 298         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 299         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 300         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 301         bfd_s12z_arch)          ta="$ta s12z-dis.lo s12z-opc.lo" ;;
 302         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 303         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 304         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 305         bfd_metag_arch)         ta="$ta metag-dis.lo" ;;
 306         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 307         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 308         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 309         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 310         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 311         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 312         bfd_msp430_arch)        ta="$ta msp430-dis.lo msp430-decode.lo" ;;
 313         bfd_nds32_arch)         ta="$ta nds32-asm.lo nds32-dis.lo" ;;
 314         bfd_nfp_arch)           ta="$ta nfp-dis.lo" ;;
 315         bfd_nios2_arch)         ta="$ta nios2-dis.lo nios2-opc.lo" ;;
 316         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 317         bfd_or1k_arch)          ta="$ta or1k-asm.lo or1k-desc.lo or1k-dis.lo or1k-ibld.lo or1k-opc.lo" using_cgen=yes ;;
 318         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 319         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 320         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 321         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 322         bfd_pru_arch)           ta="$ta pru-dis.lo pru-opc.lo" ;;
 323         bfd_pyramid_arch)       ;;
 324         bfd_romp_arch)          ;;
 325         bfd_riscv_arch)         ta="$ta riscv-dis.lo riscv-opc.lo" ;;
 326         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 327         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 328         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 329         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 330         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 331         bfd_sh_arch)            ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 332         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 333         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 334         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 335         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 336         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 337         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 338         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 339         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 340         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 341         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 342         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 343         bfd_v850_rh850_arch)    ta="$ta v850-opc.lo v850-dis.lo" ;;
 344         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 345         bfd_visium_arch)        ta="$ta visium-dis.lo visium-opc.lo" ;;
 346         bfd_wasm32_arch)        ta="$ta wasm32-dis.lo" ;;
 347         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 348         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 349         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 350         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 351         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 352         bfd_bpf_arch)           ta="$ta bpf-dis.lo bpf-opc.lo" ;;
 353         bfd_loongarch_arch)     ta="$ta loongarch-dis.lo loongarch-opc.lo loongarch-coder.lo" ;;
 354
 355         "")                     ;;
 356         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 357         esac
 358     done
 359
 360     if test $using_cgen = yes ; then
 361         ta="$ta $cgen_files"
 362     fi
 363
 364     # Weed out duplicate .o files.
 365     f=""
 366     for i in $ta ; do
 367         case " $f " in
 368         *" $i "*) ;;
 369         *) f="$f $i" ;;
 370         esac
 371     done
 372     ta="$f"
 373
 374     # And duplicate -D flags.
 375     f=""
 376     for i in $archdefs ; do
 377         case " $f " in
 378         *" $i "*) ;;
 379         *) f="$f $i" ;;
 380         esac
 381     done
 382     archdefs="$f"
 383
 384     BFD_MACHINES="$ta"
 385
 386 else    # all_targets is true
 387     archdefs=-DARCH_all
 388     if test "$enable_64_bit_bfd" = "yes" ; then
 389         BFD_MACHINES='$(ALL32_MACHINES) $(ALL64_MACHINES)'
 390     else
 391         BFD_MACHINES='$(ALL32_MACHINES)'
 392     fi
 393 fi
 394
 395 AC_SUBST(archdefs)
 396 AC_SUBST(BFD_MACHINES)
 397
 398 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 399 AC_OUTPUT
 400
 401 GNU_MAKE_JOBSERVER