src/bsv_lib/Semi_FIFOF.bsv

   1 /*
   2 Copyright (c) 2013, IIT Madras
   3 All rights reserved.
   4
   5 Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:
   6
   7 *  Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
   8 *  Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.
   9 *  Neither the name of IIT Madras  nor the names of its contributors may be used to endorse or promote products derived from this software without specific prior written permission.
  10
  11 THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  12 ---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
  13 */
  14 // Copyright (c) 2017 Bluespec, Inc.  All Rights Reserved
  15
  16 package Semi_FIFOF;
  17
  18 // ================================================================
  19 // Separate interfaces for input-side and output-side of FIFOF.
  20 // Conversion functions to these, from FIFOF interfaces.
  21
  22 // ================================================================
  23 // BSV library imports
  24
  25 import FIFOF       :: *;
  26 import Connectable :: *;
  27
  28 // ================================================================
  29 // Semi-FIFOF interfaces
  30
  31 interface FIFOF_I #(type t);
  32    method Action  enq (t x);
  33    method Bool    notFull ();
  34 endinterface
  35
  36 interface FIFOF_O #(type t);
  37    method t       first ();
  38    method Action  deq ();
  39    method Bool    notEmpty ();
  40 endinterface
  41
  42 // ================================================================
  43 // Converters from FIFOF
  44
  45 function FIFOF_I #(t) to_FIFOF_I (FIFOF #(t) f);
  46    return interface FIFOF_I;
  47              method enq (x) = f.enq (x);
  48              method notFull = f.notFull;
  49           endinterface;
  50 endfunction
  51
  52 function FIFOF_O #(t) to_FIFOF_O (FIFOF #(t) f);
  53    return interface FIFOF_O;
  54              method first    = f.first;
  55              method deq      = f.deq;
  56              method notEmpty = f.notEmpty;
  57           endinterface;
  58 endfunction
  59
  60 // ================================================================
  61 // Connections
  62
  63 // ----------------
  64 // FIFOF_O to a FIFOF_I
  65
  66 instance Connectable #(FIFOF_O #(t), FIFOF_I #(t));
  67    module mkConnection #(FIFOF_O #(t) fo, FIFOF_I #(t) fi) (Empty);
  68       rule rl_connect;
  69          fi.enq (fo.first);
  70          fo.deq;
  71       endrule
  72    endmodule
  73 endinstance
  74
  75 // ----------------
  76 // FIFOF_O to a FIFOF
  77
  78 instance Connectable #(FIFOF_O #(t), FIFOF #(t));
  79    module mkConnection #(FIFOF_O #(t) fo, FIFOF #(t) fi) (Empty);
  80       rule rl_connect;
  81          fi.enq (fo.first);
  82          fo.deq;
  83       endrule
  84    endmodule
  85 endinstance
  86
  87 // ----------------
  88 // FIFOF to a FIFOF_I
  89
  90 instance Connectable #(FIFOF #(t), FIFOF_I #(t));
  91    module mkConnection #(FIFOF #(t) fo, FIFOF_I #(t) fi) (Empty);
  92       rule rl_connect;
  93          fi.enq (fo.first);
  94          fo.deq;
  95       endrule
  96    endmodule
  97 endinstance
  98
  99 // ================================================================
 100 // Convenience function combining first/enq
 101
 102 function ActionValue #(t) pop_o (FIFOF_O #(t) f);
 103    actionvalue
 104       f.deq;
 105       return f.first;
 106    endactionvalue
 107 endfunction
 108
 109 // ================================================================
 110
 111 endpackage