sysdeps/ia64/fpu/e_exp10.S

   1 .file "exp10.s"
   2
   3
   4 // Copyright (c) 2000 - 2005, Intel Corporation
   5 // All rights reserved.
   6 //
   7 //
   8 // Redistribution and use in source and binary forms, with or without
   9 // modification, are permitted provided that the following conditions are
  10 // met:
  11 //
  12 // * Redistributions of source code must retain the above copyright
  13 // notice, this list of conditions and the following disclaimer.
  14 //
  15 // * Redistributions in binary form must reproduce the above copyright
  16 // notice, this list of conditions and the following disclaimer in the
  17 // documentation and/or other materials provided with the distribution.
  18 //
  19 // * The name of Intel Corporation may not be used to endorse or promote
  20 // products derived from this software without specific prior written
  21 // permission.
  22
  23 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  24 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  25 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  26 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  27 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  28 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  29 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  30 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  31 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  32 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  33 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  34 //
  35 // Intel Corporation is the author of this code, and requests that all
  36 // problem reports or change requests be submitted to it directly at
  37 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  38 //
  39 // History
  40 //==============================================================
  41 // 08/25/00 Initial version
  42 // 05/20/02 Cleaned up namespace and sf0 syntax
  43 // 09/06/02 Improved performance; no inexact flags on exact cases
  44 // 01/29/03 Added missing } to bundle templates
  45 // 12/16/04 Call error handling on underflow.
  46 // 03/31/05 Reformatted delimiters between data tables
  47 //
  48 // API
  49 //==============================================================
  50 // double exp10(double)
  51 //
  52 // Overview of operation
  53 //==============================================================
  54 // Background
  55 //
  56 // Implementation
  57 //
  58 // Let x= (K + fh + fl + r)/log2(10), where
  59 // K is an integer, fh= 0.b1 b2 b3 b4 b5,
  60 // fl= 2^{-5}* 0.b6 b7 b8 b8 b10 (fh, fl >= 0),
  61 // and |r|<2^{-11}
  62 // Th is a table that stores 2^fh (32 entries) rounded to
  63 // double extended precision (only mantissa is stored)
  64 // Tl is a table that stores 2^fl (32 entries) rounded to
  65 // double extended precision (only mantissa is stored)
  66 //
  67 // 10^x is approximated as
  68 // 2^K * Th [ f ] * Tl [ f ] * (1+c1*e+c1*r+c2*r^2+c3*r^3+c4*r^4),
  69 // where e= (x*log2(10)_hi-RN(x*log2(10)_hi))+log2(10)_lo*x
  70
  71 // Note there are only 22 non-zero values that produce an exact result:
  72 //  1.0, 2.0, ... 22.0.
  73 // We test for these cases and use s1 to avoid setting the inexact flag.
  74
  75 // Special values
  76 //==============================================================
  77 // exp10(0)= 1
  78 // exp10(+inf)= inf
  79 // exp10(-inf)= 0
  80 //
  81
  82 // Registers used
  83 //==============================================================
  84 // r2-r3, r14-r40
  85 // f6-f15, f32-f52
  86 // p6-p12
  87 //
  88
  89 #include <shlib-compat.h>
  90
  91
  92 GR_TBL_START        = r2
  93 GR_LOG_TBL          = r3
  94
  95 GR_OF_LIMIT         = r14
  96 GR_UF_LIMIT         = r15
  97 GR_EXP_CORR         = r16
  98 GR_F_low            = r17
  99 GR_F_high           = r18
 100 GR_K                = r19
 101 GR_Flow_ADDR        = r20
 102
 103 GR_BIAS             = r21
 104 GR_Fh               = r22
 105 GR_Fh_ADDR          = r23
 106 GR_EXPMAX           = r24
 107 GR_BIAS53           = r25
 108
 109 GR_ROUNDVAL         = r26
 110 GR_SNORM_LIMIT      = r26
 111 GR_MASK             = r27
 112 GR_KF0              = r28
 113 GR_MASK_low         = r29
 114 GR_COEFF_START      = r30
 115 GR_exact_limit      = r31
 116
 117 GR_SAVE_B0          = r33
 118 GR_SAVE_PFS         = r34
 119 GR_SAVE_GP          = r35
 120 GR_SAVE_SP          = r36
 121
 122 GR_Parameter_X      = r37
 123 GR_Parameter_Y      = r38
 124 GR_Parameter_RESULT = r39
 125 GR_Parameter_TAG    = r40
 126
 127
 128 FR_X                = f10
 129 FR_Y                = f1
 130 FR_RESULT           = f8
 131
 132
 133 FR_COEFF1           = f6
 134 FR_COEFF2           = f7
 135 FR_R                = f9
 136 FR_LOG2_10          = f10
 137
 138 FR_2P53             = f11
 139 FR_KF0              = f12
 140 FR_COEFF3           = f13
 141 FR_COEFF4           = f14
 142 FR_UF_LIMIT         = f15
 143
 144 FR_OF_LIMIT         = f32
 145 FR_DX_L210          = f33
 146 FR_ROUNDVAL         = f34
 147 FR_KF               = f35
 148
 149 FR_2_TO_K           = f36
 150 FR_T_low            = f37
 151 FR_T_high           = f38
 152 FR_P34              = f39
 153 FR_R2               = f40
 154
 155 FR_P12              = f41
 156 FR_T_low_K          = f42
 157 FR_P14              = f43
 158 FR_T                = f44
 159 FR_P                = f45
 160
 161 FR_L2_10_low        = f46
 162 FR_L2_10_high       = f47
 163 FR_E0               = f48
 164 FR_E                = f49
 165 FR_exact_limit      = f50
 166
 167 FR_int_x            = f51
 168 FR_SNORM_LIMIT      = f52
 169
 170
 171 // Data tables
 172 //==============================================================
 173
 174 RODATA
 175
 176 .align 16
 177
 178 LOCAL_OBJECT_START(poly_coeffs)
 179
 180 data8 0xd49a784bcd1b8afe, 0x00003fcb // log2(10)*2^(10-63)
 181 data8 0x9257edfe9b5fb698, 0x3fbf // log2(10)_low (bits 64...127)
 182 data8 0x3fac6b08d704a0c0, 0x3f83b2ab6fba4e77 // C_3 and C_4
 183 data8 0xb17217f7d1cf79ab, 0x00003ffe // C_1
 184 data8 0xf5fdeffc162c7541, 0x00003ffc // C_2
 185 LOCAL_OBJECT_END(poly_coeffs)
 186
 187
 188 LOCAL_OBJECT_START(T_table)
 189
 190 // 2^{0.00000 b6 b7 b8 b9 b10}
 191 data8 0x8000000000000000, 0x8016302f17467628
 192 data8 0x802c6436d0e04f50, 0x80429c17d77c18ed
 193 data8 0x8058d7d2d5e5f6b0, 0x806f17687707a7af
 194 data8 0x80855ad965e88b83, 0x809ba2264dada76a
 195 data8 0x80b1ed4fd999ab6c, 0x80c83c56b50cf77f
 196 data8 0x80de8f3b8b85a0af, 0x80f4e5ff089f763e
 197 data8 0x810b40a1d81406d4, 0x81219f24a5baa59d
 198 data8 0x813801881d886f7b, 0x814e67cceb90502c
 199 data8 0x8164d1f3bc030773, 0x817b3ffd3b2f2e47
 200 data8 0x8191b1ea15813bfd, 0x81a827baf7838b78
 201 data8 0x81bea1708dde6055, 0x81d51f0b8557ec1c
 202 data8 0x81eba08c8ad4536f, 0x820225f44b55b33b
 203 data8 0x8218af4373fc25eb, 0x822f3c7ab205c89a
 204 data8 0x8245cd9ab2cec048, 0x825c62a423d13f0c
 205 data8 0x8272fb97b2a5894c, 0x828998760d01faf3
 206 data8 0x82a0393fe0bb0ca8, 0x82b6ddf5dbc35906
 207 //
 208 // 2^{0.b1 b2 b3 b4 b5}
 209 data8 0x8000000000000000, 0x82cd8698ac2ba1d7
 210 data8 0x85aac367cc487b14, 0x88980e8092da8527
 211 data8 0x8b95c1e3ea8bd6e6, 0x8ea4398b45cd53c0
 212 data8 0x91c3d373ab11c336, 0x94f4efa8fef70961
 213 data8 0x9837f0518db8a96f, 0x9b8d39b9d54e5538
 214 data8 0x9ef5326091a111ad, 0xa27043030c496818
 215 data8 0xa5fed6a9b15138ea, 0xa9a15ab4ea7c0ef8
 216 data8 0xad583eea42a14ac6, 0xb123f581d2ac258f
 217 data8 0xb504f333f9de6484, 0xb8fbaf4762fb9ee9
 218 data8 0xbd08a39f580c36be, 0xc12c4cca66709456
 219 data8 0xc5672a115506dadd, 0xc9b9bd866e2f27a2
 220 data8 0xce248c151f8480e3, 0xd2a81d91f12ae45a
 221 data8 0xd744fccad69d6af4, 0xdbfbb797daf23755
 222 data8 0xe0ccdeec2a94e111, 0xe5b906e77c8348a8
 223 data8 0xeac0c6e7dd24392e, 0xefe4b99bdcdaf5cb
 224 data8 0xf5257d152486cc2c, 0xfa83b2db722a033a
 225 LOCAL_OBJECT_END(T_table)
 226
 227
 228
 229 .section .text
 230 GLOBAL_IEEE754_ENTRY(exp10)
 231
 232
 233 {.mfi
 234        alloc r32= ar.pfs, 1, 4, 4, 0
 235        // will continue only for non-zero normal/denormal numbers
 236        fclass.nm.unc p12, p7= f8, 0x1b
 237        mov GR_BIAS53= 0xffff+63-10
 238 }
 239 {.mlx
 240        // GR_TBL_START= pointer to log2(10), C_1...C_4 followed by T_table
 241        addl GR_TBL_START= @ltoff(poly_coeffs), gp
 242        movl GR_ROUNDVAL= 0x3fc00000             // 1.5 (SP)
 243 }
 244 ;;
 245
 246 {.mfi
 247        ld8 GR_COEFF_START= [ GR_TBL_START ]     // Load pointer to coeff table
 248        fcmp.lt.s1 p6, p8= f8, f0                // X<0 ?
 249        nop.i 0
 250 }
 251 ;;
 252
 253 {.mlx
 254        setf.exp FR_2P53= GR_BIAS53              // 2^{63-10}
 255        movl GR_UF_LIMIT= 0xc07439b746e36b52     // (-2^10-51) / log2(10)
 256 }
 257 {.mlx
 258        setf.s FR_ROUNDVAL= GR_ROUNDVAL
 259        movl GR_OF_LIMIT= 0x40734413509f79fe     // Overflow threshold
 260 }
 261 ;;
 262
 263 {.mlx
 264        ldfe FR_LOG2_10= [ GR_COEFF_START ], 16  // load log2(10)*2^(10-63)
 265        movl GR_SNORM_LIMIT= 0xc0733a7146f72a41  // Smallest normal threshold
 266 }
 267 {.mib
 268        nop.m 0
 269        nop.i 0
 270  (p12) br.cond.spnt SPECIAL_exp10               // Branch if nan, inf, zero
 271 }
 272 ;;
 273
 274 {.mmf
 275        ldfe FR_L2_10_low= [ GR_COEFF_START ], 16 // load log2(10)_low
 276        setf.d FR_OF_LIMIT= GR_OF_LIMIT           // Set overflow limit
 277        fma.s0 f8= f8, f1, f0                     // normalize x
 278 }
 279 ;;
 280
 281 {.mfi
 282        ldfpd FR_COEFF3, FR_COEFF4= [ GR_COEFF_START ], 16 // load C_3, C_4
 283  (p8)  fcvt.fx.s1 FR_int_x = f8                   // Convert x to integer
 284        nop.i 0
 285 }
 286 {.mfi
 287        setf.d FR_UF_LIMIT= GR_UF_LIMIT            // Set underflow limit
 288        fma.s1 FR_KF0= f8, FR_LOG2_10, FR_ROUNDVAL // y= (x*log2(10)*2^10 +
 289                                                   //    1.5*2^63) * 2^(-63)
 290        mov GR_EXP_CORR= 0xffff-126
 291 }
 292 ;;
 293
 294 {.mfi
 295        setf.d FR_SNORM_LIMIT= GR_SNORM_LIMIT      // Set smallest normal limit
 296        fma.s1 FR_L2_10_high= FR_LOG2_10, FR_2P53, f0 // FR_LOG2_10= log2(10)_hi
 297        nop.i 0
 298 }
 299 ;;
 300
 301 {.mfi
 302        ldfe FR_COEFF1= [ GR_COEFF_START ], 16    // load C_1
 303        fms.s1 FR_KF= FR_KF0, f1, FR_ROUNDVAL     // (K+f)*2^(10-63)
 304        mov GR_MASK= 1023
 305 }
 306 ;;
 307
 308 {.mfi
 309        ldfe FR_COEFF2= [ GR_COEFF_START ], 16    // load C_2
 310        fma.s1 FR_LOG2_10= f8, FR_L2_10_high, f0  // y0= x*log2(10)_hi
 311        mov GR_MASK_low= 31
 312 }
 313 ;;
 314
 315 {.mlx
 316        getf.sig GR_KF0= FR_KF0                   // (K+f)*2^10= round_to_int(y)
 317  (p8)  movl GR_exact_limit= 0x41b00000           // Largest x for exact result,
 318                                                  //  +22.0
 319 }
 320 ;;
 321
 322 {.mfi
 323        add GR_LOG_TBL= 256, GR_COEFF_START       // Pointer to high T_table
 324        fcmp.gt.s1 p12, p7= f8, FR_OF_LIMIT       // x>overflow threshold ?
 325        nop.i 0
 326 }
 327 ;;
 328
 329 {.mfi
 330  (p8)  setf.s FR_exact_limit = GR_exact_limit    // Largest x for exact result
 331  (p8)  fcvt.xf FR_int_x = FR_int_x               // Integral part of x
 332        shr GR_K= GR_KF0, 10                      // K
 333 }
 334 {.mfi
 335        and GR_F_high= GR_MASK, GR_KF0            // f_high*32
 336        fnma.s1 FR_R= FR_KF, FR_2P53, FR_LOG2_10  // r= x*log2(10)-2^{63-10}*
 337                                                  //    [ (K+f)*2^{10-63} ]
 338        and GR_F_low= GR_KF0, GR_MASK_low         // f_low
 339 }
 340 ;;
 341
 342 {.mmi
 343        shladd GR_Flow_ADDR= GR_F_low, 3, GR_COEFF_START // address of 2^{f_low}
 344        add GR_BIAS= GR_K, GR_EXP_CORR            // K= bias-2*63
 345        shr GR_Fh= GR_F_high, 5                   // f_high
 346 }
 347 ;;
 348
 349 {.mfi
 350        setf.exp FR_2_TO_K= GR_BIAS               // 2^{K-126}
 351  (p7)  fcmp.lt.s1 p12, p7= f8, FR_UF_LIMIT       // x<underflow threshold ?
 352        shladd GR_Fh_ADDR= GR_Fh, 3, GR_LOG_TBL   // address of 2^{f_high}
 353 }
 354 {.mfi
 355        ldf8 FR_T_low= [ GR_Flow_ADDR ]           // load T_low= 2^{f_low}
 356        fms.s1 FR_DX_L210= f8, FR_L2_10_high, FR_LOG2_10 // x*log2(10)_hi-
 357                                                  //        RN(x*log2(10)_hi)
 358        nop.i 0
 359 }
 360 ;;
 361
 362 {.mfi
 363        ldf8 FR_T_high= [ GR_Fh_ADDR ]            // load T_high= 2^{f_high}
 364        fma.s1 FR_P34= FR_COEFF4, FR_R, FR_COEFF3 // P34= C_3+C_4*r
 365        nop.i 0
 366 }
 367 {.mfb
 368        nop.m 0
 369        fma.s1 FR_R2= FR_R, FR_R, f0              // r*r
 370  (p12) br.cond.spnt OUT_RANGE_exp10
 371 }
 372 ;;
 373
 374 {.mfi
 375        nop.m 0
 376        // e= (x*log2(10)_hi-RN(x*log2(10)_hi))+log2(10)_lo*x
 377        fma.s1 FR_E0= f8, FR_L2_10_low, FR_DX_L210
 378        cmp.eq p7,p9= r0,r0                       // Assume inexact result
 379 }
 380 {.mfi
 381        nop.m 0
 382        fma.s1 FR_P12= FR_COEFF2, FR_R, FR_COEFF1 // P12= C_1+C_2*r
 383        nop.i 0
 384 }
 385 ;;
 386
 387 {.mfi
 388        nop.m 0
 389  (p8)  fcmp.eq.s1 p9,p7= FR_int_x, f8            // Test x positive integer
 390        nop.i 0
 391 }
 392 {.mfi
 393        nop.m 0
 394        fma.s1 FR_T_low_K= FR_T_low, FR_2_TO_K, f0 // T= 2^{K-126}*T_low
 395        nop.i 0
 396 }
 397 ;;
 398
 399 {.mfi
 400        nop.m 0
 401        fcmp.ge.s1 p11,p0= f8, FR_SNORM_LIMIT      // Test x for normal range
 402        nop.i 0
 403 }
 404 ;;
 405
 406 {.mfi
 407        nop.m 0
 408        fma.s1 FR_E= FR_E0, FR_COEFF1, f0          // E= C_1*e
 409        nop.i 0
 410 }
 411 {.mfi
 412        nop.m 0
 413        fma.s1 FR_P14= FR_R2, FR_P34, FR_P12       // P14= P12+r2*P34
 414        nop.i 0
 415 }
 416 ;;
 417
 418 // If x a positive integer, will it produce an exact result?
 419 //   p7 result will be inexact
 420 //   p9 result will be exact
 421 {.mfi
 422        nop.m 0
 423  (p9)  fcmp.le.s1 p9,p7= f8, FR_exact_limit       // Test x gives exact result
 424        nop.i 0
 425 }
 426 {.mfi
 427        nop.m 0
 428        fma.s1 FR_T= FR_T_low_K, FR_T_high, f0     // T= T*T_high
 429        nop.i 0
 430 }
 431 ;;
 432
 433 {.mfi
 434        nop.m 0
 435        fma.s1 FR_P= FR_P14, FR_R, FR_E            // P= P14*r+E
 436        nop.i 0
 437 }
 438 ;;
 439
 440 .pred.rel "mutex",p7,p9
 441 {.mfi
 442        nop.m 0
 443  (p7)  fma.d.s0 f8= FR_P, FR_T, FR_T              // result= T+T*P, inexact set
 444        nop.i 0
 445 }
 446 {.mfb
 447        nop.m 0
 448  (p9)  fma.d.s1 f8= FR_P, FR_T, FR_T              // result= T+T*P, exact use s1
 449  (p11) br.ret.sptk b0                             // return, if result normal
 450 }
 451 ;;
 452
 453 // Here if result in denormal range (and not zero)
 454 {.mib
 455        nop.m 0
 456        mov GR_Parameter_TAG= 265
 457        br.cond.sptk __libm_error_region           // Branch to error handling
 458 }
 459 ;;
 460
 461 SPECIAL_exp10:
 462 {.mfi
 463        nop.m 0
 464        fclass.m p6, p0= f8, 0x22                  // x= -Infinity ?
 465        nop.i 0
 466 }
 467 ;;
 468
 469 {.mfi
 470        nop.m 0
 471        fclass.m p7, p0= f8, 0x21                  // x= +Infinity ?
 472        nop.i 0
 473 }
 474 ;;
 475
 476 {.mfi
 477        nop.m 0
 478        fclass.m p8, p0= f8, 0x7                   // x= +/-Zero ?
 479        nop.i 0
 480 }
 481 {.mfb
 482        nop.m 0
 483  (p6)  mov f8= f0                                 // exp10(-Infinity)= 0
 484  (p6)  br.ret.spnt b0
 485 }
 486 ;;
 487
 488 {.mfb
 489        nop.m 0
 490        nop.f 0
 491  (p7)  br.ret.spnt b0                             // exp10(+Infinity)= +Infinity
 492 }
 493 ;;
 494
 495 {.mfb
 496        nop.m 0
 497  (p8)  mov f8= f1                                 // exp10(+/-0)= 1
 498  (p8)  br.ret.spnt b0
 499 }
 500 ;;
 501
 502 {.mfb
 503        nop.m 0
 504        fma.d.s0 f8= f8, f1, f0                    // Remaining cases: NaNs
 505        br.ret.sptk b0
 506 }
 507 ;;
 508
 509
 510 OUT_RANGE_exp10:
 511
 512 // underflow: p6= 1
 513 // overflow: p8= 1
 514
 515 .pred.rel "mutex",p6,p8
 516 {.mmi
 517  (p8)  mov GR_EXPMAX= 0x1fffe
 518  (p6)  mov GR_EXPMAX= 1
 519        nop.i 0
 520 }
 521 ;;
 522
 523 {.mii
 524        setf.exp FR_R= GR_EXPMAX
 525  (p8)  mov GR_Parameter_TAG= 166
 526  (p6)  mov GR_Parameter_TAG= 265
 527 }
 528 ;;
 529
 530 {.mfb
 531        nop.m 0
 532        fma.d.s0 f8= FR_R, FR_R, f0                // Create overflow/underflow
 533        br.cond.sptk __libm_error_region           // Branch to error handling
 534 }
 535 ;;
 536
 537 GLOBAL_IEEE754_END(exp10)
 538 libm_alias_double_other (__exp10, exp10)
 539 #if SHLIB_COMPAT (libm, GLIBC_2_1, GLIBC_2_27)
 540 compat_symbol (libm, exp10, pow10, GLIBC_2_2)
 541 #endif
 542
 543
 544 LOCAL_LIBM_ENTRY(__libm_error_region)
 545
 546 .prologue
 547 {.mfi
 548        add GR_Parameter_Y= -32, sp                // Parameter 2 value
 549        nop.f 0
 550 .save ar.pfs, GR_SAVE_PFS
 551        mov GR_SAVE_PFS= ar.pfs                    // Save ar.pfs
 552 }
 553
 554 {.mfi
 555 .fframe 64
 556        add sp= -64, sp                            // Create new stack
 557        nop.f 0
 558        mov GR_SAVE_GP= gp                         // Save gp
 559 }
 560 ;;
 561
 562 {.mmi
 563        stfd [ GR_Parameter_Y ]= FR_Y, 16          // STORE Parameter 2 on stack
 564        add GR_Parameter_X= 16, sp                 // Parameter 1 address
 565 .save b0, GR_SAVE_B0
 566        mov GR_SAVE_B0= b0                         // Save b0
 567 }
 568 ;;
 569
 570 .body
 571 {.mib
 572        stfd [ GR_Parameter_X ]= FR_X              // STORE Parameter 1 on stack
 573        add GR_Parameter_RESULT= 0, GR_Parameter_Y // Parameter 3 address
 574        nop.b 0
 575 }
 576 {.mib
 577        stfd [ GR_Parameter_Y ]= FR_RESULT         // STORE Parameter 3 on stack
 578        add GR_Parameter_Y= -16, GR_Parameter_Y
 579        br.call.sptk b0= __libm_error_support#    // Call error handling function
 580 }
 581 ;;
 582
 583 {.mmi
 584        add GR_Parameter_RESULT= 48, sp
 585        nop.m 0
 586        nop.i 0
 587 }
 588 ;;
 589
 590 {.mmi
 591        ldfd f8= [ GR_Parameter_RESULT ]          // Get return result off stack
 592 .restore sp
 593        add sp= 64, sp                            // Restore stack pointer
 594        mov b0= GR_SAVE_B0                        // Restore return address
 595 }
 596 ;;
 597
 598 {.mib
 599        mov gp= GR_SAVE_GP                        // Restore gp
 600        mov ar.pfs= GR_SAVE_PFS                   // Restore ar.pfs
 601        br.ret.sptk b0                            // Return
 602 }
 603 ;;
 604
 605
 606 LOCAL_LIBM_END(__libm_error_region)
 607
 608 .type __libm_error_support#, @function
 609 .global __libm_error_support#