sysdeps/ia64/fpu/s_floorf.S

   1 .file "floorf.s"
   2
   3
   4 // Copyright (c) 2000 - 2003, Intel Corporation
   5 // All rights reserved.
   6 //
   7 //
   8 // Redistribution and use in source and binary forms, with or without
   9 // modification, are permitted provided that the following conditions are
  10 // met:
  11 //
  12 // * Redistributions of source code must retain the above copyright
  13 // notice, this list of conditions and the following disclaimer.
  14 //
  15 // * Redistributions in binary form must reproduce the above copyright
  16 // notice, this list of conditions and the following disclaimer in the
  17 // documentation and/or other materials provided with the distribution.
  18 //
  19 // * The name of Intel Corporation may not be used to endorse or promote
  20 // products derived from this software without specific prior written
  21 // permission.
  22
  23 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  24 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  25 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  26 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  27 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  28 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  29 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  30 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  31 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  32 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  33 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  34 //
  35 // Intel Corporation is the author of this code, and requests that all
  36 // problem reports or change requests be submitted to it directly at
  37 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  38 //
  39 // History
  40 //==============================================================
  41 // 02/02/00 Initial version
  42 // 06/13/00 Improved speed
  43 // 06/27/00 Eliminated incorrect invalid flag setting
  44 // 02/07/01 Corrected sign of zero result in round to -inf mode
  45 // 05/20/02 Cleaned up namespace and sf0 syntax
  46 // 01/28/03 Improved performance
  47 //==============================================================
  48
  49 // API
  50 //==============================================================
  51 // float floorf(float x)
  52 //==============================================================
  53
  54 // general input registers:
  55 // r14 - r18
  56
  57 rSignexp   = r14
  58 rExp       = r15
  59 rExpMask   = r16
  60 rBigexp    = r17
  61 rM1        = r18
  62
  63 // floating-point registers:
  64 // f8 - f13
  65
  66 fXInt      = f9
  67 fNormX     = f10
  68 fTmp       = f11
  69 fAdj       = f12
  70 fPreResult = f13
  71
  72 // predicate registers used:
  73 // p6 - p9
  74
  75 // Overview of operation
  76 //==============================================================
  77 // float floorf(float x)
  78 // Return an integer value (represented as a float) that is the largest
  79 // value not greater than x
  80 // This is x rounded toward -infinity to an integral value.
  81 // Inexact is set if x != floorf(x)
  82 //==============================================================
  83
  84 // double_extended
  85 // if the exponent is > 1003e => 3F(true) = 63(decimal)
  86 // we have a significand of 64 bits 1.63-bits.
  87 // If we multiply by 2^63, we no longer have a fractional part
  88 // So input is an integer value already.
  89
  90 // double
  91 // if the exponent is >= 10033 => 34(true) = 52(decimal)
  92 // 34 + 3ff = 433
  93 // we have a significand of 53 bits 1.52-bits. (implicit 1)
  94 // If we multiply by 2^52, we no longer have a fractional part
  95 // So input is an integer value already.
  96
  97 // single
  98 // if the exponent is > 10016 => 17(true) = 23(decimal)
  99 // we have a significand of 24 bits 1.23-bits. (implicit 1)
 100 // If we multiply by 2^23, we no longer have a fractional part
 101 // So input is an integer value already.
 102
 103
 104 .section .text
 105 GLOBAL_IEEE754_ENTRY(floorf)
 106
 107 { .mfi
 108       getf.exp         rSignexp  = f8        // Get signexp, recompute if unorm
 109       fclass.m         p7,p0 = f8, 0x0b      // Test x unorm
 110       addl             rBigexp = 0x10016, r0 // Set exponent at which is integer
 111 }
 112 { .mfi
 113       mov              rM1 = -1              // Set all ones
 114       fcvt.fx.trunc.s1 fXInt  = f8           // Convert to int in significand
 115       mov              rExpMask    = 0x1FFFF // Form exponent mask
 116 }
 117 ;;
 118
 119 { .mfi
 120       nop.m            0
 121       fcmp.lt.s1       p8,p9 = f8, f0        // Test x < 0
 122       nop.i            0
 123 }
 124 { .mfb
 125       setf.sig         fTmp = rM1            // Make const for setting inexact
 126       fnorm.s1         fNormX  = f8          // Normalize input
 127 (p7)  br.cond.spnt     FLOOR_UNORM           // Branch if x unorm
 128 }
 129 ;;
 130
 131 FLOOR_COMMON:
 132 // Return here from FLOOR_UNORM
 133 { .mfi
 134       nop.m            0
 135       fclass.m         p6,p0 = f8, 0x1e7     // Test x natval, nan, inf, 0
 136       nop.i            0
 137 }
 138 ;;
 139
 140 .pred.rel "mutex",p8,p9
 141 { .mfi
 142       nop.m            0
 143 (p8)  fnma.s1          fAdj = f1, f1, f0     // If x < 0, adjustment is -1
 144       nop.i            0
 145 }
 146 { .mfi
 147       nop.m            0
 148 (p9)  fma.s1           fAdj = f0, f0, f0     // If x > 0, adjustment is 0
 149       nop.i            0
 150 }
 151 ;;
 152
 153 { .mfi
 154       nop.m            0
 155       fcvt.xf          fPreResult = fXInt    // trunc(x)
 156       nop.i            0
 157 }
 158 { .mfb
 159       nop.m            0
 160 (p6)  fma.s.s0         f8 = f8, f1, f0       // Result if x natval, nan, inf, 0
 161 (p6)  br.ret.spnt      b0                    // Exit if x natval, nan, inf, 0
 162 }
 163 ;;
 164
 165 { .mmi
 166       and              rExp = rSignexp, rExpMask // Get biased exponent
 167 ;;
 168       cmp.ge           p7,p6 = rExp, rBigexp  // Is |x| >= 2^23?
 169       nop.i            0
 170 }
 171 ;;
 172
 173 { .mfi
 174       nop.m            0
 175 (p6)  fma.s.s0         f8 = fPreResult, f1, fAdj // Result if !int, |x| < 2^23
 176       nop.i            0
 177 }
 178 { .mfi
 179       nop.m            0
 180 (p7)  fma.s.s0         f8 = fNormX, f1, f0    // Result, if |x| >= 2^23
 181       nop.i            0
 182 }
 183 ;;
 184
 185 { .mfi
 186       nop.m            0
 187 (p6)  fcmp.eq.unc.s1   p8, p9 = fPreResult, fNormX // Is trunc(x) = x ?
 188       nop.i            0
 189 }
 190 ;;
 191
 192 { .mfi
 193       nop.m            0
 194 (p9)  fmpy.s0          fTmp = fTmp, fTmp      // Dummy to set inexact
 195       nop.i            0
 196 }
 197 { .mfb
 198       nop.m            0
 199 (p8)  fma.s.s0         f8 = fNormX, f1, f0    // If x int, result normalized x
 200       br.ret.sptk      b0                     // Exit main path, 0 < |x| < 2^23
 201 }
 202 ;;
 203
 204
 205 FLOOR_UNORM:
 206 // Here if x unorm
 207 { .mfb
 208       getf.exp         rSignexp  = fNormX     // Get signexp, recompute if unorm
 209       fcmp.eq.s0       p7,p0 = f8, f0         // Dummy op to set denormal flag
 210       br.cond.sptk     FLOOR_COMMON           // Return to main path
 211 }
 212 ;;
 213
 214 GLOBAL_IEEE754_END(floorf)
 215 libm_alias_float_other (__floor, floor)