libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  62 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  63 #  1.x:  minimum required version
  64 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  65 #              of other PACKAGE_* variables will, however, and there's nothing
  66 #              we can do about that; they come from AC_INIT).
  67 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  68 #            file in the top srcdir, etc, etc), so stop complaining.
  69 #  no-dependencies:  turns off auto dependency generation (just for now)
  70 #  no-dist:  we don't want 'dist' and related rules.
  71 #  -Wall:  turns on all automake warnings...
  72 #  -Wno-portability:  ...except this one, since GNU make is now required.
  73 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  74 AH_TEMPLATE(PACKAGE, [Name of package])
  75 AH_TEMPLATE(VERSION, [Version number of package])
  76
  77 # -fno-builtin must be present here so that a non-conflicting form of
  78 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  79
  80 save_CXXFLAGS="$CXXFLAGS"
  81 CXXFLAGS="$CXXFLAGS -fno-builtin"
  82 AC_PROG_CC
  83 AC_PROG_CXX
  84 CXXFLAGS="$save_CXXFLAGS"
  85
  86 AC_SYS_LARGEFILE
  87
  88 # Runs configure.host, and assorted other critical bits.  Sets
  89 # up critical shell variables.
  90 GLIBCXX_CONFIGURE
  91
  92 # Libtool setup.
  93 if test "x${with_newlib}" != "xyes" && test "x${with_avrlibc}" != "xyes"; then
  94   AC_LIBTOOL_DLOPEN
  95 fi
  96 AM_PROG_LIBTOOL
  97 ACX_LT_HOST_FLAGS
  98 AC_SUBST(enable_shared)
  99 AC_SUBST(enable_static)
 100
 101 if test "$enable_vtable_verify" = yes; then
 102   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 103   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 104 fi
 105
 106
 107 # libtool variables for C++ shared and position-independent compiles.
 108 #
 109 # Use glibcxx_lt_pic_flag to designate the automake variable
 110 # used to encapsulate the default libtool approach to creating objects
 111 # with position-independent code. Default: -prefer-pic.
 112 #
 113 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 114 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 115 #
 116 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 117 # creating position-independent objects. This varies with the target
 118 # hardware and operating system, but is often: -DPIC -fPIC.
 119 if test "$enable_shared" = yes; then
 120   glibcxx_lt_pic_flag="-prefer-pic"
 121   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 122   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 123
 124 else
 125   glibcxx_lt_pic_flag=
 126   glibcxx_compiler_pic_flag=
 127   glibcxx_compiler_shared_flag=
 128 fi
 129 AC_SUBST(glibcxx_lt_pic_flag)
 130 AC_SUBST(glibcxx_compiler_pic_flag)
 131 AC_SUBST(glibcxx_compiler_shared_flag)
 132
 133 # Override the libtool's pic_flag and pic_mode.
 134 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 135 # NB: this impacts --with-pic and --without-pic.
 136 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 137 pic_mode='default'
 138
 139 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 140 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 141
 142 # Possibly disable most of the library.
 143 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 144 ## than just ignoring the results.  Faster /and/ more correct, win win.
 145 GLIBCXX_ENABLE_HOSTED
 146
 147 # Enable descriptive messages to standard output on termination.
 148 GLIBCXX_ENABLE_VERBOSE
 149
 150 # Enable compiler support that doesn't require linking.
 151 GLIBCXX_ENABLE_PCH($is_hosted)
 152 GLIBCXX_ENABLE_THREADS
 153 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 154 GLIBCXX_ENABLE_LOCK_POLICY
 155 GLIBCXX_ENABLE_DECIMAL_FLOAT
 156 GLIBCXX_ENABLE_INT128_FLOAT128
 157 if test "$enable_float128" = yes; then
 158   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 159 fi
 160
 161 # Checks for compiler support that doesn't require linking.
 162 GLIBCXX_CHECK_COMPILER_FEATURES
 163
 164 # Enable all the variable C++ runtime options that don't require linking.
 165 GLIBCXX_ENABLE_CSTDIO
 166 GLIBCXX_ENABLE_CLOCALE
 167 GLIBCXX_ENABLE_ALLOCATOR
 168 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 169 GLIBCXX_ENABLE_LONG_LONG([yes])
 170 GLIBCXX_ENABLE_WCHAR_T([yes])
 171 GLIBCXX_ENABLE_C99([yes])
 172 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 173 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 174 GLIBCXX_ENABLE_DEBUG([no])
 175 GLIBCXX_ENABLE_PARALLEL([yes])
 176 GLIBCXX_ENABLE_CXX_FLAGS
 177 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 178 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 179 GLIBCXX_ENABLE_PYTHON
 180 GLIBCXX_ENABLE_WERROR([no])
 181 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 182
 183 # Checks for operating systems support that doesn't require linking.
 184 GLIBCXX_CHECK_STDIO_PROTO
 185 GLIBCXX_CHECK_MATH11_PROTO
 186 GLIBCXX_CHECK_UCHAR_H
 187
 188 # For the streamoff typedef.
 189 GLIBCXX_CHECK_INT64_T
 190
 191 # For LFS support.
 192 GLIBCXX_CHECK_LFS
 193
 194 # For showmanyc_helper().
 195 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 196 GLIBCXX_CHECK_POLL
 197 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 198
 199 # For xsputn_2().
 200 AC_CHECK_HEADERS(sys/uio.h)
 201 GLIBCXX_CHECK_WRITEV
 202
 203 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 204 # so that the check is done with the C compiler (not C++).
 205 # Checking with C++ can break a canadian cross build if either
 206 # file does not exist in C but does in C++.
 207 AC_CHECK_HEADERS(fenv.h complex.h)
 208
 209 # For C99 support to TR1.
 210 GLIBCXX_CHECK_C99_TR1
 211
 212 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 213 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 214
 215 # For gettimeofday support.
 216 GLIBCXX_CHECK_GETTIMEOFDAY
 217
 218 # For clock_gettime, nanosleep and sched_yield support.
 219 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 220
 221 # Check for tmpnam which is obsolescent in POSIX.1-2008
 222 GLIBCXX_CHECK_TMPNAM
 223
 224 # For pthread_cond_clockwait
 225 GLIBCXX_CHECK_PTHREAD_COND_CLOCKWAIT
 226
 227 # For pthread_mutex_clocklock
 228 GLIBCXX_CHECK_PTHREAD_MUTEX_CLOCKLOCK
 229
 230 # For pthread_rwlock_clockrdlock and pthread_rwlock_clockwrlock
 231 GLIBCXX_CHECK_PTHREAD_RWLOCK_CLOCKLOCK
 232
 233 AC_LC_MESSAGES
 234
 235 # For hardware_concurrency
 236 AC_CHECK_HEADERS(sys/sysinfo.h)
 237 GLIBCXX_CHECK_GET_NPROCS
 238 AC_CHECK_HEADERS(unistd.h)
 239 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 240 GLIBCXX_CHECK_SC_NPROC_ONLN
 241 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 242 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 243 GLIBCXX_CHECK_SDT_H
 244
 245 # Check for available headers.
 246 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 247 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 248 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 249 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 250 wchar.h wctype.h linux/types.h])
 251
 252 AC_CHECK_HEADERS([linux/random.h], [], [],
 253 [[#ifdef HAVE_LINUX_TYPES_H
 254 # include <linux/types.h>
 255 #endif
 256 ]])
 257
 258 AC_CHECK_HEADERS([xlocale.h])
 259
 260 # Only do link tests if native. Else, hardcode.
 261 if $GLIBCXX_IS_NATIVE; then
 262
 263   # We can do more elaborate tests that assume a working linker.
 264   CANADIAN=no
 265
 266   GLIBCXX_CHECK_LINKER_FEATURES
 267   GLIBCXX_CHECK_MATH_SUPPORT
 268   GLIBCXX_CHECK_STDLIB_SUPPORT
 269
 270   # For /dev/random and /dev/urandom for std::random_device.
 271   GLIBCXX_CHECK_DEV_RANDOM
 272
 273   # For TLS support.
 274   GCC_CHECK_TLS
 275
 276   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 277   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 278   AC_CHECK_FUNCS(_wfopen)
 279
 280   # C11 functions for C++17 library
 281   AC_CHECK_FUNCS(timespec_get)
 282
 283   # For Networking TS.
 284   AC_CHECK_FUNCS(sockatmark)
 285
 286   # Non-standard functions used by C++17 std::from_chars
 287   AC_CHECK_FUNCS(uselocale)
 288
 289   # For iconv support.
 290   AM_ICONV
 291
 292 else
 293
 294   # This lets us hard-code the functionality we know we'll have in the cross
 295   # target environment.  "Let" is a sugar-coated word placed on an especially
 296   # dull and tedious hack, actually.
 297   #
 298   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 299   # that involve linking, can't be used:
 300   #    "cannot open sim-crt0.o"
 301   #    "cannot open crt0.o"
 302   # etc.  All this is because there currently exists no unified, consistent
 303   # way for top level CC information to be passed down to target directories:
 304   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 305   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 306   # crosses can be removed.
 307
 308   # If Canadian cross, then don't pick up tools from the build directory.
 309   # Used only in GLIBCXX_EXPORT_INCLUDES.
 310   if test -n "$with_cross_host" &&
 311      test x"$build_alias" != x"$with_cross_host" &&
 312      test x"$build" != x"$target";
 313   then
 314     CANADIAN=yes
 315   else
 316     CANADIAN=no
 317   fi
 318
 319   # Construct crosses by hand, eliminating bits that need ld...
 320   # GLIBCXX_CHECK_MATH_SUPPORT
 321
 322   # First, test for "known" system libraries.  We may be using newlib even
 323   # on a hosted environment.
 324   if test "x${with_newlib}" = "xyes"; then
 325     os_include_dir="os/newlib"
 326     AC_DEFINE(HAVE_HYPOT)
 327
 328     # GLIBCXX_CHECK_STDLIB_SUPPORT
 329     AC_DEFINE(HAVE_STRTOF)
 330
 331     AC_DEFINE(HAVE_ACOSF)
 332     AC_DEFINE(HAVE_ASINF)
 333     AC_DEFINE(HAVE_ATAN2F)
 334     AC_DEFINE(HAVE_ATANF)
 335     AC_DEFINE(HAVE_CEILF)
 336     AC_DEFINE(HAVE_COSF)
 337     AC_DEFINE(HAVE_COSHF)
 338     AC_DEFINE(HAVE_EXPF)
 339     AC_DEFINE(HAVE_FABSF)
 340     AC_DEFINE(HAVE_FLOORF)
 341     AC_DEFINE(HAVE_FMODF)
 342     AC_DEFINE(HAVE_FREXPF)
 343     AC_DEFINE(HAVE_LDEXPF)
 344     AC_DEFINE(HAVE_LOG10F)
 345     AC_DEFINE(HAVE_LOGF)
 346     AC_DEFINE(HAVE_MODFF)
 347     AC_DEFINE(HAVE_POWF)
 348     AC_DEFINE(HAVE_SINF)
 349     AC_DEFINE(HAVE_SINHF)
 350     AC_DEFINE(HAVE_SQRTF)
 351     AC_DEFINE(HAVE_TANF)
 352     AC_DEFINE(HAVE_TANHF)
 353
 354     AC_DEFINE(HAVE_ICONV)
 355     AC_DEFINE(HAVE_MEMALIGN)
 356   else
 357     GLIBCXX_CROSSCONFIG
 358   fi
 359
 360   # At some point, we should differentiate between architectures
 361   # like x86, which have long double versions, and alpha/powerpc/etc.,
 362   # which don't. For the time being, punt.
 363   if test x"long_double_math_on_this_cpu" = x"yes"; then
 364     AC_DEFINE(HAVE_ACOSL)
 365     AC_DEFINE(HAVE_ASINL)
 366     AC_DEFINE(HAVE_ATAN2L)
 367     AC_DEFINE(HAVE_ATANL)
 368     AC_DEFINE(HAVE_CEILL)
 369     AC_DEFINE(HAVE_COSL)
 370     AC_DEFINE(HAVE_COSHL)
 371     AC_DEFINE(HAVE_EXPL)
 372     AC_DEFINE(HAVE_FABSL)
 373     AC_DEFINE(HAVE_FLOORL)
 374     AC_DEFINE(HAVE_FMODL)
 375     AC_DEFINE(HAVE_FREXPL)
 376     AC_DEFINE(HAVE_LDEXPL)
 377     AC_DEFINE(HAVE_LOG10L)
 378     AC_DEFINE(HAVE_LOGL)
 379     AC_DEFINE(HAVE_MODFL)
 380     AC_DEFINE(HAVE_POWL)
 381     AC_DEFINE(HAVE_SINCOSL)
 382     AC_DEFINE(HAVE_SINL)
 383     AC_DEFINE(HAVE_SINHL)
 384     AC_DEFINE(HAVE_SQRTL)
 385     AC_DEFINE(HAVE_TANL)
 386     AC_DEFINE(HAVE_TANHL)
 387   fi
 388 fi
 389
 390 # Check for _Unwind_GetIPInfo.
 391 GCC_CHECK_UNWIND_GETIPINFO
 392
 393 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 394
 395 GCC_HEADER_STDINT(include/gstdint.h)
 396
 397 GLIBCXX_ENABLE_SYMVERS([yes])
 398 AC_SUBST(libtool_VERSION)
 399
 400 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 401
 402 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 403 GLIBCXX_DEFAULT_ABI
 404
 405 ac_ldbl_compat=no
 406 ac_ldbl_alt128_compat=no
 407 ac_ldbl_ieee128_default=no
 408 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 409 LONG_DOUBLE_128_FLAGS=
 410 LONG_DOUBLE_ALT128_COMPAT_FLAGS=
 411 case "$target" in
 412   powerpc*-*-linux* | \
 413   sparc*-*-linux* | \
 414   s390*-*-linux* | \
 415   alpha*-*-linux*)
 416   AC_TRY_COMPILE(, [
 417 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 418 #error no need for long double compatibility
 419 #endif
 420   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 421   if test "$ac_ldbl_compat" = yes; then
 422     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 423               [Define if compatibility should be provided for -mlong-double-64.])
 424     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 425     case "$target" in
 426       powerpc*-*-linux*)
 427         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute"
 428         # Check for IEEE128 support in libm:
 429         AC_CHECK_LIB(m, __frexpieee128,
 430                      [ac_ldbl_ieee128_in_libc=yes],
 431                      [ac_ldbl_ieee128_in_libc=no])
 432         if test $ac_ldbl_ieee128_in_libc = yes; then
 433           # Determine which long double format is the compiler's default:
 434           AC_TRY_COMPILE(, [
 435             #ifndef __LONG_DOUBLE_IEEE128__
 436             #error compiler defaults to ibm128
 437             #endif
 438           ], [ac_ldbl_ieee128_default=yes], [ac_ldbl_ieee128_default=no])
 439           # Library objects should use default long double format.
 440           if test "$ac_ldbl_ieee128_default" = yes; then
 441             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 442             # Except for the ones that explicitly use these flags:
 443             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ibmlongdouble -mno-gnu-attribute -Wno-psabi"
 444           else
 445             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 446             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ieeelongdouble -mno-gnu-attribute -Wno-psabi"
 447           fi
 448           AC_DEFINE([_GLIBCXX_LONG_DOUBLE_ALT128_COMPAT],1,
 449                 [Define if compatibility should be provided for alternative 128-bit long double formats.])
 450           port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/os/gnu-linux/ldbl-ieee128-extra.ver"
 451           ac_ldbl_alt128_compat=yes
 452         else
 453           ac_ldbl_alt128_compat=no
 454         fi
 455         ;;
 456     esac
 457   fi
 458 esac
 459 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 460 AC_SUBST(LONG_DOUBLE_128_FLAGS)
 461 AC_SUBST(LONG_DOUBLE_ALT128_COMPAT_FLAGS)
 462 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 463 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_ALT128_COMPAT, test $ac_ldbl_alt128_compat = yes)
 464
 465 # Check if assembler supports disabling hardware capability support.
 466 GCC_CHECK_ASSEMBLER_HWCAP
 467
 468 # Check if assembler supports rdrand opcode.
 469 GLIBCXX_CHECK_X86_RDRAND
 470 # Check if assembler supports rdseed opcode.
 471 GLIBCXX_CHECK_X86_RDSEED
 472
 473 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 474 GLIBCXX_CONFIGURE_TESTSUITE
 475
 476 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 477 GLIBCXX_CHECK_GTHREADS
 478
 479 # For Filesystem TS.
 480 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 481 GLIBCXX_ENABLE_FILESYSTEM_TS
 482 GLIBCXX_CHECK_FILESYSTEM_DEPS
 483
 484 # For Networking TS.
 485 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 486
 487 # For Transactional Memory TS
 488 GLIBCXX_CHECK_SIZE_T_MANGLING
 489
 490 # Check which release added std::exception_ptr for the target
 491 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 492
 493 # Define documentation rules conditionally.
 494
 495 # See if makeinfo has been installed and is modern enough
 496 # that we can use it.
 497 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 498                    [GNU texinfo.* \([0-9][0-9.]*\)],
 499                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 500 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 501
 502 # Check for doxygen
 503 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 504 AC_CHECK_PROG([DOT], dot, yes, no)
 505
 506 # Check for docbook
 507 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 508 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 509 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 510 GLIBCXX_CONFIGURE_DOCBOOK
 511
 512 # Check for xml/html dependencies.
 513 AM_CONDITIONAL(BUILD_XML,
 514                test $ac_cv_prog_DOXYGEN = "yes" &&
 515                test $ac_cv_prog_DOT = "yes" &&
 516                test $ac_cv_prog_XSLTPROC = "yes" &&
 517                test $ac_cv_prog_XMLLINT = "yes" &&
 518                test $glibcxx_stylesheets = "yes")
 519
 520 AM_CONDITIONAL(BUILD_HTML,
 521                test $ac_cv_prog_DOXYGEN = "yes" &&
 522                test $ac_cv_prog_DOT = "yes" &&
 523                test $ac_cv_prog_XSLTPROC = "yes" &&
 524                test $ac_cv_prog_XMLLINT = "yes" &&
 525                test $glibcxx_stylesheets = "yes")
 526
 527 # Check for man dependencies.
 528 AM_CONDITIONAL(BUILD_MAN,
 529                test $ac_cv_prog_DOXYGEN = "yes" &&
 530                test $ac_cv_prog_DOT = "yes")
 531
 532 # Check for pdf dependencies.
 533 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 534 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 535 AM_CONDITIONAL(BUILD_PDF,
 536                test $ac_cv_prog_DOXYGEN = "yes" &&
 537                test $ac_cv_prog_DOT = "yes" &&
 538                test $ac_cv_prog_XSLTPROC = "yes" &&
 539                test $ac_cv_prog_XMLLINT = "yes" &&
 540                test $ac_cv_prog_DBLATEX = "yes" &&
 541                test $ac_cv_prog_PDFLATEX = "yes")
 542
 543 case "$build" in
 544  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 545  * ) glibcxx_include_dir_notparallel=no ;;
 546 esac
 547 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 548                test $glibcxx_include_dir_notparallel = "yes")
 549
 550 # Propagate the target-specific source directories through the build chain.
 551 ATOMICITY_SRCDIR=config/${atomicity_dir}
 552 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 553 ATOMIC_FLAGS=${atomic_flags}
 554 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 555 OS_INC_SRCDIR=config/${os_include_dir}
 556 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 557 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 558 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 559 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 560 AC_SUBST(ATOMICITY_SRCDIR)
 561 AC_SUBST(ATOMIC_WORD_SRCDIR)
 562 AC_SUBST(ATOMIC_FLAGS)
 563 AC_SUBST(CPU_DEFINES_SRCDIR)
 564 AC_SUBST(ABI_TWEAKS_SRCDIR)
 565 AC_SUBST(OS_INC_SRCDIR)
 566 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 567 AC_SUBST(CPU_OPT_EXT_RANDOM)
 568 AC_SUBST(CPU_OPT_BITS_RANDOM)
 569
 570 # Conditionalize the makefile for this target machine.
 571 tmake_file_=
 572 for f in ${tmake_file}
 573 do
 574         if test -f ${srcdir}/config/$f
 575         then
 576                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 577         fi
 578 done
 579 tmake_file="${tmake_file_}"
 580 AC_SUBST(tmake_file)
 581
 582 # Add CET specific flags if Intel CET is enabled.
 583 GCC_CET_FLAGS(CET_FLAGS)
 584 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 585 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 586 AC_SUBST(EXTRA_CFLAGS)
 587 AC_SUBST(EXTRA_CXX_FLAGS)
 588
 589 # Determine cross-compile flags and AM_CONDITIONALs.
 590 #AC_SUBST(GLIBCXX_IS_NATIVE)
 591 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 592 GLIBCXX_EVALUATE_CONDITIONALS
 593
 594 AC_CACHE_SAVE
 595
 596 if test ${multilib} = yes; then
 597   multilib_arg="--enable-multilib"
 598 else
 599   multilib_arg=
 600 fi
 601
 602 # Export all the install information.
 603 GLIBCXX_EXPORT_INSTALL_INFO
 604
 605 # Export all the include and flag information to Makefiles.
 606 GLIBCXX_EXPORT_INCLUDES
 607 GLIBCXX_EXPORT_FLAGS
 608
 609 # Determine what GCC version number to use in filesystem paths.
 610 GCC_BASE_VER
 611
 612 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 613 dnl which can all be called multiple times as needed, plus one (different)
 614 dnl AC_OUTPUT macro.  This one lists the files to be created:
 615 AC_CONFIG_FILES(Makefile)
 616 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 617 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 618 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 619
 620 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 621 # that multilib installs will end up installed in the correct place.
 622 # The testsuite needs it for multilib-aware ABI baseline files.
 623 # To work around this not being passed down from config-ml.in ->
 624 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 625 # append it here.  Only modify Makefiles that have just been created.
 626 #
 627 # Also, get rid of this simulated-VPATH thing that automake does.
 628 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 629   [cat > vpsed$$ << \_EOF
 630 s!`test -f '$<' || echo '$(srcdir)/'`!!
 631 _EOF
 632    sed -f vpsed$$ $ac_file > tmp$$
 633    mv tmp$$ $ac_file
 634    rm vpsed$$
 635    echo 'MULTISUBDIR =' >> $ac_file
 636    ml_norecursion=yes
 637    . ${multi_basedir}/config-ml.in
 638    AS_UNSET([ml_norecursion])
 639 ])
 640
 641 AC_CONFIG_COMMANDS([generate-headers],
 642   [(cd include && ${MAKE-make} pch_build= )])
 643
 644 dnl And this actually makes things happen:
 645 AC_OUTPUT