sysdeps/unix/bsd/bsd4.4/kfreebsd/i386/start.S

   1 /* Startup code compliant to the ELF i386 ABI.
   2    Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, see
  34    <http://www.gnu.org/licenses/>.  */
  35
  36 /* This is the canonical entry point, usually the first thing in the text
  37    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  38    point runs, most registers' values are unspecified, except for:
  39
  40    %edx         Contains a function pointer to be registered with `atexit'.
  41                 This is how the dynamic linker arranges to have DT_FINI
  42                 functions called for shared libraries that have been loaded
  43                 before this code runs.
  44
  45    %esp         The stack contains the arguments and environment:
  46                 0(%esp)                 argc
  47                 4(%esp)                 argv[0]
  48                 ...
  49                 (4*argc)(%esp)          NULL
  50                 (4*(argc+1))(%esp)      envp[0]
  51                 ...
  52                                         NULL
  53 */
  54
  55 #include <libc-symbols.h>
  56
  57         weak_extern (_end)
  58
  59         .text
  60         .globl _start
  61         .type _start,@function
  62 _start:
  63         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  64            the outermost frame obviously.  */
  65         xorl %ebp, %ebp
  66
  67         /* Extract the arguments as encoded on the stack and set up
  68            the arguments for `main': argc, argv.  envp will be determined
  69            later in __libc_start_main.  */
  70         popl %esi               /* Pop the argument count.  */
  71         movl %esp, %ecx         /* argv starts just at the current stack top.*/
  72
  73         /* Before pushing the arguments align the stack to a 16-byte
  74         (SSE needs 16-byte alignment) boundary to avoid penalties from
  75         misaligned accesses.  Thanks to Edward Seidl <seidl@janed.com>
  76         for pointing this out.  */
  77         andl $0xfffffff0, %esp
  78         pushl %eax              /* Push garbage because we allocate
  79                                    28 more bytes.  */
  80
  81         /* Provide the highest stack address to the user code (for stacks
  82            which grow downwards).  */
  83         pushl %esp
  84
  85         pushl %edx              /* Push address of the shared library
  86                                    termination function.  */
  87
  88 #ifdef SHARED
  89         /* Load PIC register.  */
  90         call 1f
  91         addl $_GLOBAL_OFFSET_TABLE_, %ebx
  92
  93         /* Push address of our own entry points to .fini and .init.  */
  94         leal __libc_csu_fini@GOTOFF(%ebx), %eax
  95         pushl %eax
  96         leal __libc_csu_init@GOTOFF(%ebx), %eax
  97         pushl %eax
  98
  99         pushl %ecx              /* Push second argument: argv.  */
 100         pushl %esi              /* Push first argument: argc.  */
 101
 102         pushl main@GOT(%ebx)
 103
 104         /* Call the user's main function, and exit with its value.
 105            But let the libc call main.    */
 106         call __libc_start_main@PLT
 107 #else
 108         /* Push address of our own entry points to .fini and .init.  */
 109         pushl $__libc_csu_fini
 110         pushl $__libc_csu_init
 111
 112         pushl %ecx              /* Push second argument: argv.  */
 113         pushl %esi              /* Push first argument: argc.  */
 114
 115         pushl $main
 116
 117         /* Call the user's main function, and exit with its value.
 118            But let the libc call main.    */
 119         call __libc_start_main
 120 #endif
 121
 122         hlt                     /* Crash if somehow `exit' does return.  */
 123
 124 #ifdef SHARED
 125 1:      movl    (%esp), %ebx
 126         ret
 127 #endif
 128         /* just reference _end,
 129            it is needed as global symbol for brk() usage,
 130            it is a dead code on purpose.  */
 131 #ifdef SHARED
 132         leal _end@GOTOFF(%ebx), %eax
 133 #else
 134         mov $_end, %eax
 135 #endif
 136
 137 /* To fulfill the System V/i386 ABI we need this symbol.  Yuck, it's so
 138    meaningless since we don't support machines < 80386.  */
 139         .section .rodata
 140         .globl _fp_hw
 141 _fp_hw: .long 3
 142         .size _fp_hw, 4
 143         .type _fp_hw,@object
 144
 145 /* Define a symbol for the first piece of initialized data.  */
 146         .data
 147         .globl __data_start
 148 __data_start:
 149         .long 0
 150         .weak data_start
 151         data_start = __data_start