decode2.vhdl

   1 library ieee;
   2 use ieee.std_logic_1164.all;
   3 use ieee.numeric_std.all;
   4
   5 library work;
   6 use work.decode_types.all;
   7 use work.common.all;
   8 use work.helpers.all;
   9 use work.insn_helpers.all;
  10
  11 entity decode2 is
  12         port (
  13                 clk   : in std_ulogic;
  14                 rst   : in std_ulogic;
  15
  16                 complete_in : in std_ulogic;
  17                 stall_out : out std_ulogic;
  18
  19                 stopped_out : out std_ulogic;
  20
  21                 flush_in: in std_ulogic;
  22
  23                 d_in  : in Decode1ToDecode2Type;
  24
  25                 e_out : out Decode2ToExecute1Type;
  26                 m_out : out Decode2ToMultiplyType;
  27                 d_out : out Decode2ToDividerType;
  28                 l_out : out Decode2ToLoadstore1Type;
  29
  30                 r_in  : in RegisterFileToDecode2Type;
  31                 r_out : out Decode2ToRegisterFileType;
  32
  33                 c_in  : in CrFileToDecode2Type;
  34                 c_out : out Decode2ToCrFileType
  35         );
  36 end entity decode2;
  37
  38 architecture behaviour of decode2 is
  39         type reg_type is record
  40                 e : Decode2ToExecute1Type;
  41                 m : Decode2ToMultiplyType;
  42                 d : Decode2ToDividerType;
  43                 l : Decode2ToLoadstore1Type;
  44         end record;
  45
  46         signal r, rin : reg_type;
  47
  48         type decode_input_reg_t is record
  49                 reg_valid : std_ulogic;
  50                 reg       : std_ulogic_vector(4 downto 0);
  51                 data      : std_ulogic_vector(63 downto 0);
  52         end record;
  53
  54         function decode_input_reg_a (t : input_reg_a_t; insn_in : std_ulogic_vector(31 downto 0);
  55                                      reg_data : std_ulogic_vector(63 downto 0)) return decode_input_reg_t is
  56                 variable is_reg : std_ulogic;
  57         begin
  58                 is_reg := '0' when insn_ra(insn_in) = "00000" else '1';
  59
  60                 if t = RA or (t = RA_OR_ZERO and insn_ra(insn_in) /= "00000") then
  61                         --return (is_reg, insn_ra(insn_in), reg_data);
  62                         return ('1', insn_ra(insn_in), reg_data);
  63                 else
  64                         return ('0', (others => '0'), (others => '0'));
  65                 end if;
  66         end;
  67
  68         function decode_input_reg_b (t : input_reg_b_t; insn_in : std_ulogic_vector(31 downto 0);
  69                                      reg_data : std_ulogic_vector(63 downto 0)) return decode_input_reg_t is
  70         begin
  71                 case t is
  72                 when RB =>
  73                         return ('1', insn_rb(insn_in), reg_data);
  74                 when CONST_UI =>
  75                         return ('0', (others => '0'), std_ulogic_vector(resize(unsigned(insn_ui(insn_in)), 64)));
  76                 when CONST_SI =>
  77                         return ('0', (others => '0'), std_ulogic_vector(resize(signed(insn_si(insn_in)), 64)));
  78                 when CONST_SI_HI =>
  79                         return ('0', (others => '0'), std_ulogic_vector(resize(signed(insn_si(insn_in)) & x"0000", 64)));
  80                 when CONST_UI_HI =>
  81                         return ('0', (others => '0'), std_ulogic_vector(resize(unsigned(insn_si(insn_in)) & x"0000", 64)));
  82                 when CONST_LI =>
  83                         return ('0', (others => '0'), std_ulogic_vector(resize(signed(insn_li(insn_in)) & "00", 64)));
  84                 when CONST_BD =>
  85                         return ('0', (others => '0'), std_ulogic_vector(resize(signed(insn_bd(insn_in)) & "00", 64)));
  86                 when CONST_DS =>
  87                         return ('0', (others => '0'), std_ulogic_vector(resize(signed(insn_ds(insn_in)) & "00", 64)));
  88                 when CONST_M1 =>
  89                         return ('0', (others => '0'), x"FFFFFFFFFFFFFFFF");
  90                 when CONST_SH =>
  91                         return ('0', (others => '0'), x"00000000000000" & "00" & insn_in(1) & insn_in(15 downto 11));
  92                 when CONST_SH32 =>
  93                         return ('0', (others => '0'), x"00000000000000" & "000" & insn_in(15 downto 11));
  94                 when NONE =>
  95                         return ('0', (others => '0'), (others => '0'));
  96                 end case;
  97         end;
  98
  99         function decode_input_reg_c (t : input_reg_c_t; insn_in : std_ulogic_vector(31 downto 0);
 100                                      reg_data : std_ulogic_vector(63 downto 0)) return decode_input_reg_t is
 101         begin
 102                 case t is
 103                 when RS =>
 104                         return ('1', insn_rs(insn_in), reg_data);
 105                 when NONE =>
 106                         return ('0', (others => '0'), (others => '0'));
 107                 end case;
 108         end;
 109
 110         function decode_output_reg (t : output_reg_a_t; insn_in : std_ulogic_vector(31 downto 0)) return std_ulogic_vector is
 111         begin
 112                 case t is
 113                 when RT =>
 114                         return insn_rt(insn_in);
 115                 when RA =>
 116                         return insn_ra(insn_in);
 117                 when NONE =>
 118                         return "00000";
 119                 end case;
 120         end;
 121
 122         function decode_rc (t : rc_t; insn_in : std_ulogic_vector(31 downto 0)) return std_ulogic is
 123         begin
 124                 case t is
 125                 when RC =>
 126                         return insn_rc(insn_in);
 127                 when ONE =>
 128                         return '1';
 129                 when NONE =>
 130                         return '0';
 131                 end case;
 132         end;
 133
 134         -- issue control signals
 135         signal control_valid_in : std_ulogic;
 136         signal control_valid_out : std_ulogic;
 137         signal control_sgl_pipe : std_logic;
 138
 139         signal gpr_write_valid : std_ulogic;
 140         signal gpr_write : std_ulogic_vector(4 downto 0);
 141
 142         signal gpr_a_read_valid : std_ulogic;
 143         signal gpr_a_read : std_ulogic_vector(4 downto 0);
 144
 145         signal gpr_b_read_valid : std_ulogic;
 146         signal gpr_b_read : std_ulogic_vector(4 downto 0);
 147
 148         signal gpr_c_read_valid : std_ulogic;
 149         signal gpr_c_read : std_ulogic_vector(4 downto 0);
 150 begin
 151         control_0: entity work.control
 152         generic map (
 153                 PIPELINE_DEPTH => 2
 154         )
 155         port map (
 156                 clk         => clk,
 157                 rst         => rst,
 158
 159                 complete_in => complete_in,
 160                 valid_in    => control_valid_in,
 161                 flush_in    => flush_in,
 162                 sgl_pipe_in => control_sgl_pipe,
 163                 stop_mark_in => d_in.stop_mark,
 164
 165                 gpr_write_valid_in => gpr_write_valid,
 166                 gpr_write_in       => gpr_write,
 167
 168                 gpr_a_read_valid_in  => gpr_a_read_valid,
 169                 gpr_a_read_in        => gpr_a_read,
 170
 171                 gpr_b_read_valid_in  => gpr_b_read_valid,
 172                 gpr_b_read_in        => gpr_b_read,
 173
 174                 gpr_c_read_valid_in  => gpr_c_read_valid,
 175                 gpr_c_read_in        => gpr_c_read,
 176
 177                 valid_out   => control_valid_out,
 178                 stall_out   => stall_out,
 179                 stopped_out => stopped_out
 180         );
 181
 182         decode2_0: process(clk)
 183         begin
 184                 if rising_edge(clk) then
 185                         if rin.e.valid = '1' or rin.l.valid = '1' or rin.m.valid = '1' or rin.d.valid = '1' then
 186                                 report "execute " & to_hstring(rin.e.nia);
 187                         end if;
 188                         r <= rin;
 189                 end if;
 190         end process;
 191
 192         r_out.read1_reg <= insn_ra(d_in.insn);
 193         r_out.read2_reg <= insn_rb(d_in.insn);
 194         r_out.read3_reg <= insn_rs(d_in.insn);
 195
 196         c_out.read <= d_in.decode.input_cr;
 197
 198         decode2_1: process(all)
 199                 variable v : reg_type;
 200                 variable mul_a : std_ulogic_vector(63 downto 0);
 201                 variable mul_b : std_ulogic_vector(63 downto 0);
 202                 variable decoded_reg_a : decode_input_reg_t;
 203                 variable decoded_reg_b : decode_input_reg_t;
 204                 variable decoded_reg_c : decode_input_reg_t;
 205                 variable signed_division: std_ulogic;
 206         begin
 207                 v := r;
 208
 209                 v.e := Decode2ToExecute1Init;
 210                 v.l := Decode2ToLoadStore1Init;
 211                 v.m := Decode2ToMultiplyInit;
 212                 v.d := Decode2ToDividerInit;
 213
 214                 mul_a := (others => '0');
 215                 mul_b := (others => '0');
 216
 217                 --v.e.input_cr := d_in.decode.input_cr;
 218                 --v.m.input_cr := d_in.decode.input_cr;
 219                 --v.e.output_cr := d_in.decode.output_cr;
 220
 221                 decoded_reg_a := decode_input_reg_a (d_in.decode.input_reg_a, d_in.insn, r_in.read1_data);
 222                 decoded_reg_b := decode_input_reg_b (d_in.decode.input_reg_b, d_in.insn, r_in.read2_data);
 223                 decoded_reg_c := decode_input_reg_c (d_in.decode.input_reg_c, d_in.insn, r_in.read3_data);
 224
 225                 r_out.read1_enable <= decoded_reg_a.reg_valid;
 226                 r_out.read2_enable <= decoded_reg_b.reg_valid;
 227                 r_out.read3_enable <= decoded_reg_c.reg_valid;
 228
 229                 -- execute unit
 230                 v.e.nia := d_in.nia;
 231                 v.e.insn_type := d_in.decode.insn_type;
 232                 v.e.read_reg1 := decoded_reg_a.reg;
 233                 v.e.read_data1 := decoded_reg_a.data;
 234                 v.e.read_reg2 := decoded_reg_b.reg;
 235                 v.e.read_data2 := decoded_reg_b.data;
 236                 v.e.read_data3 := decoded_reg_c.data;
 237                 v.e.write_reg := decode_output_reg(d_in.decode.output_reg_a, d_in.insn);
 238                 v.e.rc := decode_rc(d_in.decode.rc, d_in.insn);
 239                 v.e.cr := c_in.read_cr_data;
 240                 v.e.invert_a := d_in.decode.invert_a;
 241                 v.e.invert_out := d_in.decode.invert_out;
 242                 v.e.input_carry := d_in.decode.input_carry;
 243                 v.e.output_carry := d_in.decode.output_carry;
 244                 v.e.is_32bit := d_in.decode.is_32bit;
 245                 v.e.is_signed := d_in.decode.is_signed;
 246                 if d_in.decode.lr = '1' then
 247                         v.e.lr := insn_lk(d_in.insn);
 248                 end if;
 249                 v.e.insn := d_in.insn;
 250
 251                 -- multiply unit
 252                 v.m.insn_type := d_in.decode.insn_type;
 253                 mul_a := decoded_reg_a.data;
 254                 mul_b := decoded_reg_b.data;
 255                 v.m.write_reg := decode_output_reg(d_in.decode.output_reg_a, d_in.insn);
 256                 v.m.rc := decode_rc(d_in.decode.rc, d_in.insn);
 257
 258                 if d_in.decode.is_32bit = '1' then
 259                         if d_in.decode.is_signed = '1' then
 260                                 v.m.data1 := (others => mul_a(31));
 261                                 v.m.data1(31 downto 0) := mul_a(31 downto 0);
 262                                 v.m.data2 := (others => mul_b(31));
 263                                 v.m.data2(31 downto 0) := mul_b(31 downto 0);
 264                         else
 265                                 v.m.data1 := '0' & x"00000000" & mul_a(31 downto 0);
 266                                 v.m.data2 := '0' & x"00000000" & mul_b(31 downto 0);
 267                         end if;
 268                 else
 269                         if d_in.decode.is_signed = '1' then
 270                                 v.m.data1 := mul_a(63) & mul_a;
 271                                 v.m.data2 := mul_b(63) & mul_b;
 272                         else
 273                                 v.m.data1 := '0' & mul_a;
 274                                 v.m.data2 := '0' & mul_b;
 275                         end if;
 276                 end if;
 277
 278                 -- divide unit
 279                 -- PPC divide and modulus instruction words have these bits in
 280                 -- the bottom 11 bits: o1dns 010t1 r
 281                 -- where o = OE for div instrs, signedness for mod instrs
 282                 --       d = 1 for div*, 0 for mod*
 283                 --       n = 1 for normal, 0 for extended (dividend << 32/64)
 284                 --       s = 1 for signed, 0 for unsigned (for div*)
 285                 --       t = 1 for 32-bit, 0 for 64-bit
 286                 --       r = RC bit (record condition code)
 287                 v.d.write_reg := decode_output_reg(d_in.decode.output_reg_a, d_in.insn);
 288                 v.d.is_modulus := not d_in.insn(8);
 289                 v.d.is_32bit := d_in.insn(2);
 290                 if d_in.insn(8) = '1' then
 291                         signed_division := d_in.insn(6);
 292                 else
 293                         signed_division := d_in.insn(10);
 294                 end if;
 295                 v.d.is_signed := signed_division;
 296                 if d_in.insn(2) = '0' then
 297                         -- 64-bit forms
 298                         if d_in.insn(8) = '1' and d_in.insn(7) = '0' then
 299                                 v.d.is_extended := '1';
 300                         end if;
 301                         v.d.dividend := decoded_reg_a.data;
 302                         v.d.divisor := decoded_reg_b.data;
 303                 else
 304                         -- 32-bit forms
 305                         if d_in.insn(8) = '1' and d_in.insn(7) = '0' then   -- extended forms
 306                                 v.d.dividend := decoded_reg_a.data(31 downto 0) & x"00000000";
 307                         elsif signed_division = '1' and decoded_reg_a.data(31) = '1' then
 308                                 -- sign extend to 64 bits
 309                                 v.d.dividend := x"ffffffff" & decoded_reg_a.data(31 downto 0);
 310                         else
 311                                 v.d.dividend := x"00000000" & decoded_reg_a.data(31 downto 0);
 312                         end if;
 313                         if signed_division = '1' and decoded_reg_b.data(31) = '1' then
 314                                 v.d.divisor := x"ffffffff" & decoded_reg_b.data(31 downto 0);
 315                         else
 316                                 v.d.divisor := x"00000000" & decoded_reg_b.data(31 downto 0);
 317                         end if;
 318                 end if;
 319                 v.d.rc := decode_rc(d_in.decode.rc, d_in.insn);
 320
 321                 -- load/store unit
 322                 v.l.update_reg := decoded_reg_a.reg;
 323                 v.l.addr1 := decoded_reg_a.data;
 324                 v.l.addr2 := decoded_reg_b.data;
 325                 v.l.data := decoded_reg_c.data;
 326                 v.l.write_reg := decode_output_reg(d_in.decode.output_reg_a, d_in.insn);
 327
 328                 if d_in.decode.insn_type = OP_LOAD then
 329                         v.l.load := '1';
 330                 else
 331                         v.l.load := '0';
 332                 end if;
 333
 334                 case d_in.decode.length is
 335                 when is1B =>
 336                         v.l.length := "0001";
 337                 when is2B =>
 338                         v.l.length := "0010";
 339                 when is4B =>
 340                         v.l.length := "0100";
 341                 when is8B =>
 342                         v.l.length := "1000";
 343                 when NONE =>
 344                         v.l.length := "0000";
 345                 end case;
 346
 347                 v.l.byte_reverse := d_in.decode.byte_reverse;
 348                 v.l.sign_extend := d_in.decode.sign_extend;
 349                 v.l.update := d_in.decode.update;
 350
 351                 -- issue control
 352                 control_valid_in <= d_in.valid;
 353                 control_sgl_pipe <= d_in.decode.sgl_pipe;
 354
 355                 gpr_write_valid <= '1' when d_in.decode.output_reg_a /= NONE else '0';
 356                 gpr_write <= decode_output_reg(d_in.decode.output_reg_a, d_in.insn);
 357
 358                 gpr_a_read_valid <= decoded_reg_a.reg_valid;
 359                 gpr_a_read <= decoded_reg_a.reg;
 360
 361                 gpr_b_read_valid <= decoded_reg_b.reg_valid;
 362                 gpr_b_read <= decoded_reg_b.reg;
 363
 364                 gpr_c_read_valid <= decoded_reg_c.reg_valid;
 365                 gpr_c_read <= decoded_reg_c.reg;
 366
 367                 v.e.valid := '0';
 368                 v.m.valid := '0';
 369                 v.d.valid := '0';
 370                 v.l.valid := '0';
 371                 case d_in.decode.unit is
 372                 when ALU =>
 373                         v.e.valid := control_valid_out;
 374                 when LDST =>
 375                         v.l.valid := control_valid_out;
 376                 when MUL =>
 377                         v.m.valid := control_valid_out;
 378                 when DIV =>
 379                         v.d.valid := control_valid_out;
 380                 when NONE =>
 381                         v.e.valid := control_valid_out;
 382                         v.e.insn_type := OP_ILLEGAL;
 383                 end case;
 384
 385                 if rst = '1' then
 386                         v.e := Decode2ToExecute1Init;
 387                         v.l := Decode2ToLoadStore1Init;
 388                         v.m := Decode2ToMultiplyInit;
 389                         v.d := Decode2ToDividerInit;
 390                 end if;
 391
 392                 -- Update registers
 393                 rin <= v;
 394
 395                 -- Update outputs
 396                 e_out <= r.e;
 397                 l_out <= r.l;
 398                 m_out <= r.m;
 399                 d_out <= r.d;
 400         end process;
 401 end architecture behaviour;