flake.nix

   1 # The license for this file is included in the `nix` directory next to this file.
   2
   3 {
   4   description = "FOSS CPU/GPU/VPU/SoC all in one, see https://libre-soc.org/";
   5
   6   inputs.nixpkgs.url = "github:L-as/nixpkgs?ref=libresoc"; # for alliance and migen
   7   inputs.c4m-jtag.url = "git+https://git.libre-soc.org/git/c4m-jtag.git";
   8   inputs.c4m-jtag.flake = false;
   9   inputs.nmigen.url = "git+https://git.libre-soc.org/git/nmigen.git";
  10   inputs.nmigen.flake = false;
  11   inputs.nmigen-soc.url = "git+https://git.libre-soc.org/git/nmigen-soc.git";
  12   inputs.nmigen-soc.flake = false;
  13   inputs.nix-litex.url = "git+https://git.sr.ht/~lschuermann/nix-litex?ref=main";
  14   inputs.nix-litex.flake = false;
  15
  16   outputs = { self, nixpkgs, c4m-jtag, nmigen, nmigen-soc, nix-litex }:
  17     let
  18       getv = x: builtins.substring 0 8 x.lastModifiedDate;
  19
  20       supportedSystems = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];
  21
  22       forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
  23
  24       litex = pkgs: import "${nix-litex}/pkgs" {
  25         inherit pkgs;
  26         pkgMetas = builtins.fromTOML (builtins.readFile ./nix/litex.toml);
  27         skipChecks = true; # FIXME: remove once checks work
  28       };
  29
  30       nixpkgsFor = forAllSystems (system: import nixpkgs { inherit system; overlays = [ self.overlay ]; });
  31
  32       lib = nixpkgs.lib;
  33     in
  34     {
  35       overlay = final: prev: {
  36         python3Packages = prev.python3Packages.override {
  37           overrides = lib.composeExtensions (litex final).pythonOverlay (pfinal: pprev: {
  38             libresoc-ieee754fpu = pfinal.callPackage ./nix/ieee754fpu.nix {};
  39             libresoc-openpower-isa = pfinal.callPackage ./nix/openpower-isa.nix {};
  40             c4m-jtag = pfinal.callPackage (import ./nix/c4m-jtag.nix { src = c4m-jtag; version = getv c4m-jtag; }) {};
  41             bigfloat = pfinal.callPackage ./nix/bigfloat.nix {};
  42             modgrammar = pfinal.callPackage ./nix/modgrammar.nix {};
  43             libresoc-nmutil = pfinal.callPackage ./nix/nmutil.nix {};
  44             libresoc-soc = pfinal.callPackage (import ./nix/soc.nix { version = getv self; }) {};
  45
  46             nmigen-soc = pprev.nmigen-soc.overrideAttrs (_: {
  47               doCheck = false;
  48               src = nmigen-soc;
  49               setuptoolsCheckPhase = "true";
  50             });
  51
  52             nmigen = pprev.nmigen.overrideAttrs (_: {
  53               src = nmigen;
  54             });
  55           });
  56         };
  57
  58         libresoc-pre-litex = final.callPackage (import ./nix/pre-litex.nix { version = getv self; }) {};
  59         libresoc-ls180 = final.callPackage (import ./nix/ls180.nix { version = getv self; }) {};
  60         libresoc-ecp5 = final.callPackage (import ./nix/ecp5.nix { version = getv self; }) {};
  61         libresoc-pinmux = final.callPackage (import ./nix/pinmux.nix { version = getv self; }) {};
  62       };
  63
  64       packages = forAllSystems (system: {
  65         soc = nixpkgsFor.${system}.python3Packages.libresoc-soc;
  66         pre-litex = nixpkgsFor.${system}.libresoc-pre-litex;
  67         pinmux = nixpkgsFor.${system}.libresoc-pinmux;
  68         ls180 = nixpkgsFor.${system}.libresoc-ls180;
  69         ecp5 = nixpkgsFor.${system}.libresoc-ecp5;
  70         openpower-isa = nixpkgsFor.${system}.python3Packages.libresoc-openpower-isa;
  71         debugNixpkgs = nixpkgsFor.${system};
  72       });
  73
  74       defaultPackage = forAllSystems (system: self.packages.${system}.pre-litex);
  75     };
  76 }