sysdeps/ia64/fpu/s_ceill.S

   1 .file "ceill.s"
   2
   3
   4 // Copyright (c) 2000 - 2003, Intel Corporation
   5 // All rights reserved.
   6 //
   7 //
   8 // Redistribution and use in source and binary forms, with or without
   9 // modification, are permitted provided that the following conditions are
  10 // met:
  11 //
  12 // * Redistributions of source code must retain the above copyright
  13 // notice, this list of conditions and the following disclaimer.
  14 //
  15 // * Redistributions in binary form must reproduce the above copyright
  16 // notice, this list of conditions and the following disclaimer in the
  17 // documentation and/or other materials provided with the distribution.
  18 //
  19 // * The name of Intel Corporation may not be used to endorse or promote
  20 // products derived from this software without specific prior written
  21 // permission.
  22
  23 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  24 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  25 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  26 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  27 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  28 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  29 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  30 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  31 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  32 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  33 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  34 //
  35 // Intel Corporation is the author of this code, and requests that all
  36 // problem reports or change requests be submitted to it directly at
  37 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  38 //
  39 // History
  40 //==============================================================
  41 // 02/02/00 Initial version
  42 // 06/13/00 Improved speed
  43 // 06/27/00 Eliminated incorrect invalid flag setting
  44 // 05/20/02 Cleaned up namespace and sf0 syntax
  45 // 01/28/03 Improved performance
  46 //==============================================================
  47
  48 // API
  49 //==============================================================
  50 // long double ceill(long double x)
  51 //==============================================================
  52
  53 // general input registers:
  54 // r14 - r19
  55
  56 rSignexp   = r14
  57 rExp       = r15
  58 rExpMask   = r16
  59 rBigexp    = r17
  60 rM1        = r18
  61 rSignexpM1 = r19
  62
  63 // floating-point registers:
  64 // f8 - f13
  65
  66 fXInt      = f9
  67 fNormX     = f10
  68 fTmp       = f11
  69 fAdj       = f12
  70 fPreResult = f13
  71
  72 // predicate registers used:
  73 // p6 - p10
  74
  75 // Overview of operation
  76 //==============================================================
  77 // long double ceill(long double x)
  78 // Return an integer value (represented as a long double) that is the smallest
  79 // value not less than x
  80 // This is x rounded toward +infinity to an integral value.
  81 // Inexact is set if x != ceill(x)
  82 //==============================================================
  83
  84 // double_extended
  85 // if the exponent is > 1003e => 3F(true) = 63(decimal)
  86 // we have a significand of 64 bits 1.63-bits.
  87 // If we multiply by 2^63, we no longer have a fractional part
  88 // So input is an integer value already.
  89
  90 // double
  91 // if the exponent is >= 10033 => 34(true) = 52(decimal)
  92 // 34 + 3ff = 433
  93 // we have a significand of 53 bits 1.52-bits. (implicit 1)
  94 // If we multiply by 2^52, we no longer have a fractional part
  95 // So input is an integer value already.
  96
  97 // single
  98 // if the exponent is > 10016 => 17(true) = 23(decimal)
  99 // we have a significand of 24 bits 1.23-bits. (implicit 1)
 100 // If we multiply by 2^23, we no longer have a fractional part
 101 // So input is an integer value already.
 102
 103
 104 .section .text
 105 GLOBAL_LIBM_ENTRY(ceill)
 106
 107 { .mfi
 108       getf.exp         rSignexp  = f8        // Get signexp, recompute if unorm
 109       fclass.m         p7,p0 = f8, 0x0b      // Test x unorm
 110       addl             rBigexp = 0x1003e, r0 // Set exponent at which is integer
 111 }
 112 { .mfi
 113       mov              rM1 = -1              // Set all ones
 114       fcvt.fx.trunc.s1 fXInt  = f8           // Convert to int in significand
 115       mov              rExpMask    = 0x1FFFF // Form exponent mask
 116 }
 117 ;;
 118
 119 { .mfi
 120       mov              rSignexpM1  = 0x2FFFF // Form signexp of -1
 121       fcmp.lt.s1       p8,p9 = f8, f0        // Test x < 0
 122       nop.i            0
 123 }
 124 { .mfb
 125       setf.sig         fTmp = rM1            // Make const for setting inexact
 126       fnorm.s1         fNormX  = f8          // Normalize input
 127 (p7)  br.cond.spnt     CEIL_UNORM            // Branch if x unorm
 128 }
 129 ;;
 130
 131 CEIL_COMMON:
 132 // Return here from CEIL_UNORM
 133 { .mfi
 134       nop.m            0
 135       fclass.m         p6,p0 = f8, 0x1e7     // Test x natval, nan, inf, 0
 136       nop.i            0
 137 }
 138 ;;
 139
 140 .pred.rel "mutex",p8,p9
 141 { .mfi
 142       nop.m            0
 143 (p8)  fma.s1           fAdj = f0, f0, f0     // If x < 0, adjustment is 0
 144       nop.i            0
 145 }
 146 { .mfi
 147       nop.m            0
 148 (p9)  fma.s1           fAdj = f1, f1, f0     // If x > 0, adjustment is +1
 149       nop.i            0
 150 }
 151 ;;
 152
 153 { .mfi
 154       nop.m            0
 155       fcvt.xf          fPreResult = fXInt    // trunc(x)
 156       nop.i            0
 157 }
 158 { .mfb
 159       nop.m            0
 160 (p6)  fma.s0           f8 = f8, f1, f0       // Result if x natval, nan, inf, 0
 161 (p6)  br.ret.spnt      b0                    // Exit if x natval, nan, inf, 0
 162 }
 163 ;;
 164
 165 { .mmi
 166       and              rExp = rSignexp, rExpMask // Get biased exponent
 167 ;;
 168       cmp.ge           p7,p6 = rExp, rBigexp  // Is |x| >= 2^63?
 169 (p8)  cmp.lt.unc       p10,p0 = rSignexp, rSignexpM1 // Is -1 < x < 0?
 170 }
 171 ;;
 172
 173 // If -1 < x < 0, we turn off p6 and compute result as -0
 174 { .mfi
 175 (p10) cmp.ne           p6,p0 = r0,r0
 176 (p10) fmerge.s         f8 = fNormX, f0
 177       nop.i            0
 178 }
 179 ;;
 180
 181 .pred.rel "mutex",p6,p7
 182 { .mfi
 183       nop.m            0
 184 (p6)  fma.s0           f8 = fPreResult, f1, fAdj // Result if !int, |x| < 2^63
 185       nop.i            0
 186 }
 187 { .mfi
 188       nop.m            0
 189 (p7)  fma.s0           f8 = fNormX, f1, f0    // Result, if |x| >= 2^63
 190 (p10) cmp.eq           p6,p0 = r0,r0          // If -1 < x < 0, turn on p6 again
 191 }
 192 ;;
 193
 194 { .mfi
 195       nop.m            0
 196 (p6)  fcmp.eq.unc.s1   p8, p9 = fPreResult, fNormX // Is trunc(x) = x ?
 197       nop.i            0
 198 }
 199 ;;
 200
 201 { .mfi
 202       nop.m            0
 203 (p9)  fmpy.s0          fTmp = fTmp, fTmp      // Dummy to set inexact
 204       nop.i            0
 205 }
 206 { .mfb
 207       nop.m            0
 208 (p8)  fma.s0           f8 = fNormX, f1, f0    // If x int, result normalized x
 209       br.ret.sptk      b0                     // Exit main path, 0 < |x| < 2^63
 210 }
 211 ;;
 212
 213
 214 CEIL_UNORM:
 215 // Here if x unorm
 216 { .mfb
 217       getf.exp         rSignexp  = fNormX     // Get signexp, recompute if unorm
 218       fcmp.eq.s0       p7,p0 = f8, f0         // Dummy op to set denormal flag
 219       br.cond.sptk     CEIL_COMMON            // Return to main path
 220 }
 221 ;;
 222
 223 GLOBAL_LIBM_END(ceill)
 224 libm_alias_ldouble_other (ceil, ceil)